Shader "Custom/Chapter6-BlinnPhong" {
    Properties {
        _Diffuse ("Diffuse",Color) = (1,1,1,1)
        _Specular("Specular",Color) = (1,1,1,1)
        // 高光區(qū)域大小控制
        _Gloss("Gloss",Range(8.0,256)) = 20
    }
    SubShader {
        Pass{
            Tags{"LightMode" = "ForwardBase"}

            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct a2v{
                float4 vertex :POSITION;
                float3 normal : NORMAL;
            };

            struct v2f{
                float4 pos : SV_POSITION;
                float3 worldPos : TEXCOORD1;
                float3 worldNormal : TEXCOORD0;
            };

            v2f vert(a2v v){
                
                v2f o;
                // 將頂點坐標(biāo)從模型空間轉(zhuǎn)換到裁切空間
                o.pos = UnityObjectToClipPos(v.vertex);
                // 將法線從模型空間轉(zhuǎn)換到世界空間，normalize進(jìn)行歸一化處理
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                // 將頂點坐標(biāo)從模型空間轉(zhuǎn)換到世界空間
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);
                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET{
                // 獲取環(huán)境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                // 世界空間法線歸一化
                fixed3 worldNormal = normalize(i.worldNormal);
                // 光源方向歸一化
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                // 計算漫反射
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal,worldLightDir));
                // 反射光線方向
                fixed3 reflectDir = normalize(reflect(-worldLightDir,worldNormal));
                // 視線方向
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
                // Blinn引入矢量
                fixed3 halfDir = normalize(worldLightDir + viewDir);
                // 計算反射光
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(worldNormal,halfDir)),_Gloss);
                return fixed4(ambient + diffuse + specular,1.0);
            }

            ENDCG
        }
        
    }
    FallBack "Specular"
}