可以將一個(gè)單獨(dú)的任務(wù)所用到的所有東西都封裝在一個(gè)LDT中。
step1.增加一個(gè)32位的代碼段：LABEL_CODE_A
step2.增加一個(gè)段，內(nèi)容是一個(gè)描述表(LDT)，添加一個(gè)描述增加代碼段的代碼段描述符。注意，涉及的選擇子的TI位是1。
step3.在GDT中增加一個(gè)描述符，用以描述這個(gè)LDT，同時(shí)要定義其描述符
step4.增加新添的描述符的初始化代碼，主要是針對(duì)段基址
step5.用新加的LDT描述的局部任務(wù)準(zhǔn)備
step6.使用前用lldt指令加載ldtr，用jmp指令跳轉(zhuǎn)等方式運(yùn)行
保護(hù)模式中保護(hù)二字到底是什么含義？
answer：在描述符中段基址和段界限定義了一個(gè)段的范圍，對(duì)超越段界限之外的地址的訪問是被禁止的。
? ? ? ? ? ? ? ? 段屬性規(guī)定和限制了段的行為和性質(zhì)。
; ==========================================
; pmtest3.asm
; 編譯方法：nasm pmtest3.asm -o pmtest3.com
; ==========================================
%include "pm.inc" ; 常量, 宏, 以及一些說明
org 0100h
jmp LABEL_BEGIN
[SECTION .gdt]
; GDT
;? ? ? ? ? ? ? ? ? ? ? ? ? ? ? ? ? ? ? ? 段基址,? ? ? 段界限? ? , 屬性
LABEL_GDT:? ? ? ? Descriptor? ? ? 0,? ? ? ? ? ? ? ? 0, 0? ? ; 空描述符
LABEL_DESC_NORMAL: Descriptor? ? ? 0,? ? ? ? ? ? 0ffffh, DA_DRW ; Normal 描述符
LABEL_DESC_CODE32: Descriptor? ? ? 0,? SegCode32Len - 1, DA_C + DA_32 ; 非一致代碼段, 32
LABEL_DESC_CODE16: Descriptor? ? ? 0,? ? ? ? ? ? 0ffffh, DA_C ; 非一致代碼段, 16
LABEL_DESC_DATA:? Descriptor? ? ? 0,? ? ? DataLen - 1, DA_DRW+DA_DPL1 ; Data
LABEL_DESC_STACK:? Descriptor? ? ? 0,? ? ? ? TopOfStack, DA_DRWA + DA_32; Stack, 32 位
LABEL_DESC_LDT:? ? Descriptor? ? ? 0,? ? ? ? LDTLen - 1, DA_LDT ; LDT
LABEL_DESC_VIDEO:? Descriptor 0B8000h,? ? ? ? ? ? 0ffffh, DA_DRW ; 顯存首地址
; GDT 結(jié)束
GdtLen equ $ - LABEL_GDT ; GDT長度
GdtPtr dw GdtLen - 1 ; GDT界限
dd 0 ; GDT基地址
; GDT 選擇子
SelectorNormal equ LABEL_DESC_NORMAL - LABEL_GDT
SelectorCode32 equ LABEL_DESC_CODE32 - LABEL_GDT
SelectorCode16 equ LABEL_DESC_CODE16 - LABEL_GDT
SelectorData equ LABEL_DESC_DATA - LABEL_GDT
SelectorStack equ LABEL_DESC_STACK - LABEL_GDT
SelectorLDT equ LABEL_DESC_LDT - LABEL_GDT
SelectorVideo equ LABEL_DESC_VIDEO - LABEL_GDT
; END of [SECTION .gdt]
[SECTION .data1] ; 數(shù)據(jù)段
ALIGN 32
[BITS 32]
LABEL_DATA:
SPValueInRealMode dw 0
; 字符串
PMMessage: db "In Protect Mode now. ^-^", 0 ; 進(jìn)入保護(hù)模式后顯示此字符串
OffsetPMMessage equ PMMessage - $$
StrTest: db "ABCDEFGHIJKLMNOPQRSTUVWXYZ", 0
OffsetStrTest equ StrTest - $$
DataLen equ $ - LABEL_DATA
; END of [SECTION .data1]
; 全局堆棧段
[SECTION .gs]
ALIGN 32
[BITS 32]
LABEL_STACK:
times 512 db 0
TopOfStack equ $ - LABEL_STACK - 1
; END of [SECTION .gs]
[SECTION .s16]
[BITS 16]
LABEL_BEGIN:
? ? ? ? mov ax, cs
? ? ? ? mov ds, ax
? ? ? ? mov es, ax
? ? ? ? mov ss, ax
? ? ? ? mov sp, 0100h
? ? ? ? mov [LABEL_GO_BACK_TO_REAL+3], ax
? ? ? ? mov [SPValueInRealMode], sp
? ? ? ? ; 初始化 16 位代碼段描述符
? ? ? ? mov ax, cs
? ? ? ? movzx eax, ax
? ? ? ? shl eax, 4
? ? ? ? add eax, LABEL_SEG_CODE16
? ? ? ? mov word [LABEL_DESC_CODE16 + 2], ax
? ? ? ? shr eax, 16
? ? ? ? mov byte [LABEL_DESC_CODE16 + 4], al
? ? ? ? mov byte [LABEL_DESC_CODE16 + 7], ah
? ? ? ? ; 初始化 32 位代碼段描述符
? ? ? ? xor eax, eax
? ? ? ? mov ax, cs
? ? ? ? shl eax, 4?
? ? ? ? add eax, LABEL_SEG_CODE32
? ? ? ? mov word [LABEL_DESC_CODE32 + 2], ax
? ? ? ? shr eax, 16
? ? ? ? mov byte [LABEL_DESC_CODE32 + 4], al
? ? ? ? mov byte [LABEL_DESC_CODE32 + 7], ah
? ? ? ? ; 初始化數(shù)據(jù)段描述符
? ? ? ? xor eax, eax
? ? ? ? mov ax, ds
? ? ? ? shl eax, 4
? ? ? ? add eax, LABEL_DATA
? ? ? ? mov word [LABEL_DESC_DATA + 2], ax
? ? ? ? shr eax, 16
? ? ? ? mov byte [LABEL_DESC_DATA + 4], al
? ? ? ? mov byte [LABEL_DESC_DATA + 7], ah
? ? ? ? ; 初始化堆棧段描述符
? ? ? ? xor eax, eax
? ? ? ? mov ax, ds
? ? ? ? shl eax, 4
? ? ? ? add eax, LABEL_STACK
? ? ? ? mov word [LABEL_DESC_STACK + 2], ax
? ? ? ? shr eax, 16
? ? ? ? mov byte [LABEL_DESC_STACK + 4], al
? ? ? ? mov byte [LABEL_DESC_STACK + 7], ah
? ? ? ? ; 初始化 LDT 在 GDT 中的描述符
? ? ? ? xor eax, eax
? ? ? ? mov ax, ds
? ? ? ? shl eax, 4
? ? ? ? add eax, LABEL_LDT
? ? ? ? mov word [LABEL_DESC_LDT + 2], ax
? ? ? ? shr eax, 16
? ? ? ? mov byte [LABEL_DESC_LDT + 4], al
? ? ? ? mov byte [LABEL_DESC_LDT + 7], ah
? ? ? ? ; 初始化 LDT 中的描述符
? ? ? ? xor eax, eax
? ? ? ? mov ax, ds
? ? ? ? shl eax, 4
? ? ? ? add eax, LABEL_CODE_A
? ? ? ? mov word [LABEL_LDT_DESC_CODEA + 2], ax
? ? ? ? shr eax, 16
? ? ? ? mov byte [LABEL_LDT_DESC_CODEA + 4], al
? ? ? ? mov byte [LABEL_LDT_DESC_CODEA + 7], ah
? ? ? ? ; 為加載 GDTR 作準(zhǔn)備
? ? ? ? xor eax, eax
? ? ? ? mov ax, ds
? ? ? ? shl eax, 4
? ? ? ? add eax, LABEL_GDT ; eax <- gdt 基地址
? ? ? ? mov dword [GdtPtr + 2], eax ; [GdtPtr + 2] <- gdt 基地址
? ? ? ? ; 加載 GDTR
? ? ? ? lgdt [GdtPtr]
? ? ? ? ; 關(guān)中斷
? ? ? ? cli
? ? ? ? ; 打開地址線A20
? ? ? ? in al, 92h
? ? ? ? or al, 00000010b
? ? ? ? out 92h, al
? ? ? ? ; 準(zhǔn)備切換到保護(hù)模式
? ? ? ? mov eax, cr0
? ? ? ? or eax, 1
? ? ? ? mov cr0, eax
? ? ? ? ; 真正進(jìn)入保護(hù)模式
? ? ? ? jmp dword SelectorCode32:0 ; 執(zhí)行這一句會(huì)把 SelectorCode32 裝入 cs, 并跳轉(zhuǎn)到 Code32Selector:0? 處
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
LABEL_REAL_ENTRY: ; 從保護(hù)模式跳回到實(shí)模式就到了這里
? ? ? ? mov ax, cs
? ? ? ? mov ds, ax
? ? ? ? mov es, ax
? ? ? ? mov ss, ax
? ? ? ? mov sp, [SPValueInRealMode] ? ?
? ? ? ? in al, 92h ; ? ? ? ? ? ? ? ?┓
? ? ? ? and al, 11111101b ; ┣ 關(guān)閉 A20 地址線
? ? ? ? out 92h, al ; ? ? ? ? ? ? ?┛
? ? ? ? sti ; 開中斷
? ? ? ? mov ax, 4c00h ; ┓
? ? ? ? int 21h ; ? ? ? ? ? ? ?┛回到 DOS
? ? ? ? ; END of [SECTION .s16]
[SECTION .s32]; 32 位代碼段. 由實(shí)模式跳入.
[BITS 32]
LABEL_SEG_CODE32:
? ? ? ? mov ax, SelectorData
? ? ? ? mov ds, ax ; 數(shù)據(jù)段選擇子
? ? ? ? mov ax, SelectorVideo
? ? ? ? mov gs, ax ; 視頻段選擇子
? ? ? ? mov ax, SelectorStack
? ? ? ? mov ss, ax ; 堆棧段選擇子
? ? ? ? mov esp, TopOfStack
? ? ? ? ; 下面顯示一個(gè)字符串
? ? ? ? mov ah, 0Ch ; 0000: 黑底? ? 1100: 紅字
? ? ? ? xor esi, esi
? ? ? ? xor edi, edi
? ? ? ? mov esi, OffsetPMMessage ; 源數(shù)據(jù)偏移
? ? ? ? mov edi, (80 * 10 + 0) * 2 ; 目的數(shù)據(jù)偏移。屏幕第 10 行, 第 0 列。
? ? ? ? cld
.1:
? ? ? ? lodsb
? ? ? ? test al, al
? ? ? ? jz .2
? ? ? ?mov [gs:edi], ax
? ? ? ?add edi, 2
? ? ? ?jmp .1
.2: ; 顯示完畢
? ? ? ? call DispReturn
? ? ? ? ; Load LDT
? ? ? ? mov ax, SelectorLDT
? ? ? ? lldt ax
? ? ? ? jmp SelectorLDTCodeA:0 ; 跳入局部任務(wù)
; ------------------------------------------------------------------------
DispReturn:
? ? ? ? push eax
? ? ? ? push ebx
? ? ? ? mov eax, edi
? ? ? ? mov bl, 160 ?
? ? ? ? div bl
? ? ? ? and eax, 0FFh
? ? ? ? inc eax
? ? ? ? mov bl, 160
? ? ? ? mul bl
? ? ? ? mov edi, eax
? ? ? ? pop ebx
? ? ? ? pop eax
? ? ? ? ret
? ? ? ? ; DispReturn 結(jié)束---------------------------------------------------------
? ? ? ? SegCode32Len equ $ - LABEL_SEG_CODE32
; END of [SECTION .s32]
; 16 位代碼段. 由 32 位代碼段跳入, 跳出后到實(shí)模式
[SECTION .s16code]
ALIGN 32
[BITS 16]
LABEL_SEG_CODE16:
? ? ? ? ?; 跳回實(shí)模式:
? ? ? ? mov ax, SelectorNormal
? ? ? ? mov ds, ax
? ? ? ? mov es, ax
? ? ? ? mov fs, ax
? ? ? ? mov gs, ax
? ? ? ? mov ss, ax
? ? ? ? mov eax, cr0
? ? ? ? and al, 11111110b
? ? ? ? mov cr0, eax
LABEL_GO_BACK_TO_REAL:
? ? ? ? jmp 0:LABEL_REAL_ENTRY ; 段地址會(huì)在程序開始處被設(shè)置成正確的值
Code16Len equ $ - LABEL_SEG_CODE16
; END of [SECTION .s16code]
; LDT
[SECTION .ldt]
ALIGN 32
LABEL_LDT:
;? ? ? ? ? ? ? ? ? ? ? ? ? ? 段基址? ? ? 段界限? ? ? 屬性
LABEL_LDT_DESC_CODEA: Descriptor 0, CodeALen - 1, DA_C + DA_32 ; Code, 32 位
LDTLen equ $ - LABEL_LDT
; LDT 選擇子
SelectorLDTCodeA equ LABEL_LDT_DESC_CODEA - LABEL_LDT + SA_TIL
; END of [SECTION .ldt]
; CodeA (LDT, 32 位代碼段)
[SECTION .la]
ALIGN 32
[BITS 32]
LABEL_CODE_A:
? ? ? ? mov ax, SelectorVideo
? ? ? ? mov gs, ax ; 視頻段選擇子(目的)
? ? ? ? mov edi, (80 * 12 + 0) * 2 ; 屏幕第 10 行, 第 0 列。
? ? ? ? mov ah, 0Ch ; 0000: 黑底? ? 1100: 紅字
? ? ? ? mov al, 'L'
? ? ? ? mov [gs:edi], ax
? ? ? ? ; 準(zhǔn)備經(jīng)由16位代碼段跳回實(shí)模式
? ? ? ? jmp SelectorCode16:0
CodeALen equ $ - LABEL_CODE_A
; END of [SECTION .la]
一、lldt
? ? lldt負(fù)責(zé)加載ldtr，它的操作數(shù)是一個(gè)選擇子，這個(gè)選擇子對(duì)應(yīng)的就是用來描述LDT的那個(gè)描述符。?
? ? SA_TIL將選擇子的TI置位為1，表明系統(tǒng)將從當(dāng)前LDT中尋找相應(yīng)描述符。
