下面的程序中，已經(jīng)定義好了這些數(shù)據(jù):

assume cs:codesg
data segment
  db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
  db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
  db '1993','1994','1995'
  # 以上表示21年的21個字符串

  dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
  dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
  # 以上表示21年公司總收入的21個dword型數(shù)據(jù)

  dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
  dw 11542,14430,15257,17800
  # 以上表示21年公司雇員人數(shù)的21個word型數(shù)據(jù)
data ends

table segment
  db 21 dup ('year summ ne ??')
table ends

編程，將data段中的數(shù)據(jù)按照如下格式寫入到table段中，并計算21年中的人均收入(取整)，結(jié)果按照下面的格式保存在table段中。

思路分析：

將data中的數(shù)據(jù)作為三個數(shù)組看待。
ds:[0 - 53h]：為年份
ds:[54h - 0a7h]：為對應(yīng)年份總收入
ds:[0a8h - 0d1h]：為對應(yīng)年份公司雇員數(shù)

完整程序如下：

assume cs:codesg
data segment
  db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
  db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
  db '1993','1994','1995'
  # 以上表示21年的21個字符串

  dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
  dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
  # 以上表示21年公司總收入的21個dword型數(shù)據(jù)

  dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
  dw 11542,14430,15257,17800
  # 以上表示21年公司雇員人數(shù)的21個word型數(shù)據(jù)
data ends

table segment
  db 21 dup ('year summ ne ??')
table ends

codesg segment

start: mov ax,data
       mov ds,ax                     # 將data段傳入ds
       mov ax,table
       mov es,ax                     # 將table段傳入es
       mov bx,0
       mov si,0
       mov di,0
       mov cx,15h                    # 循環(huán)次數(shù)
       
    s: mov ax,ds:[bx]                # 將年份低位傳入ax寄存器
       mov es:[si],ax                # 將ax中的年份低位傳入es:[si]的0位
       mov ax,ds:[bx + 2]            # 將年份高位傳入ax寄存器
       mov es:[si + 2],ax            # 將ax中的年份高位傳入es:[si]的2位
                                     # 以上四條指令處理表格此行的年份

       mov ax,ds:[bx + 54h]          # 將收入低位傳入ax寄存器
       mov es:[si + 5],ax            # 將ax中的收入低位傳入es:[si]的5位
       mov ax,ds:[bx + 56h]          # 將收入高位傳入ax寄存器
       mov es:[si + 7],ax            # 將ax中的收入高位傳入es:[si]的7位
                                     # 以上四條指令處理表格此行的收入
       
       mov ax,ds:[di + 00a8h]        # 將雇員數(shù)傳入ax寄存器
       mov es:[si + 0ah],ax          # 將雇員數(shù)傳入es:[si]的10位 
                                     # 以上兩條指令處理表格此行的雇員數(shù)

       mov ax,[bx + 54h]             # 取收入的低位傳入ax
       mov dx,[bx + 56h]             # 取收入的高位傳入dx
       div word ptr ds:[di + 00a8h]  # 收入除以雇員數(shù)
       mov es:[si + 0dh],ax          # 將ax中收入的整數(shù)傳入es:[si]的13位
                                     # 以上四條指令處理表格此行的人均收入

       add si,16                     # 表格換行
       add di,2                      # 雇員數(shù)和人均收入均為2字節(jié)
       add bx,4                      # 年份和收入均為4字節(jié)

       loop s

       mov ax 4c00h
       int 21h

codesg ends
end start