代碼在執行前，一般會編譯成指令。指令就是一個個邏輯，邏輯操作的是數據。代碼，或者說業務，操作的其實是數據。非區塊鏈中，代碼操作的數據，一般會存到數據庫中。
在區塊鏈里，區塊鏈本身就是一個數據庫。如果你使用區塊鏈標記物產的所有權，歸屬信息將會被記錄到區塊鏈上，所有人都無法篡改，以標明不可爭議的擁有權。所以在區塊鏈中編程中，有一個數據位置的屬性用來標識變量是否需要持久化到區塊鏈中。
1. 數據位置的類型
數據位置[1]，變量的存儲位置屬性。有三種類型，memory，storage和calldata。最后一種數據位置比較特殊，一般只有外部函數的參數（不包括返回參數）被強制指定為calldata。這種數據位置是只讀的，不會持久化到區塊鏈。一般我們可以選擇指定的是memory和storage。
memory存儲位置同我們普通程序的內存類似。即分配，即使用，越過作用域即不可被訪問，等待被回收。而對于storage的變量，數據將永遠存在于區塊鏈上。
2. 默認數據位置
2.1 參數及局部變量
默認的函數參數，包括返回的參數，他們是memory。而默認的局部變量是storage的。
pragma solidity ^0.4.0;
contract SimpleAssign{
struct S{string a;uint b;}
//默認參數是memory
function assign(S s) internal{
//默認的變量是storage的指針
//Type struct MemoryToLocalVar.S memory is not implicitly convertible to expected type struct MemoryToLocalVar.S storage pointer.
//S tmp = s;
}
}
在上述示例中，assign()嘗試將一個參數賦值給一個局部變量。具體的報錯信息Error: Type struct memory is not implicitly convertible to expected type storage pointer.。
從報錯可以看出，默認的的參數是memory的，而默認的局部變量是storage的。
2.2 狀態變量
狀態變量，合約內聲明的公有變量。默認的數據位置是storage。
pragma solidity ^0.4.0;
contract StateVariable{
struct S{string a;uint b;}
//狀態變量，默認是storage
S s;
}
3. 數據位置間相互轉換
3.1 storage轉換為storage
當我們把一個storage類型的變量賦值給另一個storage時，我們只是修改了它的指針。
pragma solidity ^0.4.0;
contract StorageConvertToStorage{
struct S{string a;uint b;}
//默認是storage的
S s;
function convertStorage(S storage s) internal{
S tmp = s;
tmp.a = "Test";
}
function call() returns (string){
convertStorage(s);
return s.a;//Test
}
}
在上面的代碼中，我們將傳入的storage變量，賦值給另一個臨時的storage類型的tmp時，并修改tmp.a = "Test"，最后我們發現合約的狀態變量s也被修改了。
3.2 memory轉換為storage
因為局部變量和狀態變量的類型都可能是storage。所以我們要分開來說這兩種情況。
3.2.1 memory賦值給狀態變量
將一個memory類型的變量賦值給一個狀態變量時，實際是將內存變量拷貝到存儲中。
pragma solidity ^0.4.0;
contract MemoryConvertToStateVariable{
struct S{string a;uint b;}
//默認是storage的
S s;
function memoryToState(S memory tmp) internal{
s = tmp;//從內存中復制到狀態變量中。
//修改舊memory中的值，并不會影響狀態變量
tmp.a = "Test";
}
function call() returns(string){
S memory tmp = S("memory", 0);
memoryToState(tmp);
return s.a;
}
}
通過上例，我們發現，在memoryToState()中，我們把tmp賦值給s后，再修改tmp值，并不能產生任何變化。賦值時，完成了值拷貝，后續他們不再有任何的關系。
3.2.2 memory賦值給局部變量
由于在區塊鏈中，storage必須是靜態分配存儲空間的[2]。局部變量雖然是一個storage的，但它僅僅是一個storage類型的指針。如果進行這樣的賦值，實際會產生一個錯誤。
pragma solidity ^0.4.0;
contract MemoryToLocalVar{
struct S{string a;uint b;}
//默認參數是memory
function memoryToLocal(S s) internal{
//默認的變量是storage的指針
//Type struct MemoryToLocalVar.S memory is not implicitly convertible to expected type struct MemoryToLocalVar.S storage pointer.
//S tmp = s;
//修改變量為memory類型
S memory tmp = s;
}
}
通過上面的代碼，我們可以看到這樣的賦值的確不被允許。你可以通過將變量tmp改為memory來完成這樣的賦值。
3.3 storage轉為memory
將storage轉為memory，實際是將數據從storage拷貝到memory中。
pragma solidity ^0.4.0;
contract StorageToMemory{
struct S{string a;uint b;}
S s = S("storage", 1);
function storageToMemory(S storage x) internal{
S memory tmp = x;//由Storage拷貝到memory中
//memory的修改不影響storage
tmp.a = "Test";
}
function call() returns (string){
storageToMemory(s);
return s.a;
}
}
在上面的例子中，我們看到，拷貝后對tmp變量的修改，完全不會影響到原來的storage變量。
3.4 memory轉為memory
memory之間是引用傳遞，并不會拷貝數據。我們來看看下面的代碼。
pragma solidity ^0.4.0;
contract MemoryToMemory{
struct S{string a;uint b;}
//默認參數是memory
function memoryToMemory(S s) internal{
S memory tmp = s;
//引用傳遞
tmp.a = "other memory";
}
function call() returns (string){
S memory mem = S("memory", 1);
memoryToMemory(mem);
return mem.a;//other memory
}
}
在上面的代碼中，memoryToMemory()傳遞進來了一個memory類型的變量，在函數內將之賦值給tmp，修改tmp的值，發現外部的memory也被改為了other memory。
關于作者
專注基于以太坊的相關區塊鏈技術，了解以太坊，Solidity，Truffle。
博客：http://me.tryblockchain.org
