從1.5.0-beta1開始，android的gradle插件引入了com.android.build.api.transform.Transform
，可以點擊 http://tools.android.com/tech-docs/new-build-system/transform-api 查看相關內容。Transform
每次都是將一個輸入進行處理，然后將處理結果輸出，而輸出的結果將會作為另一個Transform
的輸入，過程如下：
Transform 是 Android Gradle API ，允許第三方插件在class文件轉為dex文件前操作編譯完成的class文件，這個API的引入是為了簡化class文件的自定義操作而無需對Task進行處理。在做代碼插樁時，本質上是在merge{ProductFlavor}{BuildType}Assets Task之后，transformClassesWithDexFor{ProductFlavor}{BuildType} Transform 之前,插入一個transformClassesWith{YourTransformName}For{ProductFlavor}{BuildType} Transform，此Transform中完成對class文件的自定義操作（包括修改父類繼承，方法中的super方法調用，方法參數替換等等，這個class交給你，理論上是可以改到懷疑人生）。
注意，輸出地址不是由你任意指定的。而是根據輸入的內容、作用范圍等由TransformOutputProvider生成，需要通過一下方法獲取獲取輸出路徑：
TransformOutputProvider.getContentLocation
添加依賴
com.android.tools.build:gradle:2.3.3
可以自定義一個Transform子類，然后在Plugin實現類的apply方法中 調用如下代碼注冊Tranform到編譯過程中
//注冊Transform
def android = project.extensions.getByType(AppExtension);
android.registerTransform(this)
為省事直接將上一篇的Plugin實現類繼承Transform，代碼如下
public class PluginImpl extends Transform implements Plugin<Project> {
void apply(Project project) {
//注冊Transform
def android = project.extensions.getByType(AppExtension);
android.registerTransform(this)
}
// 設置我們自定義的Transform對應的Task名稱
// 類似：TransformClassesWithPreDexForXXX
@Override
String getName() {
return "myTestTransform"
}
// 指定輸入的類型，通過這里的設定，可以指定我們要處理的文件類型
//這樣確保其他類型的文件不會傳入
@Override
Set<QualifiedContent.ContentType> getInputTypes() {
return TransformManager.CONTENT_CLASS
}
// 指定Transform的作用范圍
@Override
Set<? super QualifiedContent.Scope> getScopes() {
return TransformManager.SCOPE_FULL_PROJECT
}
@Override
boolean isIncremental() {
return false
}
@Override
void transform(Context context, Collection<TransformInput> inputs, Collection<TransformInput> referencedInputs, TransformOutputProvider outputProvider, boolean isIncremental) throws IOException, TransformException, InterruptedException {
println '==================MyPlugin transform start=================='
inputs.each { TransformInput transformInput ->
// Transform的inputs有兩種類型，一種是目錄，一種是jar包，要分開遍歷
//對類型為“文件夾”的input進行遍歷
transformInput.directoryInputs.each { DirectoryInput directoryInput ->
//文件夾里面包含的是我們手寫的類以及R.class、BuildConfig.class以及R$XXX.class等
MyInject.injectDir(directoryInput.file.absolutePath,"com\\example\\use_plugin")
// 獲取output目錄
def dest = outputProvider.getContentLocation(directoryInput.name,
directoryInput.contentTypes, directoryInput.scopes,
Format.DIRECTORY)
// 將input的目錄復制到output指定目錄
FileUtils.copyDirectory(directoryInput.file, dest)
}
//對類型為jar文件的input進行遍歷
transformInput.jarInputs.each { JarInput jarInput ->
//jar文件一般是第三方依賴庫jar文件
// 重命名輸出文件（同目錄copyFile會沖突）
def jarName = jarInput.name
def md5Name = org.apache.commons.codec.digest.DigestUtils.md5Hex(jarInput.file.getAbsolutePath())
if(jarName.endsWith(".jar")) {
jarName = jarName.substring(0,jarName.length()-4)
}
//生成輸出路徑
def dest = outputProvider.getContentLocation(jarName+md5Name,
jarInput.contentTypes, jarInput.scopes, Format.JAR)
//將輸入內容復制到輸出
FileUtils.copyFile(jarInput.file, dest)
}
}
}
}
MyInject找出特定的類，利用Javassist（同樣功能的修改class文件的框架還有asm，asm與Javassist對比，在這不做重點）修改class文件。
要使用 Javassit添加如下依賴
compile 'org.javassist:javassist:3.20.0-GA'
MyInject源碼如下：
public class MyInject {
private static ClassPool pool = ClassPool.getDefault();
private static String injectStr = "System.out.println(\"inster before =======\" ) "
public static void injectDir(String path, String packageName) {
pool.appendClassPath(path)
File dir = new File(path)
if (dir.isDirectory()) {
dir.eachFileRecurse { File file ->
String filePath = file.absolutePath
//確保當前文件是class文件，并且不是系統自動生成的class文件
if (filePath.endsWith(".class")
&& !filePath.contains('R$')
&& !filePath.contains('R.class')
&& !filePath.contains("BuildConfig.class")) {
// 判斷當前目錄是否是在我們的應用包里面
int index = filePath.indexOf(packageName);
boolean isMyPackage = index != -1;
if (isMyPackage) {
int end = filePath.length() - 6 // .class = 6
String className = filePath.substring(index, end)
.replace('\\', '.').replace('/', '.')
//開始修改class文件
CtClass c = pool.getCtClass(className)
if (c.isFrozen()) {
c.defrost()
}
CtConstructor[] cts = c.getDeclaredConstructors()
if (cts == null || cts.length == 0) {
//手動創建一個構造函數
CtConstructor constructor = new CtConstructor(new CtClass[0], c)
constructor.insertBeforeBody(injectStr)
c.addConstructor(constructor)
} else {
//如果已經有構造函數，則添加一行打印代碼
cts[0].insertBeforeBody(injectStr)
}
c.writeFile(path)
c.detach()
}
}
}
}
}
}
以上只是簡單的修改已有class字節碼文件，利用該技術可以實現無痕埋點等深層次更能
