什么是alloc？

分析alloc之前我們來分析一段代碼

#import <Foundation/Foundation.h>
#import "LGPerson.h"

int main(int argc, const char * argv[]) {
   
    LGPerson *p = [LGPerson alloc];
    LGPerson *p1 = [p init];
    LGPerson *p2 = [p init];
    NSLog(@"%@, %p, %p",p,p,&p);
    NSLog(@"%@, %p, %p",p1,p1,&p1);
    NSLog(@"%@, %p, %p",p2,p2,&p2);
    return 0;
}

分別打印出三個對象的 內容 內存地址 對象指針地址 得出結果如下

image.png

第一步：開始分析alloc做了什么

分析alloc 源碼之前我們要先下載objc源碼
下載地址 objc-781
編譯源碼，可參考iOS-底層原理 03：objc4-781 源碼編譯 & 調試

先來一張alloc init 源碼探索流程圖

alloc + init源碼流程圖

• 【第一步】首先根據main函數中的LGPerson類的alloc方法進入alloc方法的源碼實現（即源碼分析開始）

+ (id)alloc {
    return _objc_rootAlloc(self);
}

• 【第二步】跳轉至_objc_rootAlloc的源碼實現

//alloc源碼分析-第二步
id
_objc_rootAlloc(Class cls)
{
    return callAlloc(cls, false/*checkNil*/, true/*allocWithZone*/);
}

• 【第三步】跳轉至callAlloc的源碼實現

static ALWAYS_INLINE id
callAlloc(Class cls, bool checkNil, bool allocWithZone=false)// alloc 源碼 第三步
{
#if __OBJC2__ //有可用的編譯器優化
    /*
     參考鏈接：http://www.lxweimin.com/p/536824702ab6
     */
    
    // checkNil 為false，!cls 也為false ，所以slowpath 為 false，假值判斷不會走到if里面，即不會返回nil
    if (slowpath(checkNil && !cls)) return nil;
    
    //判斷一個類是否有自定義的 +allocWithZone 實現，沒有則走到if里面的實現
    if (fastpath(!cls->ISA()->hasCustomAWZ())) {
        return _objc_rootAllocWithZone(cls, nil);
    }
#endif

    // No shortcuts available. // 沒有可用的編譯器優化
    if (allocWithZone) {
        return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
    }
    return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}

如上所示，在calloc方法中，當我們無法確定實現走到哪步時，可以通過斷點調試，判斷執行走哪部分邏輯。這里是執行到_objc_rootAllocWithZone

• 【第四步】跳轉至_objc_rootAllocWithZone的源碼實現

id
_objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused)// alloc 源碼 第四步
{
    // allocWithZone under __OBJC2__ ignores the zone parameter
    //zone 參數不再使用 類創建實例內存空間
    return _class_createInstanceFromZone(cls, 0, nil,
                                         OBJECT_CONSTRUCT_CALL_BADALLOC);
}

• 【第五步】跳轉至_class_createInstanceFromZone的源碼實現，這部分是alloc源碼的核心操作，由下面的流程圖及源碼可知，該方法的實現主要分為三部分
  • cls->instanceSize：計算需要開辟的內存空間大小
  • calloc：申請內存，返回地址指針
  • obj->initInstanceIsa：將 類 與 isa 關聯

static ALWAYS_INLINE id
_class_createInstanceFromZone(Class cls, size_t extraBytes, void *zone,
                              int construct_flags = OBJECT_CONSTRUCT_NONE,
                              bool cxxConstruct = true,
                              size_t *outAllocatedSize = nil)// alloc 源碼 第五步
{
    ASSERT(cls->isRealized()); //檢查是否已經實現

    // Read class's info bits all at once for performance
    //一次性讀取類的位信息以提高性能
    bool hasCxxCtor = cxxConstruct && cls->hasCxxCtor();
    bool hasCxxDtor = cls->hasCxxDtor();
    bool fast = cls->canAllocNonpointer();
    size_t size;

    //計算需要開辟的內存大小，傳入的extraBytes 為 0
    size = cls->instanceSize(extraBytes);
    if (outAllocatedSize) *outAllocatedSize = size;

    id obj;
    if (zone) {
        obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
    } else {
        //申請內存
        obj = (id)calloc(1, size);
    }
    if (slowpath(!obj)) {
        if (construct_flags & OBJECT_CONSTRUCT_CALL_BADALLOC) {
            return _objc_callBadAllocHandler(cls);
        }
        return nil;
    }

    if (!zone && fast) {
        //將 cls類 與 obj指針（即isa） 關聯
        obj->initInstanceIsa(cls, hasCxxDtor);
    } else {
        // Use raw pointer isa on the assumption that they might be
        // doing something weird with the zone or RR.
        obj->initIsa(cls);
    }

    if (fastpath(!hasCxxCtor)) {
        return obj;
    }

    construct_flags |= OBJECT_CONSTRUCT_FREE_ONFAILURE;
    return object_cxxConstructFromClass(obj, cls, construct_flags);
}

根據源碼分析，得出其實現流程圖如下圖所示：

_class_createInstanceFromZone流程圖

alloc 核心操作

核心操作都位于calloc方法中
cls->instanceSize：計算所需內存大小
計算需要開辟內存的大小的執行流程如下圖所示：

什么是new？

查看源碼

+ (id)new {
    return [callAlloc(self, false/*checkNil*/) init];
}

結論：通過源碼可以得知，new函數中直接調用了callAlloc函數（即alloc中分析的函數），且調用了init函數，所以可以得出new 其實就等價于 [alloc init]的結論

什么是init?

查看源碼

類init

+ (id)init {
    return (id)self;
}

結論：這里的init是一個構造方法 ，是通過工廠設計（工廠方法模式）,主要是用于給用戶提供構造方法入口。這里能使用id強轉的原因，主要還是因為 內存字節對齊后，可以使用類型強轉為你所需的類型

實例init

- (id)init {
    return _objc_rootInit(self);
}
id _objc_rootInit(id obj)
{
    // In practice, it will be hard to rely on this function.
    // Many classes do not properly chain -init calls.
    return obj;
}

結論：有上述代碼可以，返回的是傳入的self本身。