在上一篇文章中我們分析cache_t的寫入流程，有寫入那么就會有讀取，這篇文章分析cache_t的讀取流程

什么是Runtime

我們都知道Runtime被稱為運(yùn)行時(shí)，他與編譯時(shí)的區(qū)別

• 運(yùn)行時(shí) 是代碼跑起來，被裝載到內(nèi)存中的過程，如果此時(shí)出錯(cuò)，則程序會崩潰，是一個(gè)動態(tài)階段
• 編譯時(shí) 是源代碼翻譯成機(jī)器能識別的代碼的過程，主要是對語言進(jìn)行最基本的檢查報(bào)錯(cuò)，即詞法分析、語法分析等，是一個(gè)靜態(tài)的階段

我們可以通過以下三種方式實(shí)現(xiàn)Runtime

• 調(diào)用自定義的OC方法，例如 [person sayNB]
• 調(diào)用NSObject方法 ,例如isKindOfClass
• 通過Runtime API，例如class_getInstanceSize
  
  Runtime三種方式及底層的關(guān)系

探索方法的本質(zhì)

方法的本質(zhì)

在OC底層04：isa和類的關(guān)聯(lián)文章中通過clang編譯源碼，了解了OC對象的本質(zhì)。同理，我們可以通過clang編輯main.cpp文件，查看main函數(shù)中方法調(diào)用的實(shí)現(xiàn)，如下所示

//main.m中方法的調(diào)用
LGPerson *person = [LGPerson alloc];
[person sayNB];
[person sayHello];

//clang編譯后的底層實(shí)現(xiàn)
LGPerson *person = ((LGPerson *(*)(id, SEL))(void *)objc_msgSend)((id)objc_getClass("LGPerson"), sel_registerName("alloc"));
((void (*)(id, SEL))(void *)objc_msgSend)((id)person, sel_registerName("sayNB"));
((void (*)(id, SEL))(void *)objc_msgSend)((id)person, sel_registerName("sayHello"));

通過上述代碼可以得出結(jié)論，方法的本質(zhì)就是objc_msgSend消息發(fā)送
我們可以通過objc_msgSend方法來替換[person sayNB]的調(diào)用，查看打印地址是否一致來驗(yàn)證。

注：
1、直接調(diào)用objc_msgSend，需要導(dǎo)入頭文件#import <objc/message.h>
2、需要將target --> Build Setting -->搜索msg -- 將enable strict checking of obc_msgSend calls由YES 改為NO，將嚴(yán)厲的檢查機(jī)制關(guān)掉，否則objc_msgSend的參數(shù)會報(bào)錯(cuò)

LGPerson *person = [LGPerson alloc];   
objc_msgSend(person,sel_registerName("sayNB"));
[person sayNB];

打印結(jié)果如下、發(fā)現(xiàn)是一致的，所以[person sayNB]等價(jià)于objc_msgSend(person,sel_registerName("sayNB"))

objc_msgSend與方法調(diào)用結(jié)果打印

對象方法調(diào)用--父類方法

我們可以嘗試讓person通過調(diào)用objc_msgSendSuper執(zhí)行父類方法實(shí)現(xiàn)，

• 定義兩個(gè)類LGPerson(子類) 和 LGTeacher(父類)，父類中實(shí)現(xiàn)了sayHello方法,子類中調(diào)用。
• main函數(shù)中調(diào)用

LGPerson *person = [LGPerson alloc];
LGTeacher *teacher = [LGTeacher alloc];
[person sayHello];

struct objc_super lgsuper;
lgsuper.receiver = person; //消息的接收者還是person
lgsuper.super_class = [LGTeacher class]; //告訴父類是誰
    
//消息的接受者還是自己 - 父類 - 請你直接找我的父親
objc_msgSendSuper(&lgsuper, sel_registerName("sayHello"));

打印結(jié)果如下

子類方法調(diào)用轉(zhuǎn)為執(zhí)行父類的實(shí)現(xiàn)打印結(jié)果

發(fā)現(xiàn)不論是[person sayHello]還是objc_msgSendSuper執(zhí)行的是父類中的syaHello的實(shí)現(xiàn)，所以我們可以得出一個(gè)猜想方法調(diào)用，首先在本類中查找，如果本類中沒有，回到父類中查找

objc_msgSendSuper方法中有兩個(gè)參數(shù)（結(jié)構(gòu)體，sel），其結(jié)構(gòu)體類型objc_super定義的結(jié)構(gòu)體對象，并且需要指定receiver和super_class兩個(gè)屬性，源碼實(shí)現(xiàn)和定義如下

• objc_msgSendSuper方法參數(shù)
  
  objc_msgSendSuper方法對應(yīng)參數(shù)
• objc_super源碼定義
  
  objc_super源碼

objc_msgSend快速查找流程分析

在objc-781源碼中，搜索objc_msgSend，由于我們?nèi)粘ｉ_發(fā)的架構(gòu)是arm64，所以需要在arm64.s后綴的文件中查找objc_msgSend源碼實(shí)現(xiàn)，發(fā)現(xiàn)是匯編實(shí)現(xiàn)，其匯編執(zhí)行流程圖如下：

方法快速查找流程

objc_msgSend匯編源碼

objc_msgSend是消息發(fā)送的入口，使用匯編實(shí)現(xiàn)的，實(shí)現(xiàn)源碼如下

//---- 消息發(fā)送 -- 匯編入口--objc_msgSend主要是拿到接收者的isa信息
ENTRY _objc_msgSend 
//---- 無窗口
    UNWIND _objc_msgSend, NoFrame 
    
//---- p0 和空對比，即判斷接收者是否存在，其中p0是objc_msgSend的第一個(gè)參數(shù)-消息接收者receiver
    cmp p0, #0          // nil check and tagged pointer check 
//---- le小于 --支持taggedpointer（小對象類型）的流程
#if SUPPORT_TAGGED_POINTERS
    b.le    LNilOrTagged        //  (MSB tagged pointer looks negative) 
#else
//---- p0 等于 0 時(shí)，直接返回 空
    b.eq    LReturnZero 
#endif 
//---- p0即receiver 肯定存在的流程
//---- 根據(jù)對象拿出isa ，即從x0寄存器指向的地址 取出 isa，存入 p13寄存器
    ldr p13, [x0]       // p13 = isa 
//---- 在64位架構(gòu)下通過 p16 = isa（p13） & ISA_MASK，拿出shiftcls信息，得到class信息
    GetClassFromIsa_p16 p13     // p16 = class 
LGetIsaDone:
    // calls imp or objc_msgSend_uncached 
//---- 如果有isa，走到CacheLookup 即緩存查找流程，也就是所謂的sel-imp快速查找流程
    CacheLookup NORMAL, _objc_msgSend

#if SUPPORT_TAGGED_POINTERS
LNilOrTagged:
//---- 等于空，返回空
    b.eq    LReturnZero     // nil check 

    // tagged
    adrp    x10, _objc_debug_taggedpointer_classes@PAGE
    add x10, x10, _objc_debug_taggedpointer_classes@PAGEOFF
    ubfx    x11, x0, #60, #4
    ldr x16, [x10, x11, LSL #3]
    adrp    x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGE
    add x10, x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGEOFF
    cmp x10, x16
    b.ne    LGetIsaDone

    // ext tagged
    adrp    x10, _objc_debug_taggedpointer_ext_classes@PAGE
    add x10, x10, _objc_debug_taggedpointer_ext_classes@PAGEOFF
    ubfx    x11, x0, #52, #8
    ldr x16, [x10, x11, LSL #3]
    b   LGetIsaDone
// SUPPORT_TAGGED_POINTERS
#endif

LReturnZero:
    // x0 is already zero
    mov x1, #0
    movi    d0, #0
    movi    d1, #0
    movi    d2, #0
    movi    d3, #0
    ret

    END_ENTRY _objc_msgSend

主要有以下幾步

• 【第一步】判斷objc_msgSend方法的第一個(gè)參數(shù)receiver是否為空
  • 如果支持tagged pointer，跳轉(zhuǎn)至LNilOrTagged
    • 如果小對象為空，則直接返回空,即LReturenZero
    • 如果小對象不為空，則處理小對象的isa，跳轉(zhuǎn)到【第二步】
  • 如果不是小對象類型并且receiver也不為空
    • 從receiver中取出isa存入p13寄存器
    • 通過GetClassFromIsa_p16中，然后跳轉(zhuǎn)到【第二步】
      arm64架構(gòu)下通過isa & ISA_MASK獲取shiftcls位域的類信息，即class，GetClassFromIsa_p16的匯編實(shí)現(xiàn)如下：

.macro GetClassFromIsa_p16 /* src */
//---- 此處用于watchOS
#if SUPPORT_INDEXED_ISA 
    // Indexed isa
//---- 將isa的值存入p16寄存器
    mov p16, $0         // optimistically set dst = src 
    tbz p16, #ISA_INDEX_IS_NPI_BIT, 1f  // done if not non-pointer isa -- 判斷是否是 nonapointer isa
    // isa in p16 is indexed
//---- 將_objc_indexed_classes所在的頁的基址 讀入x10寄存器
    adrp    x10, _objc_indexed_classes@PAGE 
//---- x10 = x10 + _objc_indexed_classes(page中的偏移量) --x10基址 根據(jù) 偏移量 進(jìn)行 內(nèi)存偏移
    add x10, x10, _objc_indexed_classes@PAGEOFF
//---- 從p16的第ISA_INDEX_SHIFT位開始，提取 ISA_INDEX_BITS 位 到 p16寄存器，剩余的高位用0補(bǔ)充
    ubfx    p16, p16, #ISA_INDEX_SHIFT, #ISA_INDEX_BITS  // extract index 
    ldr p16, [x10, p16, UXTP #PTRSHIFT] // load class from array
1:

//--用于64位系統(tǒng)
#elif __LP64__ 
    // 64-bit packed isa
//---- p16 = class = isa & ISA_MASK(位運(yùn)算 & 即獲取isa中的shiftcls信息)
    and p16, $0, #ISA_MASK 

#else
    // 32-bit raw isa ---- 用于32位系統(tǒng)
    mov p16, $0

#endif

.endmacro

• 【第二步】獲取isa后，進(jìn)入慢速查找流程CacheLookup NORMAL

CacheLookup 緩存查找匯編源碼

//！！！！！！！！！重點(diǎn)！！！！！！！！！！！！
.macro CacheLookup 
    //
    // Restart protocol:
    //
    //   As soon as we're past the LLookupStart$1 label we may have loaded
    //   an invalid cache pointer or mask.
    //
    //   When task_restartable_ranges_synchronize() is called,
    //   (or when a signal hits us) before we're past LLookupEnd$1,
    //   then our PC will be reset to LLookupRecover$1 which forcefully
    //   jumps to the cache-miss codepath which have the following
    //   requirements:
    //
    //   GETIMP:
    //     The cache-miss is just returning NULL (setting x0 to 0)
    //
    //   NORMAL and LOOKUP:
    //   - x0 contains the receiver
    //   - x1 contains the selector
    //   - x16 contains the isa
    //   - other registers are set as per calling conventions
    //
LLookupStart$1:

//---- p1 = SEL, p16 = isa --- #define CACHE (2 * __SIZEOF_POINTER__)，其中 __SIZEOF_POINTER__表示pointer的大小 ，即 2*8 = 16
//---- p11 = mask|buckets -- 從x16（即isa）中平移16字節(jié)，取出cache 存入p11寄存器 -- isa距離cache 正好16字節(jié)：isa（8字節(jié)）-superClass（8字節(jié)）-cache（mask高16位 + buckets低48位）
    ldr p11, [x16, #CACHE]              
//---- 64位真機(jī)
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16 
//--- p11(cache) & 0x0000ffffffffffff ，mask高16位抹零，得到buckets 存入p10寄存器-- 即去掉mask，留下buckets
    and p10, p11, #0x0000ffffffffffff   // p10 = buckets 
    
//--- p11(cache)右移48位，得到mask（即p11 存儲mask），mask & p1(msgSend的第二個(gè)參數(shù) cmd-sel) ，得到sel-imp的下標(biāo)index（即搜索下標(biāo)） 存入p12（cache insert寫入時(shí)的哈希下標(biāo)計(jì)算是 通過 sel & mask，讀取時(shí)也需要通過這種方式）
    and p12, p1, p11, LSR #48       // x12 = _cmd & mask 

//--- 非64位真機(jī)
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4 
    and p10, p11, #~0xf         // p10 = buckets
    and p11, p11, #0xf          // p11 = maskShift
    mov p12, #0xffff
    lsr p11, p12, p11               // p11 = mask = 0xffff >> p11
    and p12, p1, p11                // x12 = _cmd & mask
#else
#error Unsupported cache mask storage for ARM64.
#endif

//--- p12是下標(biāo) p10是buckets數(shù)組首地址，下標(biāo) * 1<<4(即16) 得到實(shí)際內(nèi)存的偏移量，通過buckets的首地址偏移，獲取bucket存入p12寄存器
//--- LSL #(1+PTRSHIFT)-- 實(shí)際含義就是得到一個(gè)bucket占用的內(nèi)存大小 -- 相當(dāng)于mask = occupied -1-- _cmd & mask -- 取余數(shù)
    add p12, p10, p12, LSL #(1+PTRSHIFT)   
                     // p12 = buckets + ((_cmd & mask) << (1+PTRSHIFT)) -- PTRSHIFT是3
                     
//--- 從x12（即p12）中取出 bucket 分別將imp和sel 存入 p17（存儲imp） 和 p9（存儲sel）
    ldp p17, p9, [x12]      // {imp, sel} = *bucket 
    
//--- 比較 sel 與 p1（傳入的參數(shù)cmd）
1:  cmp p9, p1          // if (bucket->sel != _cmd) 
//--- 如果不相等，即沒有找到，請?zhí)D(zhuǎn)至 2f
    b.ne    2f          //     scan more 
//--- 如果相等 即cacheHit 緩存命中，直接返回imp
    CacheHit $0         // call or return imp 
    
2:  // not hit: p12 = not-hit bucket
//--- 如果一直都找不到， 因?yàn)槭莕ormal ，跳轉(zhuǎn)至__objc_msgSend_uncached
    CheckMiss $0            // miss if bucket->sel == 0 
//--- 判斷p12（下標(biāo)對應(yīng)的bucket） 是否 等于 p10（buckets數(shù)組第一個(gè)元素，），如果等于，則跳轉(zhuǎn)至第3步
    cmp p12, p10        // wrap if bucket == buckets 
//--- 定位到最后一個(gè)元素（即第一個(gè)bucket）
    b.eq    3f 
//--- 從x12（即p12 buckets首地址）- 實(shí)際需要平移的內(nèi)存大小BUCKET_SIZE，得到得到第二個(gè)bucket元素，imp-sel分別存入p17-p9，即向前查找
    ldp p17, p9, [x12, #-BUCKET_SIZE]!  // {imp, sel} = *--bucket 
//--- 跳轉(zhuǎn)至第1步，繼續(xù)對比 sel 與 cmd
    b   1b          // loop 

3:  // wrap: p12 = first bucket, w11 = mask
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
//--- 人為設(shè)置到最后一個(gè)元素
//--- p11（mask）右移44位 相當(dāng)于mask左移4位，直接定位到buckets的最后一個(gè)元素，緩存查找順序是向前查找
    add p12, p12, p11, LSR #(48 - (1+PTRSHIFT)) 
                    // p12 = buckets + (mask << 1+PTRSHIFT) 
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
    add p12, p12, p11, LSL #(1+PTRSHIFT)
                    // p12 = buckets + (mask << 1+PTRSHIFT)
#else
#error Unsupported cache mask storage for ARM64.
#endif

    // Clone scanning loop to miss instead of hang when cache is corrupt.
    // The slow path may detect any corruption and halt later.
//--- 再查找一遍緩存()
//--- 拿到x12（即p12）bucket中的 imp-sel 分別存入 p17-p9
    ldp p17, p9, [x12]      // {imp, sel} = *bucket 
    
//--- 比較 sel 與 p1（傳入的參數(shù)cmd）
1:  cmp p9, p1          // if (bucket->sel != _cmd) 
//--- 如果不相等，即走到第二步
    b.ne    2f          //     scan more 
//--- 如果相等 即命中，直接返回imp
    CacheHit $0         // call or return imp  
    
2:  // not hit: p12 = not-hit bucket
//--- 如果一直找不到，則CheckMiss
    CheckMiss $0            // miss if bucket->sel == 0 
//--- 判斷p12（下標(biāo)對應(yīng)的bucket） 是否 等于 p10（buckets數(shù)組第一個(gè)元素）-- 表示前面已經(jīng)沒有了，但是還是沒有找到
    cmp p12, p10        // wrap if bucket == buckets 
    b.eq    3f //如果等于，跳轉(zhuǎn)至第3步
//--- 從x12（即p12 buckets首地址）- 實(shí)際需要平移的內(nèi)存大小BUCKET_SIZE，得到得到第二個(gè)bucket元素，imp-sel分別存入p17-p9，即向前查找
    ldp p17, p9, [x12, #-BUCKET_SIZE]!  // {imp, sel} = *--bucket 
//--- 跳轉(zhuǎn)至第1步，繼續(xù)對比 sel 與 cmd
    b   1b          // loop 

LLookupEnd$1:
LLookupRecover$1:
3:  // double wrap
//--- 跳轉(zhuǎn)至JumpMiss 因?yàn)槭莕ormal ，跳轉(zhuǎn)至__objc_msgSend_uncached

    JumpMiss $0 
.endmacro

//以下是最后跳轉(zhuǎn)的匯編函數(shù)
.macro CacheHit
.if $0 == NORMAL
    TailCallCachedImp x17, x12, x1, x16 // authenticate and call imp
.elseif $0 == GETIMP
    mov p0, p17
    cbz p0, 9f          // don't ptrauth a nil imp
    AuthAndResignAsIMP x0, x12, x1, x16 // authenticate imp and re-sign as IMP
9:  ret             // return IMP
.elseif $0 == LOOKUP
    // No nil check for ptrauth: the caller would crash anyway when they
    // jump to a nil IMP. We don't care if that jump also fails ptrauth.
    AuthAndResignAsIMP x17, x12, x1, x16    // authenticate imp and re-sign as IMP
    ret             // return imp via x17
.else
.abort oops
.endif
.endmacro

.macro CheckMiss
    // miss if bucket->sel == 0
.if $0 == GETIMP 
//--- 如果為GETIMP ，則跳轉(zhuǎn)至 LGetImpMiss
    cbz p9, LGetImpMiss
.elseif $0 == NORMAL 
//--- 如果為NORMAL ，則跳轉(zhuǎn)至 __objc_msgSend_uncached
    cbz p9, __objc_msgSend_uncached
.elseif $0 == LOOKUP 
//--- 如果為LOOKUP ，則跳轉(zhuǎn)至 __objc_msgLookup_uncached
    cbz p9, __objc_msgLookup_uncached
.else
.abort oops
.endif
.endmacro

.macro JumpMiss
.if $0 == GETIMP
    b   LGetImpMiss
.elseif $0 == NORMAL
    b   __objc_msgSend_uncached
.elseif $0 == LOOKUP
    b   __objc_msgLookup_uncached
.else
.abort oops
.endif
.endmacro

主要分為以下幾步

• 【第一步】通過cache首地址平移16字節(jié)（因?yàn)樵?code>objc_class中，首地址距離cache正好16字節(jié)，即isa首地址占8字節(jié)，superClass占8字節(jié)），獲取cache，cache中高16位存mask，低16位存buckes，即p11=cache。
• 【第二步】從cache中分別取出buckets和mask，并且mask根據(jù)哈希算法計(jì)算出哈希下標(biāo)
  • 通過cache和掩碼（0x0000ffffffffffff）的&運(yùn)算，將高16位mask抹零，得到buckets的指針地址，即p10=buckets
  • 將cache右移48位，得到mask，即p11=mask
  • 將objc_msgSend的參數(shù)p1（即第二個(gè)參數(shù)_cmd）&mask，通過哈希算法，得到需要查到存儲sel-imp的bucket下標(biāo)index即p12 = index = _cmd & mask ，為什么通過這種方式呢？因?yàn)樵?code>存儲sel-imp時(shí)，也是通過同樣的哈希算法計(jì)算哈希下標(biāo)進(jìn)行存儲，所以讀取也需要通過同樣的方式讀取，如下所示
    
    cache_t存儲sel-imp時(shí)計(jì)算哈希下標(biāo)的哈希算法源碼
  • 【第三步】根據(jù)所得到的哈希下標(biāo)index和buckets首地址，取出哈希下標(biāo)對應(yīng)的bucket
    • 其中PTRSHIFT等于3，左移4位（即2^4=16字節(jié)）的目的是計(jì)算出一個(gè)bucket實(shí)際占用大小，結(jié)構(gòu)體bucket_t中sel占8字節(jié)，imp占8字節(jié)
    • 根據(jù)計(jì)算的哈希下標(biāo)index 乘以單個(gè)bucket占用的內(nèi)存大小，得到buckets首地址在實(shí)際內(nèi)存中的偏移量
    • 通過首地址 + 偏移量，獲取哈希下標(biāo)index對應(yīng)的bucket
  • 【第四步】 根據(jù)獲取的bucket，去除其中的imp存入p17，即p17 = imp，取出sel存入p9，即p9 = sel
  • 【第五步】第一次遞歸循環(huán)
    • 比較獲取bucket中sel與objc_msgSend的第二個(gè)參數(shù)的_cmd(即p1)是否相等
    • 如果相等，則直接跳轉(zhuǎn)至CacheHit，即緩存命中，返回imp
    • 如果不相等，有以下兩種情況
      • 如果一直找不到，直接跳轉(zhuǎn)到CheckMiss，因?yàn)?code>$0是nomal，會跳轉(zhuǎn)到__objc_msgSend_uncached，即進(jìn)入慢速查找流程
      • 如果根據(jù)index獲取的bucket==buckets的第一個(gè)元素，則人為的將當(dāng)前bucket設(shè)置為buckets的最后一個(gè)元素（通過buckets首地址+mask右移44位（等于左移4位）直接定位到buckets的最后一個(gè)元素）,然后繼續(xù)進(jìn)行遞歸循環(huán)（第一個(gè)遞歸循環(huán)嵌套第二個(gè)遞歸循環(huán)），即【第六步】
  • 【第六步】第二次遞歸循環(huán)，重復(fù)【第五步】的操作，與【第五步】的操作中唯一的區(qū)別是，如果當(dāng)前的bucket還是等于buckets的一個(gè)元素，則直接跳轉(zhuǎn)JumpMiss，此時(shí)$0是nomal，也是直接跳轉(zhuǎn)至__objc_msgSend_uncached，進(jìn)入慢速查找流程

以下是整個(gè)快速查找過程值得變化過程

值變化過程