前言

當一個project下有多個module時，全局依賴參數可以統一起來，修改時只需修改一處就行了，比較方便。當然如果格式你看著不爽，可以不這樣寫，畢竟現在是社會主義社會嘛，選擇自由。

配置

1.只想配置defaultConfig的情況和google系統的自帶庫
首先在項目的根build.gradle下配置ext

ext{
    compileSdkVersion =25
    buildToolsVersion= '25.0.2'
    minSdkVersion = 16
    targetSdkVersion = compileSdkVersion
    versionCode =1
    versionName ='1.0.0'
    supportLibVersion = '25.3.1'
}

然后在app/build.gradle下修改defaultConfig

    compileSdkVersion rootProject.ext.compileSdkVersion
    buildToolsVersion rootProject.ext.buildToolsVersion
    defaultConfig {
        applicationId "com.xxx"
        minSdkVersion rootProject.ext.minSdkVersion
        targetSdkVersion rootProject.ext.targetSdkVersion
        versionCode rootProject.ext.versionCode
        versionName rootProject.ext.versionName
  
    }

dependencies {
       compile "com.android.support:design:$supportLibVersion"
       compile "com.android.support:cardview-v7:$supportLibVersion"
}

2.想配置defaultConfig和所有依賴庫的情況
在項目的根目錄下創建config.gradle文件

ext{
    android=[
            applicationId:"com.fsp.aiyagirl",
            compileSdkVersion :25,
            buildToolsVersion :"25.0.2",
            minSdkVersion : 16,
            targetSdkVersion : 25,
            versionCode : 1,
            versionName :"1.0.0"
    ]

    dependencies =[
            "appcompat-v7"        : "com.android.support:appcompat-v7:25.3.1",
            "constraint"        : "com.android.support.constraint:constraint-layout:1.0.2",
    ]
}

然后在根的build.gradle中引用
apply from: "config.gradle"
這樣工程的所有module都能用這個文件的參數
最后在app/build.gradle中

android {
    compileSdkVersion rootProject.ext.android.compileSdkVersion
    buildToolsVersion rootProject.ext.android.buildToolsVersion
    defaultConfig {
        applicationId rootProject.ext.android.applicationId
        minSdkVersion rootProject.ext.android.minSdkVersion
        targetSdkVersion rootProject.ext.android.targetSdkVersion
        versionCode rootProject.ext.android.versionCode
        versionName rootProject.ext.android.versionName
     
    }
}
dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    androidTestCompile('com.android.support.test.espresso:espresso-core:2.2.2', {
        exclude group: 'com.android.support', module: 'support-annotations'
    })
    compile rootProject.ext.dependencies["appcompat-v7"]
    compile rootProject.ext.dependencies["constraint"]
}

至此，配置工作已經全部結束，有不足之處可以提出來共同探討。