Gradle 入門

[TOC]

是什么？

在語法上是基于Groovy語言的（Groovy 是一種基于JVM的敏捷開發語言，可以簡單的理解為強類型語言java的弱類型版本），在項目管理上是基于Ant和Maven概念的項目自動化建構工具。

搭建Gradle運行環境

  1. Gradle 運行依賴JVM，也就是java運行的環境。所以要安裝jdk和jre，好像目前的Gradle的運行環境要求jdk的版本在1.6以上，應該的，現在jdk都到1.8了。
  2. 然后到Gradle官網現在Gradle的壓縮包。地址，這個頁面里面又兩種方式，一種手動安裝，一種通過腳本安裝。我一般喜歡自己動手，這樣將來清理起來比較方便。
  3. 下載壓縮包后，解壓，然后配置環境變量，手動安裝過jdk的人應該都配置環境變量很熟了吧。每個平臺下配置環境變量的方式不一樣

MacOS 下配置。在~/.bash_profile中添加如下代碼

#gradle  注意gradle-2.14.1是自己解壓的路徑
export GRADLE_HOME=${HOME}/gradle-2.14.1
PATH=${PATH}:${GRADLE_HOME}/bin
export PATH

保存后在終端輸入source ~/.bash_profile回車執行讓剛剛的配置生效。然后命令行輸入gradle -v查看是否安裝成功。

$ gradle -v

------------------------------------------------------------
Gradle 2.14.1
------------------------------------------------------------

Build time:   2016-07-18 06:38:37 UTC
Revision:     d9e2113d9fb05a5caabba61798bdb8dfdca83719

Groovy:       2.4.4
Ant:          Apache Ant(TM) version 1.9.6 compiled on June 29 2015
JVM:          1.8.0_111 (Oracle Corporation 25.111-b14)
OS:           Mac OS X 10.12.2 x86_64

弄一個HelloWorld看看

創建一個test_gralde文件夾。然后在文件夾里面創建一個build.gradle文件。注意文件名不要亂起。在build.gradle中添加如下代碼：

task helloworld{
    doLast{
        println'Hello World!'
    }
}

然后來運行一下：

gradle helloworld

> Task :helloworld
Hello World!

BUILD SUCCESSFUL in 809ms
1 actionable task: 1 executed

我們分析一下執行步驟。build.gradle是Gradle默認的構建腳本文件，執行Gradle命令的時候，會默認加載當前目錄下的build.gradle腳本文件，當然你也可以通過 -b 參數指定想要加載執行的文件。這只是個最簡單的task例子，后面詳細介紹task的常見定義。

這個構建腳本定義一個任務（Task），任務名字叫helloworld，并且給任務helloworld添加了一個動作，官方名字是Action，閱讀Gradle源代碼你會到處見到它，其實他就是一段Groovy語言實現的閉包，doLast就意味著在Task執行完畢之后要回調doLast的這部分閉包的代碼實現

執行流程和基本術語

和Maven一樣，Gradle只是提供了構建項目的一個框架，真正起作用的是Plugin。Gradle在默認情況下為我們提供了許多常用的Plugin，其中包括有構建Java項目的Plugin，還有Android等。與Maven不同的是，Gradle不提供內建的項目生命周期管理，只是java Plugin向Project中添加了許多Task，這些Task依次執行，為我們營造了一種如同Maven般項目構建周期。

Gradle是一種聲明式的構建工具。在執行時，Gradle并不會一開始便順序執行build.gradle文件中的內容，而是分為兩個階段，第一個階段是配置階段，然后才是實際的執行階段。
配置階段，Gradle將讀取所有build.gradle文件的所有內容來配置Project和Task等，比如設置Project和Task的Property，處理Task之間的依賴關系等。

看一個基本結構的Android多Moudule（也就是gradle中的多Project Multi-Projects Build）的基本項目結構。

├── app #Android App目錄
│   ├── app.iml
│   ├── build #構建輸出目錄
│   ├── build.gradle #構建腳本
│   ├── libs #so相關庫
│   ├── proguard-rules.pro #proguard混淆配置
│   └── src #源代碼，資源等
├── module #Android 另外一個module目錄
│   ├── module.iml
│   ├── build #構建輸出目錄
│   ├── build.gradle #構建腳本
│   ├── libs #so相關庫
│   ├── proguard-rules.pro #proguard混淆配置
│   └── src #源代碼，資源等
├── build
│   └── intermediates
├── build.gradle #工程構建文件
├── gradle
│   └── wrapper
├── gradle.properties #gradle的配置
├── gradlew #gradle wrapper linux shell腳本
├── gradlew.bat
├── LibSqlite.iml
├── local.properties #配置Androod SDK位置文件
└── settings.gradle #工程配置

上面的是完整的AndroidStudio中的項目結構，我們抽象成Gradle多個Project的樣子

├── app 
│   ├── build.gradle #構建腳本
├── module 
│   ├── build.gradle #構建腳本
├── build.gradle #工程構建文件
├── gradle
│   └── wrapper    #先不去管它
├── gradle.properties #gradle的配置
├── gradlew #gradle wrapper linux shell腳本
├── gradlew.bat
└── settings.gradle #工程配置
  1. Gradle為每個build.gradle都會創建一個相應的Project領域對象，在編寫Gradle腳本時，我們實際上是在操作諸如Project這樣的Gradle領域對象。在多Project的項目中，我們會操作多個Project領域對象。Gradle提供了強大的多Project構建支持。
  2. 要創建多Project的Gradle項目，我們首先需要在根（Root）Project中加入名為settings.gradle的配置文件，該文件應該包含各個子Project的名稱。Gradle中的Project可以簡單的映射為AndroidStudio中的Module。
  3. 在最外層的build.gradle。一般干得活是：配置其他子Project的。比如為子Project添加一些屬性。
  4. 在項目根目錄下有個一個名為settings.gradle。這個文件很重要，名字必須是settings.gradle。它里邊用來告訴Gradle，這個multiprojects包含多少個子Project（可以理解為AndroidStudio中Module）。

讀懂Gradle配置語法

Gradle向我們提供了一整套DSL，所以在很多時候我們寫的代碼似乎已經脫離了groovy，但是在底層依然是執行的groovy所以很多語法還是Groovy的語法規則。

看一個AndroidStudio中app下的build.gradle的配置

apply plugin: 'com.android.application'

android {
    compileSdkVersion 25
    buildToolsVersion "25.0.0"
    defaultConfig {
        applicationId "me.febsky.demo"
        minSdkVersion 15
        targetSdkVersion 25
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    compile 'com.android.support:appcompat-v7:25.1.0'
}

分析第一行apply plugin: 'com.android.application'

這句其實是Groovy語法糖，像Ruby和Js都有這種語法糖，apply實際上是個方法，補上括號后的腳本：apply (plugin: 'com.android.application'),看起來還是有點別扭是不？還有個語法糖，如果方法參數是個map類型，那么方括號可以省略，進一步還原apply([ plugin: 'com.android.application']),不理解的可以去看下Groovy的map的寫法，和js一樣。所以這行的意思是：apply其實是個方法，接收一個Map類型的參數。

總結兩點：1. 方法調用，圓括號可以省略 2. 如果方法參數是個Map，方括號可以省略。

Groovy語言的閉包語法
看上面的dependencies 這其實是個方法調用。調用了Project的dependencies方法。只不過參數是個閉包,我們對其進行還原一下：

#方法調用省略了（）我們加上
dependencies ({
    compile fileTree(dir: 'libs', include: ['*.jar'])
    compile 'com.android.support:appcompat-v7:25.1.0'
})
Project，Task ，Action

Gradle的Project之間的依賴關系是基于Task的，而不是整個Project的。

Project:是Gradle最重要的一個領域對象，我們寫的build.gradle腳本的全部作用，其實就是配置一個Project實例。在build.gradle腳本里，我們可以隱式的操縱Project實例，比如，apply插件、聲明依賴、定義Task等，如上面build.gradle所示。apply、dependencies、task等實際上是Project的方法，參數是一個代碼塊。如果需要，也可以顯示的操縱Project實例，比如：project.ext.myProp = 'myValue'

Task:被組織成了一個有向無環圖（DAG）。Gradle中的Task要么是由不同的Plugin引入的，要么是我們自己在build.gradle文件中直接創建的。Gradle保證Task按照依賴順序執行，并且每個Task最多只被執行一次。

Gradle在默認情況下為我們提供了幾個常用的Task，比如查看Project的Properties、顯示當前Project中定義的所有Task等。可以通過一下命令行查看Project中所有的Task：$ gradle tasks （具體log不再貼出來）。可以看到，Gradle默認為我們提供了dependencies、projects和properties等Task。dependencies用于顯示Project的依賴信息，projects用于顯示所有Project，包括根Project和子Project，而properties則用于顯示一個Project所包含的所有Property。

**Tips: **查看Project中所有的Task：gradle tasks 查看Project中所有的properties： gradle properties

在上面的build.gradle中加入如下代碼：

task myTask {  
    doFirst {  
        println 'hello'  
    }  
    doLast {  
        println 'world'  
    }  
}

這段代碼的含義：給Project添加一個名為“myTask”的任務
用一個閉包來配置這個任務,Task提供了doFirst和doLast方法來給自己添加Action。

其實build.gradle腳本的真正作用，就是配置一個Project實例。在執行build腳本之前，Gradle會為我們準備好一個Project實例，執行完腳本之后，Gradle會按照DAG依次執行任務。

自定義Task的寫法

看下面代碼文件路徑~/Test/build.gradle：

#1
task helloWorld << {
    println "Hello World"
}
#2 Test文件夾下建一個src目錄，建一個dst目錄，src目錄下建立一個文件，命名為test.txt
task copyFile(type: Copy){
    from "src"
    into "dst"
}

第一個這里的helloWorld是一個DefaultTask類型的對象，這也是定義一個Task時的默認類型，當然我們也可以顯式地聲明Task的類型，甚至可以自定義一個Task類型。
第二個代碼中（type：Copy）就是“顯式地聲明Task的類型”，執行gradle copyFile test.txt也跑到dst中去了。

如果task聲明在根Project的build.gradle中的allprojects()方法中，那么這個Task會應用于所有的Project。

task的依賴關系

Gradle不提供內建的項目生命周期管理，只是java Plugin向Project中添加了許多Task，這些Task依次執行，為我們營造了一種如同Maven般項目構建周期。那么這些task是如何依次執行的這就用到聲明的依賴關系taskA.dependsOn taskB看下面代碼：

task taskA << {
   println 'this is taskA from project 1'
}

task taskB << {
   println 'this is taskB from project 1'
}

taskA.dependsOn taskB

然后我們在命令行運行：
$ gradle taskA

運行結果會先執行taskB的打印，然后執行taskA的打印

如果是Muliti-Project的模式，依賴關系要帶著所屬的Project，如taskA.dependsOn ':other-project:taskC' 其中taskC位于和taskA不同的Project中，相對于AndroidStudio來說，就是位于不同的Module下的build.gradle中，而other-project為Module名字。

自定義Plugin的寫法

apply plugin: DateAndTimePlugin

dateAndTime {
    timeFormat = 'HH:mm:ss.SSS'
    dateFormat = 'MM/dd/yyyy'
}

class DateAndTimePlugin implements Plugin<Project> {
    //該接口定義了一個apply()方法，在該方法中，我們可以操作Project，
    //比如向其中加入Task，定義額外的Property等。
    void apply(Project project) {
        project.extensions.create("dateAndTime", DateAndTimePluginExtension)

        project.task('showTime') << {
            println "Current time is " + new Date().format(project.dateAndTime.timeFormat)
        }

        project.tasks.create('showDate') << {
            println "Current date is " + new Date().format(project.dateAndTime.dateFormat)
        }
    }
}
//每個Gradle的Project都維護了一個ExtenionContainer，
//我們可以通過project.extentions進行訪問
//比如讀取額外的Property和定義額外的Property等。
//向Project中定義了一個名為dateAndTime的extension
//并向其中加入了2個Property，分別為timeFormat和dateFormat
class DateAndTimePluginExtension {
    String timeFormat = "MM/dd/yyyyHH:mm:ss.SSS"
    String dateFormat = "yyyy-MM-dd"
}

Gradle Wrapper

Wrapper，顧名思義，其實就是對Gradle的一層包裝，便于在團隊開發過程中統一Gradle構建的版本，然后提交到git上，然后別人可以下載下來，這樣大家都可以使用統一的Gradle版本進行構建，避免因為Gradle版本不統一帶來的不必要的問題。（所以要明白這個東西可以沒有，有了只是為了統一管理，更加方便）

生成wrapper
gradle 內置了生成wrapper的task，我們可以命令行下執行：
$ gradle wrapper

生成后的目錄結構如下(用過AndroidStudio的很熟悉了)：

├── gradle
│ └── wrapper
│ ├── gradle-wrapper.jar
│ └── gradle-wrapper.properties
├── gradlew
└── gradlew.bat

  1. gradlew和gradlew.bat分別是Linux和Window下的可執行腳本，他們的用法和gradle原生命令是一樣的，gradle怎么用，他們也就可以怎么用。在MacOS下運行$ ./gradlew myTask
  2. gradle-wrapper.jar是具體業務邏輯實現的jar包，gradlew最終還是使用java執行的這個jar包來執行相關gradle操作。
  3. gradle-wrapper.properties是配置文件，用于配置使用哪個版本的gradle等

詳細的看下gradle-wrapper.properties內容

#Sat Jan 21 14:02:40 CST 2017
distributionBase=GRADLE_USER_HOME
distributionPath=wrapper/dists
zipStoreBase=GRADLE_USER_HOME
zipStorePath=wrapper/dists
distributionUrl=https\://services.gradle.org/distributions/gradle-2.14.1-bin.zip

從上面內容和文件的名稱都可以看出，這就是個java的配置文件,上面看到的是自動生成的，我們也可以手動修改。然后看下各個字段的含義：

  1. distributionBase 下載的gradle壓縮包解壓后存儲的主目錄
  2. distributionPath 相對于distributionBase的解壓后的gradle壓縮包的路徑
  3. zipStoreBase 同distributionBase，只不過是存放zip壓縮包的
  4. zipStorePath 同distributionPath，只不過是存放zip壓縮包的
  5. distributionUrl gradle發行版壓縮包的下載地址，也就是你現在這個項目將要依賴的gradle的版本。
refer to:

grale學習

深入理解Android之Gradle

?著作權歸作者所有,轉載或內容合作請聯系作者
平臺聲明：文章內容（如有圖片或視頻亦包括在內）由作者上傳并發布，文章內容僅代表作者本人觀點，簡書系信息發布平臺，僅提供信息存儲服務。

推薦閱讀更多精彩內容

  • 是什么？ 在語法上是基于Groovy語言的（Groovy 是一種基于JVM的敏捷開發語言，可以簡單的理解為強類型語...
    千山萬水迷了鹿閱讀 99,666評論 4贊 122
  • 前言 本文將會聊聊這兩周以來學習的Gradle 腳本知識點。先后閱讀了Gradle in Action 以及Gra...
    yjy239閱讀 1,344評論 1贊 5
  • 對Gradle的疑問 從剛學習Android開始，就對gradle有著好多疑問，隨著了解的越來越多，疑問也越來越多...
    362d4db360a5閱讀 1,544評論 0贊 1
  • 本文已授權微信公眾號 Android技術經驗分享 獨家發布轉載請注明出處：Gradle從入門到了解 通過這篇文章，...
    hongjay閱讀 5,366評論 7贊 82
  • 什么是gradle Gradle 是新一代的自動化構建工具，它是一個獨立的項目，跟 AS、Android 無關，官...
    Boreas_su閱讀 4,356評論 0贊 5