[傅里葉變換算法及盲水印實現]
盲水印，顧名思義就是看不見的水印。今天我們來說下頻域加盲水印。相信大家做過圖像處理的對頻域、時域、空間域概念都有了一定的了解。
空間域，我們日常所見的圖像就是空域。空域添加數字水印的方法是在空間域直接對圖像操作（之所以說的這么繞，是因為不僅僅原圖是空域，原圖的差分等等也是空域），比如將水印直接疊加在圖像上。
頻域：描述信號在頻率方面特性時用到的一種坐標系。在圖像中就是圖像灰度變化強烈的情況，圖像的頻率。
時域：是描述數學函數或物理信號對時間的關系。例如一個信號的時域波形可以表達信號隨著時間的變化。
下邊來說說頻域添加盲水印原理：頻域添加數字水印的方法，是指通過某種變換手段（傅里葉變換，離散余弦變換，小波變換等）將圖像變換到頻域（小波域），在頻域對圖像添加水印，再通過逆變換，將圖像轉換為空間域。相對于空域手段，頻域手段隱匿性更強，抗攻擊性更高。
如果對頻域、傅里葉轉換不太懂得，可以參考這篇文章如果看了此文你還不懂傅里葉變換，那就過來掐死我吧【完整版】,感謝大神。
傅里葉變換公式png
我們有方法將時域信號轉換成為頻域，同樣，我們也能將二維信號（圖像）轉換為頻域。
因為圖像是離散信號，我們實際用的是離散傅里葉變換，在本文采用的都是二維快速傅里葉變換，快速傅里葉變換與離散傅里葉變換等價。
添加盲水印流程：
傅里葉轉換添加水印.png
水印提取是水印疊加的逆過程：
水印提取.png
上邊說了下一些基礎及頻域加盲水印原理。下邊來說下具體代碼，具體代碼用iOS來實現，我們使用OpenCV3來實現，OpenCV3對圖像處理使用 Mat（包含信息有矩陣的大小，用于存儲的方法，矩陣存儲的地址等）的矩陣頭和一個指針指向包含了像素值的矩陣。而OpenCV2是IplImage，如果你在查找資料的時候發現IplImage則是之前的C實現的。因為我們使用OpenCV3是C++實現的只要看懂學會，Android、python等都可以按照其代碼來實現的。
首先我們先來建個工程來添加OpenCV庫，我們這里是pod下來的庫----pod 'OpenCV', '~> 3.2.0'，方便管理。
全局先定義：
cv::Mat _complexImage;
vector<Mat> planes;
vector<Mat> allPlanes;
1.原始圖片UIImage轉Mat進行處理
- (cv::Mat)cvMatFromUIImage:(UIImage *)image
{
UIImage *tmpImage = image;
CGColorSpaceRef colorSpace = CGImageGetColorSpace(tmpImage.CGImage);
CGFloat cols = tmpImage.size.width;
CGFloat rows = tmpImage.size.height;
cv::Mat cvMat(rows, cols, CV_8UC4);
CGContextRef contextRef = CGBitmapContextCreate(cvMat.data,cols,rows,8,cvMat.step[0],colorSpace,kCGImageAlphaNoneSkipLast | kCGBitmapByteOrderDefault);
CGContextDrawImage(contextRef, CGRectMake(0, 0, cols, rows), tmpImage.CGImage);
CGContextRelease(contextRef);
return cvMat;
}
2.為了加快傅里葉轉換速度，先對圖片進行尺寸優化
- (cv::Mat)optimizeImageDim:(cv::Mat)image {
Mat padded = Mat();
// get the optimal rows size for dft
int addPixelRows = getOptimalDFTSize(image.rows);
// get the optimal cols size for dft
int addPixelCols = getOptimalDFTSize(image.cols);
// apply the optimal cols and rows size to the image
copyMakeBorder(image, padded, 0, addPixelRows - image.rows, 0, addPixelCols - image.cols, BORDER_CONSTANT, Scalar::all(0));
return padded;
}
3.由于只能在單通道處理，所以要分離圖片多通道
//分離多通道獲取B通道
- (cv::Mat)splitSrc:(cv::Mat) image {
//清空allPlanes
if (!allPlanes.empty()) {
allPlanes.clear();
}
//分離image通道到allPlanes
//先優化
Mat optimizeImage = [self optimizeImageDim:image];
split(optimizeImage,allPlanes);
Mat padded = Mat();
if (allPlanes.size()>1) {
for (int i = 0; i < allPlanes.size();i++) {
if (i == 0) {
// optimize the dimension of the loaded image
//分離之前優化，這里不需要優化
padded = allPlanes[i];
// padded = [self optimizeImageDim:allPlanes[i]];
break;
}
}
} else {
padded = [self optimizeImageDim:image];
}
return padded;
}
4.對圖片進行傅里葉轉換并在頻譜上添加文本
- (void)transformImageWithText:(cv::Mat) image blindMarkText:(NSString *) blindMarkText point:(cv::Point) point fontSize:(double)fontSize scalar:(cv::Scalar) scalar {
// planes數組中存的通道數若開始不為空,需清空.
if (!planes.empty()) {
planes.clear();
}
Mat padded = [self splitSrc:image];
padded.convertTo(padded, CV_32F);
// prepare the image planes to obtain the complex image
planes.push_back(padded);
planes.push_back(cv::Mat::zeros(padded.size(), CV_32F));
// prepare a complex image for performing the dft
merge(planes, _complexImage);
// dft
dft(_complexImage, _complexImage);
// 頻譜圖上添加文本
putText(_complexImage, [blindMarkText UTF8String], point, CV_FONT_HERSHEY_DUPLEX, fontSize, scalar);
flip(_complexImage, _complexImage, -1);
putText(_complexImage, [blindMarkText UTF8String], point, CV_FONT_HERSHEY_DUPLEX, fontSize, scalar);
flip(_complexImage, _complexImage, -1);
planes.clear();
}
5.idft把處理過后的圖片恢復成原圖
- (cv::Mat)antitransformImage {
Mat invDFT ;
idft(_complexImage, invDFT, DFT_SCALE | DFT_REAL_OUTPUT, 0);
Mat restoredImage ;
invDFT.convertTo(restoredImage, CV_8U);
//合并多通道
allPlanes.erase(allPlanes.begin());
allPlanes.insert(allPlanes.begin(), restoredImage);
Mat lastImage ;
merge(allPlanes,lastImage);
return lastImage;
}
6.Mat轉UIImage
- (UIImage *)UIImageFromCVMat:(cv::Mat)cvMat
{
NSData *data = [NSData dataWithBytes:cvMat.data length:cvMat.elemSize()*cvMat.total()];
CGColorSpaceRef colorSpace;
if (cvMat.elemSize() == 1) {
colorSpace = CGColorSpaceCreateDeviceGray();
} else {
colorSpace = CGColorSpaceCreateDeviceRGB();
}
CGDataProviderRef provider = CGDataProviderCreateWithCFData((__bridge CFDataRef)data);
CGImageRef imageRef = CGImageCreate(cvMat.cols, cvMat.rows,8, 8 * cvMat.elemSize(), cvMat.step[0],colorSpace, kCGImageAlphaNone|kCGBitmapByteOrderDefault, provider, NULL, false,kCGRenderingIntentDefault);
UIImage *finalImage = [UIImage imageWithCGImage:imageRef];
CGImageRelease(imageRef);
CGDataProviderRelease(provider);
CGColorSpaceRelease(colorSpace);
return finalImage;
}
到這里我們盲水印所需要的函數、方法已經寫完，具體調用
- (void)fourierConversion {
cv::Mat orignMat = [self cvMatFromUIImage:[UIImage imageNamed:imageName]];
cv::Scalar color = CV_RGB(0,255,255);
[self transformImageWithText:orignMat blindMarkText:@"Test" point:cv::Point(45,45) fontSize:0.8 scalar:color];
cv::Mat cvMat = [self antitransformImage];
self.imgView.image = [self UIImageFromCVMat:cvMat];
}
圖片.jpg
這時候你會發現圖片和原來沒什么區別。是的，確實肉眼看沒有任何區別.
下邊我們獲取到水印:
1.創建優化級
- (cv::Mat)createOptimizedMagnitude:(cv::Mat)complexImage {
// init
vector<Mat> newPlanes = {};
Mat mag = Mat();
// split the comples image in two planes
split(complexImage, newPlanes);
// compute the magnitude
magnitude(newPlanes[0], newPlanes[1], mag);
// move to a logarithmic scale
add(Mat::ones(mag.size(), CV_32F), mag, mag);
// optionally reorder the 4 quadrants of the magnitude image
[self shiftDFT:mag];
// normalize the magnitude image for the visualization
// and OpenCV need images with value between 0 and 255
// convert back to CV_8UC1
mag.convertTo(mag, CV_8UC1);
normalize(mag, mag, 0, 255, NORM_MINMAX, CV_8UC1);
return mag;
}
2.轉化DFT
- (void)shiftDFT:(cv::Mat)image {
image = image(cv::Rect(0, 0, image.cols & (-2), image.rows & (-2)));
int cx = image.cols / 2;
int cy = image.rows / 2;
Mat q0 = Mat(image, cv::Rect(0, 0, cx, cy));
Mat q1 = Mat(image, cv::Rect(cx, 0, cx, cy));
Mat q2 = Mat(image, cv::Rect(0, cy, cx, cy));
Mat q3 = Mat(image, cv::Rect(cx, cy, cx, cy));
Mat tmp = Mat();
q0.copyTo(tmp);
q3.copyTo(q0);
tmp.copyTo(q3);
q1.copyTo(tmp);
q2.copyTo(q1);
tmp.copyTo(q2);
}
3.轉換圖片獲取水印圖
- (cv::Mat)transformImage:(cv::Mat)image {
// planes數組中存的通道數若開始不為空,需清空.
if (!planes.empty()) {
planes.clear();
}
Mat padded = [self splitSrc:image];
padded.convertTo(padded, CV_32F);
// prepare the image planes to obtain the complex image
planes.push_back(padded);
planes.push_back(cv::Mat::zeros(padded.size(), CV_32F));
// prepare a complex image for performing the dft
merge(planes, _complexImage);
// dft
dft(_complexImage, _complexImage);
// optimize the image resulting from the dft operation
Mat magnitude = [self createOptimizedMagnitude:_complexImage];
planes.clear();
return magnitude;
}
獲取水印具體調用：
- (void)reverseFourier {
cv::Mat cvMat = [self antitransformImage];
cvMat = [self transformImage:cvMat];
self.imgView.image = [self UIImageFromCVMat:cvMat];
}
盲水印.png
引用下別人的語言：
頻域添加數字水印的方法，是指通過某種變換手段（傅里葉變換，離散余弦變換，小波變換等）將圖像變換到頻域（小波域），在頻域對圖像添加水印，再通過逆變換，將圖像轉換為空間域。相對于空域手段，頻域手段隱匿性更強，抗攻擊性更高。所謂對水印的攻擊，是指破壞水印，包括涂抹，剪切，放縮，旋轉，壓縮，加噪，濾波等。數字盲水印不僅僅要敏捷性高（不被人抓到），也要防御性強（抗打）。就像Dota的敏捷英雄往往是脆皮，數字盲水印的隱匿性和魯棒性是互斥的。（魯棒性是抗攻擊性的學術名字）。
有許多同學還是不懂，我把核心代碼封成了庫，需要的請自己去clone。
封裝庫地址：https://github.com/miaozhang9/opencvLib.git
