目的

一個項目（project）文件夾中有多個工程（module），這多個module使用的

compileSdkVersion
buildToolsVersion
minSdkVersion
targetSdkVersion
依賴庫

等等需要統(tǒng)一管理其版本號，避免頻繁修改。

運用

在module項目里的build.gradle文件中，通過下面的方式來統(tǒng)一版本

$rootProject.supportLibraryVersion
$rootProject.ext.junitVersion

例子

dependencies {
      compile "com.android.support:appcompat-v7:$rootProject.supportLibraryVersion"
      compile "com.android.support:cardview-v7:$rootProject.supportLibraryVersion"
      compile "com.android.support:design:$rootProject.supportLibraryVersion"
      compile "com.android.support:recyclerview-v7:$rootProject.supportLibraryVersion"
}

對比

下面是沒有統(tǒng)一管理的依賴

dependencies {
    compile 'com.android.support:appcompat-v7:25.1.0'
    compile 'com.android.support:design:25.1.0'
    testCompile 'junit:junit:4.12'
}

可見，當(dāng)module很多的時候，如果沒有統(tǒng)一管理，那么將可能導(dǎo)致很多問題：

1. A module使用24版本的v7包，B module使用25版本的v7包。當(dāng)另一臺電腦需要運行這些module時而不得不下載24和25兩個版本的v7包，即浪費時間又浪費系統(tǒng)資源；
2. 而當(dāng)需要更新依賴庫版本時，必須一個一個module去修改，非常耗時；
3. 你猜。

廢話少說，下面開始設(shè)置

代碼

在project的build.gradle文件的最底部加上

ext {
    // Sdk and tools
    minSdkVersion = 15
    targetSdkVersion = 25
    compileSdkVersion = 25
    buildToolsVersion = '25.0.2'

    // App dependencies
    supportLibraryVersion = '25.1.0'
    guavaVersion = '18.0'
    junitVersion = '4.12'
    mockitoVersion = '1.10.19'
    powerMockito = '1.6.2'
    hamcrestVersion = '1.3'
    runnerVersion = '0.5'
    rulesVersion = '0.5'
    espressoVersion = '2.2.2'
}

上面的名稱和版本號根據(jù)個人需要進(jìn)行修改。
在module里的build.gradle里

android {
    compileSdkVersion rootProject.ext.compileSdkVersion
    buildToolsVersion rootProject.ext.buildToolsVersion

    defaultConfig {
        applicationId "你的包名"
        minSdkVersion rootProject.ext.minSdkVersion
        targetSdkVersion rootProject.ext.targetSdkVersion
        versionCode 1
        versionName "1.0"

        testInstrumentationRunner 'android.support.test.runner.AndroidJUnitRunner'
}
dependencies {
    compile (group:'com.android.support',name:'appcompat-v7',version:"$rootProject.supportLibraryVersion")
    // App's dependencies, including test
    compile "com.android.support:appcompat-v7:$rootProject.supportLibraryVersion"
    compile "com.android.support:cardview-v7:$rootProject.supportLibraryVersion"
    compile "com.android.support:design:$rootProject.supportLibraryVersion"
    compile "com.android.support:recyclerview-v7:$rootProject.supportLibraryVersion"
    compile "com.android.support:support-v4:$rootProject.supportLibraryVersion"
    compile "com.android.support.test.espresso:espresso-idling-resource:$rootProject.espressoVersion"
    compile "com.google.guava:guava:$rootProject.guavaVersion"

    // Dependencies for local unit tests
    testCompile "junit:junit:$rootProject.ext.junitVersion"
    testCompile "org.mockito:mockito-all:$rootProject.ext.mockitoVersion"
    testCompile "org.hamcrest:hamcrest-all:$rootProject.ext.hamcrestVersion"

    // Android Testing Support Library's runner and rules
    androidTestCompile "com.android.support.test:runner:$rootProject.ext.runnerVersion"
    androidTestCompile "com.android.support.test:rules:$rootProject.ext.runnerVersion"

    // Dependencies for Android unit tests
    androidTestCompile "junit:junit:$rootProject.ext.junitVersion"
    androidTestCompile "org.mockito:mockito-core:$rootProject.ext.mockitoVersion"
    androidTestCompile 'com.google.dexmaker:dexmaker:1.2'
    androidTestCompile 'com.google.dexmaker:dexmaker-mockito:1.2'

    // Espresso UI Testing
    androidTestCompile "com.android.support.test.espresso:espresso-core:$rootProject.espressoVersion"
    androidTestCompile "com.android.support.test.espresso:espresso-contrib:$rootProject.espressoVersion"
    androidTestCompile "com.android.support.test.espresso:espresso-intents:$rootProject.espressoVersion"

    // Resolve conflicts between main and test APK:
    androidTestCompile "com.android.support:support-annotations:$rootProject.supportLibraryVersion"
    androidTestCompile "com.android.support:support-v4:$rootProject.supportLibraryVersion"
    androidTestCompile "com.android.support:recyclerview-v7:$rootProject.supportLibraryVersion"
    androidTestCompile "com.android.support:appcompat-v7:$rootProject.supportLibraryVersion"
    androidTestCompile "com.android.support:design:$rootProject.supportLibraryVersion"
}

方法二

你也可以新建一個工程級別的*.gradle文件來單獨裝在這些版本號，但需要在module級別的build.gradle文件里添加一行代碼（*號表示你指定名稱）。

上面刪除線處更正為：“但需要在project級別”（感謝TsuiYC提醒）

apply from:"*.gradle"

最終樣式看圖：

自建gradle保存版本.png

針對第二種方法，不用修改model.gradle里的任何代碼

參考

Gradle統(tǒng)一依賴管理
googlesamples/android-architectureMVP例子