轉自：http://m.blog.csdn.net/puppet_master/article/details/53548134
簡介
寫了兩篇簡單光照模型的shader的文章，雖然Unity自帶的shader就有diffuse和specular，效果還比自己寫的好，然而要想學好shader，基礎還是很重要的。不然到網上到處找shader，扔到項目里，能用就好，完全不看性能的話，遲早會出事的。今天不看光照模型了，物理渲染還沒搞懂，所以只好先來個簡單的shader玩一玩。正好最近在和某基友玩黑魂，這貨一出來總是自帶一個特效-邊緣光。于是本人強迫癥發作，決定研究一下這個怎么實現。
RimLight--邊緣發光效果，是一個比較常用的效果，實現簡單，在普通的光照計算后只需要兩步操作，就可以實現邊緣光效果?？聪旅嬉环鶊D，簡單介紹一下RimLight的原理：
所謂RimLight邊緣發光，也就是說對應我們當前視角方向，物體上位于邊緣的地方額外加一個光的效果。那么，怎么判斷一個點是否在物體的邊緣呢？就是通過法線方向和視線方向的夾角來判斷。當視線方向V與法線方向N垂直時，這個法線對應的面就與視線方向平行，說明當前這個點對于當前視角來說，就處在邊緣；而視線方向與法線方向一致時，這個法線對應的面就垂直于視線方向，說明當前是直視這個面。所以，我們就可以根據dot（N,V）來獲得視線方向與法線方向的余弦值，通過這個值來區分該像素是否處在邊緣，進而判斷是否需要增加以及增加邊緣光的強弱。
邊緣光效果Unity下的實現
上面已經說完了邊緣光效果的實現原理，下面附上完整的邊緣光效果shader，基于之前介紹過的蘭伯特光照模型，增加了邊緣光效果：
//邊緣發光Shader
//by：puppet_master
//2016.12.11
Shader "ApcShader/RimLight"
{
//屬性
Properties{
_Diffuse("Diffuse", Color) = (1,1,1,1)
_RimColor("RimColor", Color) = (1,1,1,1)
_RimPower("RimPower", Range(0.000001, 3.0)) = 0.1
_MainTex("Base 2D", 2D) = "white"{}
}
//子著色器
SubShader
{
Pass
{
//定義Tags
Tags{ "RenderType" = "Opaque" }
CGPROGRAM
//引入頭文件
#include "Lighting.cginc"
//定義Properties中的變量
fixed4 _Diffuse;
sampler2D _MainTex;
//使用了TRANSFROM_TEX宏就需要定義XXX_ST
float4 _MainTex_ST;
fixed4 _RimColor;
float _RimPower;
//定義結構體：vertex shader階段輸出的內容
struct v2f
{
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float2 uv : TEXCOORD1;
//在vertex shader中計算觀察方向傳遞給fragment shader
float3 worldViewDir : TEXCOORD2;
};
//定義頂點shader,參數直接使用appdata_base（包含position, noramal, texcoord）
v2f vert(appdata_base v)
{
v2f o;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
//通過TRANSFORM_TEX宏轉化紋理坐標，主要處理了Offset和Tiling的改變,默認時等同于o.uv = v.texcoord.xy;
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
o.worldNormal = mul(v.normal, (float3x3)_World2Object);
//頂點轉化到世界空間
float3 worldPos = mul(_Object2World, v.vertex).xyz;
//可以把計算計算ViewDir的操作放在vertex shader階段，畢竟逐頂點計算比較省
o.worldViewDir = _WorldSpaceCameraPos.xyz - worldPos;
return o;
}
//定義片元shader
fixed4 frag(v2f i) : SV_Target
{
//unity自身的diffuse也是帶了環境光，這里我們也增加一下環境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Diffuse.xyz;
//歸一化法線，即使在vert歸一化也不行，從vert到frag階段有差值處理，傳入的法線方向并不是vertex shader直接傳出的
fixed3 worldNormal = normalize(i.worldNormal);
//把光照方向歸一化
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
//根據半蘭伯特模型計算像素的光照信息
fixed3 lambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;
//最終輸出顏色為lambert光強*材質diffuse顏色*光顏色
fixed3 diffuse = lambert * _Diffuse.xyz * _LightColor0.xyz + ambient;
//進行紋理采樣
fixed4 color = tex2D(_MainTex, i.uv);
//以下為本篇主題：計算RimLight
//把視線方向歸一化
float3 worldViewDir = normalize(i.worldViewDir);
//計算視線方向與法線方向的夾角，夾角越大，dot值越接近0，說明視線方向越偏離該點，也就是平視，該點越接近邊緣
float rim = 1 - max(0, dot(worldViewDir, worldNormal));
//計算rimLight
fixed3 rimColor = _RimColor * pow(rim, 1 / _RimPower);
//輸出顏色+邊緣光顏色
color.rgb = color.rgb* diffuse + rimColor;
return fixed4(color);
}
//使用vert函數和frag函數
#pragma vertex vert
#pragma fragment frag
ENDCG
}
}
//前面的Shader失效的話，使用默認的Diffuse
FallBack "Diffuse"
}
下面看一下加了邊緣光后的效果，普通diffuse shader：
白色邊緣光效果：
黃色邊緣光效果：
增加景深效果和Bloom效果，Bloom可以把亮的部分處理得更亮，有一種光線溢出的效果，而景深效果可以突出我們要表現的重點。唉，最近發現自己身陷后處理不能自拔啊....
通過Mask圖控制邊緣光
我們把邊緣光效果加大到一定程度，就快成了自發光效果，但是上面的shader有個問題，就是全身都會自發光。如下圖所示：
如果只希望盔甲部分有自發光效果，而其他部分沒有自發光，我們就需要用Mask圖來控制了，我們用一張Alpha8的灰度圖來控制是否開啟邊緣光效果，將上面的shader簡單修改一下，增加Mask圖的通道：
//邊緣發光Shader
//by：puppet_master
//2016.12.11
Shader "ApcShader/RimLight"
{
//屬性
Properties{
_Diffuse("Diffuse", Color) = (1,1,1,1)
_RimColor("RimColor", Color) = (1,1,1,1)
_RimPower("RimPower", Range(0.000001, 20.0)) = 0.1
_RimMask("RimMask", 2D) = "white"{}
_MainTex("Base 2D", 2D) = "white"{}
}
//子著色器
SubShader
{
Pass
{
//定義Tags
Tags{ "RenderType" = "Opaque" }
CGPROGRAM
//引入頭文件
#include "Lighting.cginc"
//定義Properties中的變量
fixed4 _Diffuse;
sampler2D _MainTex;
//使用了TRANSFROM_TEX宏就需要定義XXX_ST
float4 _MainTex_ST;
sampler2D _RimMask;
fixed4 _RimColor;
float _RimPower;
//定義結構體：vertex shader階段輸出的內容
struct v2f
{
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float2 uv : TEXCOORD1;
//在vertex shader中計算觀察方向傳遞給fragment shader
float3 worldViewDir : TEXCOORD2;
};
//定義頂點shader,參數直接使用appdata_base（包含position, noramal, texcoord）
v2f vert(appdata_base v)
{
v2f o;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
//通過TRANSFORM_TEX宏轉化紋理坐標，主要處理了Offset和Tiling的改變,默認時等同于o.uv = v.texcoord.xy;
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
o.worldNormal = mul(v.normal, (float3x3)_World2Object);
//頂點轉化到世界空間
float3 worldPos = mul(_Object2World, v.vertex).xyz;
//可以把計算計算ViewDir的操作放在vertex shader階段，畢竟逐頂點計算比較省
o.worldViewDir = _WorldSpaceCameraPos.xyz - worldPos;
return o;
}
//定義片元shader
fixed4 frag(v2f i) : SV_Target
{
//unity自身的diffuse也是帶了環境光，這里我們也增加一下環境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Diffuse.xyz;
//歸一化法線，即使在vert歸一化也不行，從vert到frag階段有差值處理，傳入的法線方向并不是vertex shader直接傳出的
fixed3 worldNormal = normalize(i.worldNormal);
//把光照方向歸一化
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
//根據半蘭伯特模型計算像素的光照信息
fixed3 lambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;
//最終輸出顏色為lambert光強*材質diffuse顏色*光顏色
fixed3 diffuse = lambert * _Diffuse.xyz * _LightColor0.xyz + ambient;
//進行紋理采樣
fixed4 color = tex2D(_MainTex, i.uv);
//以下為本篇主題：計算RimLight
//把視線方向歸一化
float3 worldViewDir = normalize(i.worldViewDir);
//計算視線方向與法線方向的夾角，夾角越大，dot值越接近0，說明視線方向越偏離該點，也就是平視，該點越接近邊緣
float rim = 1 - max(0, dot(worldViewDir, worldNormal));
//計算RimLight
fixed3 rimColor = _RimColor * pow(rim, 1 / _RimPower);
//通過RimMask控制是否有邊緣光,Rim目前存在一張Alpha8類型的圖片中
fixed rimMask = tex2D(_RimMask, i.uv).a;
//輸出顏色+邊緣光顏色
color.rgb = color.rgb* diffuse + rimColor * (1 - rimMask);
return fixed4(color);
}
//使用vert函數和frag函數
#pragma vertex vert
#pragma fragment frag
ENDCG
}
}
//前面的Shader失效的話，使用默認的Diffuse
FallBack "Diffuse"
}
我們把下面這張自發光Mask圖賦給材質：
通過采樣這張Mask就能控制那部分開啟自發光，那部分關閉自發光了：
調整Mask圖，也可以得到一些比較好玩的效果：
動態RimLight效果
看了一篇博文，其中的邊緣光使用了一張動態圖，達到了流動的效果，感謝作者的無私分享，于是我也嘗試一下動態RimLight的效果。其實思路跟上面的Mask圖一樣，只不過這次改成一張掃面線類型的紋理，然后通過這張紋理的采樣滾動，達到動態的效果。一提到動態效果，我們第一個想到的應該就是_Time向量，這個向量中幾個值都是跟時間相關的，我們如果做動態效果，肯定少不了和這個變量打交道，關于_Time及其變種，可以參考這篇文章，我們這里用_Time.y就可以獲得時間了。
我們用一張Mask紋理，白色代表有邊緣光，黑色無邊緣光，通過采樣這張Mask紋理，控制模型上顯示邊緣光的部分：
動態RimLight的shader如下：
//邊緣發光Shader
//by：puppet_master
//2016.12.11
Shader "ApcShader/RimLight"
{
//屬性
Properties{
_Diffuse("Diffuse", Color) = (1,1,1,1)
_RimColor("RimColor", Color) = (1,1,1,1)
_RimPower("RimPower", Range(0.000001, 20.0)) = 0.1
_RimMask("RimMask", 2D) = "white"{}
_MainTex("Base 2D", 2D) = "white"{}
_RimSpeed("RimSpeed", Range(-10, 10)) = 1.0
}
//子著色器
SubShader
{
Pass
{
//定義Tags
Tags{ "RenderType" = "Opaque" }
CGPROGRAM
//引入頭文件
#include "Lighting.cginc"
//定義Properties中的變量
fixed4 _Diffuse;
sampler2D _MainTex;
//使用了TRANSFROM_TEX宏就需要定義XXX_ST
float4 _MainTex_ST;
sampler2D _RimMask;
fixed4 _RimColor;
float _RimPower;
float _RimSpeed;
//定義結構體：vertex shader階段輸出的內容
struct v2f
{
float4 pos : SV_POSITION;
float3 worldNormal : TEXCOORD0;
float2 uv : TEXCOORD1;
//在vertex shader中計算觀察方向傳遞給fragment shader
float3 worldViewDir : TEXCOORD2;
};
//定義頂點shader,參數直接使用appdata_base（包含position, noramal, texcoord）
v2f vert(appdata_base v)
{
v2f o;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
//通過TRANSFORM_TEX宏轉化紋理坐標，主要處理了Offset和Tiling的改變,默認時等同于o.uv = v.texcoord.xy;
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
o.worldNormal = mul(v.normal, (float3x3)_World2Object);
//頂點轉化到世界空間
float3 worldPos = mul(_Object2World, v.vertex).xyz;
//可以把計算計算ViewDir的操作放在vertex shader階段，畢竟逐頂點計算比較省
o.worldViewDir = _WorldSpaceCameraPos.xyz - worldPos;
return o;
}
//定義片元shader
fixed4 frag(v2f i) : SV_Target
{
//unity自身的diffuse也是帶了環境光，這里我們也增加一下環境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Diffuse.xyz;
//歸一化法線，即使在vert歸一化也不行，從vert到frag階段有差值處理，傳入的法線方向并不是vertex shader直接傳出的
fixed3 worldNormal = normalize(i.worldNormal);
//把光照方向歸一化
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
//根據半蘭伯特模型計算像素的光照信息
fixed3 lambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;
//最終輸出顏色為lambert光強*材質diffuse顏色*光顏色
fixed3 diffuse = lambert * _Diffuse.xyz * _LightColor0.xyz + ambient;
//進行紋理采樣
fixed4 color = tex2D(_MainTex, i.uv);
//以下為本篇主題：計算RimLight
//把視線方向歸一化
float3 worldViewDir = normalize(i.worldViewDir);
//計算視線方向與法線方向的夾角，夾角越大，dot值越接近0，說明視線方向越偏離該點，也就是平視，該點越接近邊緣
float rim = 1 - max(0, dot(worldViewDir, worldNormal));
//計算RimLight
fixed3 rimColor = _RimColor * pow(rim, 1 / _RimPower);
//通過RimMask控制是否有邊緣光,Rim目前存在一張Alpha8類型的圖片中
fixed rimMask = tex2D(_RimMask, i.uv + float2(0 , _Time.y * _RimSpeed)).r;
//輸出顏色+邊緣光顏色
color.rgb = color.rgb* diffuse + rimColor * (1-rimMask);
return fixed4(color);
}
//使用vert函數和frag函數
#pragma vertex vert
#pragma fragment frag
ENDCG
}
}
//前面的Shader失效的話，使用默認的Diffuse
FallBack "Diffuse"
}
來一張Gif截圖（旁邊好像有什么搶鏡了）：
Unity Shader中可用的變量類型整理
在傳遞參數時總是忘了能傳遞哪些類型的參數，記錄一下，方便以后查找，這種東西也沒必要死記硬背下來，需要的時候幾秒鐘之內能找到就好了。
//Float類型，下面對應變量可以用flaot,half,fixed
_Name("Inspector Name", Float) = defaultValue
//Float類型,可以用一個滑動條控制范圍,下面對應變量可以用float,half,fixed
_Name("Inspector Name", Range(min, max)) = defaultValue
//顏色類型，下面對應變量可以用float4,half4,fixed4，如果是顏色，盡量fixed4
_Name("Inspector Name", Color) = (defaultValue.r, defaultValue.g, defaultValue.b, defaultValue.a)
//2D紋理類型,默認紋理可以為空，白，黑，灰，凹凸，下面對應變量sampler2D
_Name("Inspector Name", 2D) = "" / "white" / "black" / "gray" / "bump"{options}
//長方形紋理，非2次方大小的紋理，其同上
_Name("Inspector Name", Rect) = "" / "white" / "black" / "gray" / "bump"{options}
//立方體貼圖CubeMap
_Name("Inspector Name", Cube) = "" {options}
//傳遞一個Vector4向量
_Name("Inspector Name", Vector) = (defaultValue.x, defaultValue.y, defaultValue.z, defaultValue.w)
//注：上面紋理后面{}里面是一些紋理TexGen，LightmapMode光照模式等內容
