plugins {
    id("com.android.application")
    kotlin("android")
    kotlin("kapt")
}
android {
    compileSdkVersion(29)
    defaultConfig {
        applicationId = "com.xxx.xxxxx"
        minSdkVersion(21)
        targetSdkVersion(29)
        versionCode = 27
        versionName = "2.2.0"
        resConfigs("zh")
        ndk {
              abiFilters += listOf("armeabi-v7a","arm64-v8a")
        }
    }

    //開啟dataBinding
    buildFeatures {
        dataBinding = true
    }

    //圖片已壓縮 指定aapt不做圖片壓縮 因為可能會反而增加圖片大小
    aaptOptions {
//        cruncherEnabled = false
    }

    //關閉lint檢查
    lintOptions {
        disable("ResourceType")
//        abortOnError  = false
    }

    //jniLibs目錄指向libs目錄
    sourceSets {
        getByName("main") {
            jniLibs.srcDirs("libs")
        }
    }

    //優化transformClassDexBuilderForDebug的時間
    dexOptions {
        preDexLibraries = true
        maxProcessCount = 8
    }

    //禁止生成依賴元數據 不上play用不到
    dependenciesInfo {
        includeInApk = false
    }

    //jdk1.8支持
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
    }

    kotlinOptions {
        jvmTarget = JavaVersion.VERSION_1_8.toString()
    }

    //簽名配置
    signingConfigs {
        getByName("debug") {
            storeFile = file("../xxx.jks")
            storePassword = "xxx"
            keyAlias = "xxx"
            keyPassword = "xxx"
        }
    }

    buildTypes {
        getByName("debug") {
            //簽名
            signingConfig = signingConfigs.getByName("debug")
            //git提交次數 作為測試包版本后綴
            buildConfigField("int", "GIT_COMMIT_COUNT", getGitCommitCount())
        }
        register("alpha") {
            //繼承debug配置
            initWith(getByName("debug"))
            //混淆
            isMinifyEnabled = true
            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
            //ZipAlignEnabled優化
            isZipAlignEnabled = true
            //移除無用的resource文件
            isShrinkResources = true
        }
        getByName("release") {
            //繼承alpha配置
            initWith(getByName("alpha"))
            //關閉debug
            debuggable(false)
        }
    }

    //release打包時自定義apk名字、輸出路徑
    android.applicationVariants.all {
        outputs.all {
            if (this is com.android.build.gradle.internal.api.ApkVariantOutputImpl) {
                this.outputFileName = "xxxx.apk"
            }
        }
    }
}

//獲取git提交次數
fun getGitCommitCount(): String {
    val os = org.apache.commons.io.output.ByteArrayOutputStream()
    project.exec {
        commandLine = "git rev-list --count HEAD".split(" ")
        standardOutput = os
    }
    return String(os.toByteArray()).trim()
}

//依賴庫
apply(from = "depends.gradle")