或許你會覺得沒有必要這樣做，可是有一種應用場景就是，為每個編譯后的class文件添加一行代碼。比如：在每個Java類的構造函數中加一句System.out.println("I Love HuaChao!");（PS:莫吐槽_，莫嘲笑），如果你每次創建一個類的時候都手動加這么一句話，先不談容易出錯，我們說說工作量?；蛟S你覺得，你愿意手動加，那我再跟你提新需求，我現在不要這句代碼了，我要的是System.out.println("I Love MaYun!");你給我改去吧_{，這時候你會不會想罵人}。忍??！我們上一篇《在AndroidStudio中自定義Gradle插件》不是學過自定義Gradle插件了嗎？我們為什么要手動寫呢？直接通過Gradle插件來幫我們干！

1 認識Project對象

還記得上一篇文章中，我們自定義的插件類是通過實現Plugin接口，并將org.gradle.api.Project作為模板參數嗎？org.gradle.api.Project的實例對象將作為參數傳給void apply(Project project)函數。接下來我看看Project類。

根據Gradle官網的介紹，Project是你與Gradle交互的主接口，通過Project你可以通過代碼使用所有的Gradle特性，Project與build.gradle是一對一的關系。簡單來說，你想要通過代碼使用Gradle，通過Project這個入口，就可以啦~

我們先看一個簡單的通過Project訪問的使用場景：Extension?？赡苣銓?code>Extension不熟悉，但是，我給你看一個你熟悉的內容：

android {
    compileSdkVersion 24
    buildToolsVersion "24.0.0"

    defaultConfig {
        applicationId "com.hc.hcplugin"
        minSdkVersion 15
        targetSdkVersion 24
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

上面的這些你是不是很熟悉呢？你有沒有想過，上面的android{}、compileSdkVersion、defaultConfig {}等等這些設置是如何被Android的Gradle插件讀取的呢？想必你已經想到了，沒錯，就是通過Extension。下面我們自定義一個Extension，感受一下~。首先，定義兩個Groovy類：Address和HCExtension.注意：為了避免引入插件問題，以下代碼全部放入buildsrc模塊的build.gradle文件中:

class Address{
    String province=null
    String city=null
}
class HCExtension{
    String myName = null;

}

再新建一個Plugin(同樣也放入build.gradle中)：

class TestExtensionPlugin implements Plugin<Project> {

    @Override
    void apply(Project project) {

        project.extensions.create('hc', HCExtension);
        project.extensions.create('address', Address);

        project.task('readExtension') << {
            def address=project['address']

            println project['hc'].myName
            println address.province+" "+address.city

        }
    }
}

接下來就是把你的配置放進去啦(同樣也放入build.gradle中)：

apply plugin: TestExtensionPlugin

hc {
    address{
       province "HuBei"
        city "WuHan"
    }

    myName "huachao"

}

稍微解釋一下，apply plugin: TestExtensionPlugin這一行會導致直接執行TestExtensionPlugin類的apply方法。所以，hc{}這個塊必須放在apply plugin: TestExtensionPlugin之后，因為在沒有執行project.extensions.create('hc', HCExtension);之前，使用hc{}會報錯！address{}也是同理。另外，補充一下：project.extensions相當于project.getExtensions()即返回的是ExtensionContainer對象，而ExtensionContainer對象的create方法就是把hc{}與HCExtension對應起來。其他通過project.的方式也是同樣的道理。再看看project.task('readExtension')，這是創建一個task。相當于在build.gradle文件中的task xxx <<{}只不過這里是通過代碼的方式動態創建.

此時你的buildsrc模塊中的build.gradle文件應該如下：

apply plugin: 'groovy'

dependencies {
    compile gradleApi()//gradle sdk
    compile localGroovy()//groovy sdk
    compile 'com.android.tools.build:gradle:2.1.0'
}

repositories {
    jcenter()
}
class Address{
    String province=null
    String city=null
}
class HCExtension{
    String myName = null;

}

class TestExtensionPlugin implements Plugin<Project> {

    @Override
    void apply(Project project) {

        project.extensions.create('hc', HCExtension);
        project.extensions.create('address', Address);

        project.task('readExtension') << {
            def address=project['address']

            println project['hc'].myName
            println address.province+" "+address.city

        }
    }
}

apply plugin: TestExtensionPlugin

hc {
    address{
       province "HuBei"
        city "WuHan"
    }

    myName "huachao"

}

點擊buildsrc模塊中的readExtension如下圖：

image

看看打印信息

···
:buildsrc:readExtension
huachao
HuBei WuHan

···

關于Project對象先介紹到這里，更多內容請查看官方網站：https://docs.gradle.org/current/javadoc/org/gradle/api/Project.html

2 修改編譯后的class

接下來回到我們的主題，我們需要修改class文件，首先我們得知道什么時候編譯完成，并且我們要趕在class文件被轉化為dex文件之前去修改。從1.5.0-beta1開始，android的gradle插件引入了com.android.build.api.transform.Transform，可以點擊 http://tools.android.com/tech-docs/new-build-system/transform-api 查看相關內容。Transform每次都是將一個輸入進行處理，然后將處理結果輸出，而輸出的結果將會作為另一個Transform的輸入，過程如下：

image

注意，輸出地址不是由你任意指定的。而是根據輸入的內容、作用范圍等由TransformOutputProvider生成，比如，你要獲取輸出路徑：

 String dest = outputProvider.getContentLocation(directoryInput.name,
                        directoryInput.contentTypes, directoryInput.scopes, Format.DIRECTORY)

Transform是一個抽象類，我們先自定義一個Transform，如下：

package com.hc.plugin

import com.android.build.api.transform.*
import com.android.build.gradle.internal.pipeline.TransformManager
import org.apache.commons.codec.digest.DigestUtils
import org.apache.commons.io.FileUtils
import org.gradle.api.Project

/**
 * Created by HuaChao on 2016/7/4.
 */
public class MyTransform extends Transform {

    Project project

    // 構造函數，我們將Project保存下來備用
    public MyTransform(Project project) {
        this.project = project
    }

    // 設置我們自定義的Transform對應的Task名稱
    // 類似：TransformClassesWithPreDexForXXX
    @Override
    String getName() {
        return "MyTrans"
    }

    // 指定輸入的類型，通過這里的設定，可以指定我們要處理的文件類型
    //這樣確保其他類型的文件不會傳入
    @Override
    Set<QualifiedContent.ContentType> getInputTypes() {
        return TransformManager.CONTENT_CLASS
    }

    // 指定Transform的作用范圍
    @Override
    Set<QualifiedContent.Scope> getScopes() {
        return TransformManager.SCOPE_FULL_PROJECT
    }

    @Override
    boolean isIncremental() {
        return false
    }

//具體的處理
    @Override
    void transform(Context context, Collection<TransformInput> inputs,
                   Collection<TransformInput> referencedInputs,
                   TransformOutputProvider outputProvider, boolean isIncremental)
            throws IOException, TransformException, InterruptedException {

    }
}

看到函數transform,我們還沒有具體實現這個函數。這個函數就是具體如何處理輸入和輸出?？梢赃\行一下看看，注意，這里的運行時直接編譯執行我們的apk，而不是像之前那樣直接rebuild，因為rebuild并沒有執行到編譯這一步。由于我們沒有實現transform這個函數，導致沒有輸出！使得整個過程中斷了！最終導致apk運行時找不到MainActivity，所以會報錯。接下來我們去實現以下這個函數，我們啥也不干，就是把輸入內容寫入到作為輸出內容，不做任何處理，（下面代碼參考自這里）：

@Override
void transform(Context context, Collection<TransformInput> inputs,
               Collection<TransformInput> referencedInputs,
               TransformOutputProvider outputProvider, boolean isIncremental)
        throws IOException, TransformException, InterruptedException {
    // Transform的inputs有兩種類型，一種是目錄，一種是jar包，要分開遍歷
    inputs.each {TransformInput input ->
        //對類型為“文件夾”的input進行遍歷
            input.directoryInputs.each {DirectoryInput directoryInput->
             //文件夾里面包含的是我們手寫的類以及R.class、BuildConfig.class以及R$XXX.class等

            // 獲取output目錄
            def dest = outputProvider.getContentLocation(directoryInput.name,
                    directoryInput.contentTypes, directoryInput.scopes, 
                    Format.DIRECTORY)

            // 將input的目錄復制到output指定目錄
            FileUtils.copyDirectory(directoryInput.file, dest)
        }
    //對類型為jar文件的input進行遍歷
        input.jarInputs.each {JarInput jarInput->

            //jar文件一般是第三方依賴庫jar文件

            // 重命名輸出文件（同目錄copyFile會沖突）
            def jarName = jarInput.name
            def md5Name = DigestUtils.md5Hex(jarInput.file.getAbsolutePath())
            if(jarName.endsWith(".jar")) {
                jarName = jarName.substring(0,jarName.length()-4)
            }
            //生成輸出路徑
            def dest = outputProvider.getContentLocation(jarName+md5Name, 
                         jarInput.contentTypes, jarInput.scopes, Format.JAR)
            //將輸入內容復制到輸出
            FileUtils.copyFile(jarInput.file, dest)
        }
    }
}

注意input的類型，分為"文件夾"和“jar文件”，"文件夾"里面的就是我們寫的類對應的class文件，jar文件一般為第三方庫。此時，能成功運行，但是我們還沒有注入代碼呢_{，下面我們看看如何注入代碼}

3 Javassist

要修改class字節碼，我們要是自己手動改二進制文件，有點困難，好在有Javassist這個庫，可以讓我們直接修改編譯后的class二進制代碼。關于Javassist的使用，這里不介紹，可以自行搜索。要使用到Javassist，我們得在buildsrc模塊下的build.gradle添加依賴包：

compile 'org.javassist:javassist:3.20.0-GA'

使用Javassist也很簡單，首先拿到ClassPool對象，通過ClassPool獲取已經編譯好的類，如：

ClassPool pool = ClassPool.getDefault();
CtClass cc = pool.get("com.hc.MyClass");
cc.setSuperclass(pool.get("com.hc.ParentClass"));
cc.writeFile();

上面代碼就實現了修改MyClass類的父類為ParentClass.

要獲取字節碼以及加載為Class對象，如下：

byte[] b = cc.toBytecode();
Class clazz = cc.toClass();

前面提到，我們自己創建的Java類編譯后是放入到文件夾里面的，因此，我們只需針對這個文件夾里面的class文件進行修改即可，新建一個Groovy類：

package com.hc.plugin

import javassist.ClassPool
import javassist.CtClass
import javassist.CtConstructor
public class MyInject {

    private static ClassPool pool = ClassPool.getDefault()
    private static String injectStr = "System.out.println(\"I Love HuaChao\" ); ";

    public static void injectDir(String path, String packageName) {
        pool.appendClassPath(path)
        File dir = new File(path)
        if (dir.isDirectory()) {
            dir.eachFileRecurse { File file ->

                String filePath = file.absolutePath
                //確保當前文件是class文件，并且不是系統自動生成的class文件
                if (filePath.endsWith(".class")
                        && !filePath.contains('R$')
                        && !filePath.contains('R.class')
                        && !filePath.contains("BuildConfig.class")) {
                    // 判斷當前目錄是否是在我們的應用包里面
                    int index = filePath.indexOf(packageName);
                    boolean isMyPackage = index != -1;
                    if (isMyPackage) {
                        int end = filePath.length() - 6 // .class = 6
                        String className = filePath.substring(index, end)
                           .replace('\\', '.').replace('/', '.')
                        //開始修改class文件
                        CtClass c = pool.getCtClass(className)

                        if (c.isFrozen()) {
                            c.defrost()
                        }

                        CtConstructor[] cts = c.getDeclaredConstructors() 
                        if (cts == null || cts.length == 0) {
                            //手動創建一個構造函數
                            CtConstructor constructor = new CtConstructor(new CtClass[0], c)
                            constructor.insertBeforeBody(injectStr)
                            c.addConstructor(constructor)
                        } else {
                            cts[0].insertBeforeBody(injectStr)
                        }
                        c.writeFile(path)
                        c.detach()
                    }
                }
            }
        }
    }

}

然后就是在 transform函數中，針對“文件夾”里面的class進行注入，而jar文件類型的input依然不做處理。transform函數如下：

 @Override
void transform(Context context, Collection<TransformInput> inputs,
               Collection<TransformInput> referencedInputs,
               TransformOutputProvider outputProvider, boolean isIncremental)
        throws IOException, TransformException, InterruptedException {
    // Transform的inputs有兩種類型，一種是目錄，一種是jar包，要分開遍歷
    inputs.each { TransformInput input ->
        //對類型為“文件夾”的input進行遍歷
        input.directoryInputs.each { DirectoryInput directoryInput ->
            //文件夾里面包含的是我們手寫的類以及R.class、BuildConfig.class以及R$XXX.class等
            MyInject.injectDir(directoryInput.file.absolutePath,"com\\hc\\hcplugin")
            // 獲取output目錄
            def dest = outputProvider.getContentLocation(directoryInput.name,
                    directoryInput.contentTypes, directoryInput.scopes,
                    Format.DIRECTORY)

            // 將input的目錄復制到output指定目錄
            FileUtils.copyDirectory(directoryInput.file, dest)
        }
        //對類型為jar文件的input進行遍歷
        input.jarInputs.each { JarInput jarInput ->

            //jar文件一般是第三方依賴庫jar文件

            // 重命名輸出文件（同目錄copyFile會沖突）
            def jarName = jarInput.name
            def md5Name = DigestUtils.md5Hex(jarInput.file.getAbsolutePath())
            if (jarName.endsWith(".jar")) {
                jarName = jarName.substring(0, jarName.length() - 4)
            }
            //生成輸出路徑
            def dest = outputProvider.getContentLocation(jarName + md5Name,
                    jarInput.contentTypes, jarInput.scopes, Format.JAR)
            //將輸入內容復制到輸出
            FileUtils.copyFile(jarInput.file, dest)
        }
    }
}

大功告成，接下來測試一下，在app模塊中，新建一個Test類，在MainActivity中調用new Test()；

Test.java

package com.hc.hcplugin;

/**
 * Created by HuaChao on 2016/7/4.
 */
public class Test {
}

MainActivity.java

package com.hc.hcplugin;

import android.os.Bundle;
import android.support.v7.app.AppCompatActivity;
import android.util.Log;

public class MainActivity extends AppCompatActivity {

    @Override
    protected void onCreate(Bundle savedInstanceState) {
        super.onCreate(savedInstanceState);
        Log.e("--->", "===================");
        new Test();
        Log.e("--->", "===================");
    }

}

運行結果如下：

image

第一個打印是MainActivity的構造函數打印的，第二個是Test的構造函數打印的?？吹竭@里，或許你想說，這有什么用??？難道搞半天就為了打印這么一句話？其實，真的很有用，如果你看過關于熱補丁相關內容，你就知道，還真的需要對每個類加上System.out.println(xxx)。不信你看：

https://mp.weixin.qq.com/s?__biz=MzI1MTA1MzM2Nw==&mid=400118620&idx=1&sn=b4fdd5055731290eef12ad0d17f39d4a&scene=1&srcid=1106Imu9ZgwybID13e7y2nEi#wechat_redirect

附上源碼：http://download.csdn.net/download/huachao1001/9567113

作者：huachao1001
鏈接：http://www.lxweimin.com/p/417589a561da
來源：簡書
著作權歸作者所有。商業轉載請聯系作者獲得授權，非商業轉載請注明出處。

三个男躁一个女,国精产品一区一手机的秘密,麦子交换系列最经典十句话,欧美国产综合欧美视频

通過自定義Gradle插件修改編譯后的class文件

通過自定義Gradle插件修改編譯后的class文件

1 認識Project對象

2 修改編譯后的class

3 Javassist

推薦閱讀更多精彩內容

三个男躁一个女,国精产品一区一手机的秘密,麦子交换系列最经典十句话,欧美 国产 综合 欧美 视频

通過自定義Gradle插件修改編譯后的class文件

1 認識Project對象

2 修改編譯后的class

3 Javassist

推薦閱讀更多精彩內容

三个男躁一个女,国精产品一区一手机的秘密,麦子交换系列最经典十句话,欧美国产综合欧美视频