https://blog.csdn.net/zzhouqianq/article/details/78646861

使用awk解析JSON

使用

json='{"country":"China", "address":{"province":"guangdong","city":"shenzhen","numberOfPeople":17682000}, "numberOfPeople":"One billion four hundred million"}'

country=`getJsonValuesByAwk "$json" "country" "default"`
address=`getJsonValuesByAwk "$json" "address" ""`
province=`getJsonValuesByAwk "$address" "province" ""`
city=`getJsonValuesByAwk "$address" "city" ""`
numberOfPeople=`getJsonValuesByAwk "$json" "numberOfPeople" "a lot of"`

echo $country #"China"
echo $address #{"province":"guangdong","city":"shenzhen","numberOfPeople":17682000}
echo $province #"guangdong"
echo $city #"shenzhen"
echo $numberOfPeople #17682000 "One billion four hundred million"

原方法如下

### 方法簡要說明：
### 1. 是先查找一個字符串：帶雙引號的key。如果沒找到，則直接返回defaultValue。
### 2. 查找最近的冒號，找到后認為值的部分開始了，直到在層數上等于0時找到這3個字符：,}]。
### 3. 如果有多個同名key，則依次全部打印（不論層級，只按出現順序）
### @author lux feary
###
### 3 params: json, key, defaultValue
function getJsonValuesByAwk() {
    awk -v json="$1" -v key="$2" -v defaultValue="$3" 'BEGIN{
        foundKeyCount = 0
        while (length(json) > 0) {
            # pos = index(json, "\""key"\""); ## 這行更快一些，但是如果有value是字符串，且剛好與要查找的key相同，會被誤認為是key而導致值獲取錯誤
            pos = match(json, "\""key"\"[ \\t]*?:[ \\t]*");
            if (pos == 0) {if (foundKeyCount == 0) {print defaultValue;} exit 0;}

            ++foundKeyCount;
            start = 0; stop = 0; layer = 0;
            for (i = pos + length(key) + 1; i <= length(json); ++i) {
                lastChar = substr(json, i - 1, 1)
                currChar = substr(json, i, 1)

                if (start <= 0) {
                    if (lastChar == ":") {
                        start = currChar == " " ? i + 1: i;
                        if (currChar == "{" || currChar == "[") {
                            layer = 1;
                        }
                    }
                } else {
                    if (currChar == "{" || currChar == "[") {
                        ++layer;
                    }
                    if (currChar == "}" || currChar == "]") {
                        --layer;
                    }
                    if ((currChar == "," || currChar == "}" || currChar == "]") && layer <= 0) {
                        stop = currChar == "," ? i : i + 1 + layer;
                        break;
                    }
                }
            }

            if (start <= 0 || stop <= 0 || start > length(json) || stop > length(json) || start >= stop) {
                if (foundKeyCount == 0) {print defaultValue;} exit 0;
            } else {
                print substr(json, start, stop - start);
            }

            json = substr(json, stop + 1, length(json) - stop)
        }
    }'
}

使用第三方jq

官網：https://stedolan.github.io/jq/
參考：https://cloud.tencent.com/developer/article/1393873
參考：http://www.lxweimin.com/p/6de3cfdbdb0e

brew install jq