• 批處理符號簡介

回顯屏蔽 @

表示不顯示@后面的命令
@用法舉例：通過運行批處理文件對比pause和@pause命令即可明了@的效果。

重定向1 >與>>

將輸出信息重定向到指定的設備或文件。系統默認輸出到顯示器。
\>清除文件中原有的內容后再寫入
\>\>追加內容到文件末尾，而不會清除原有的內容主要將本來顯示在屏幕上的內容輸出到指定文件中指定文件如果不存在，則自動生成該文件
====================================================
echo hello world>c:/test.txt   生成c:/test.txt文件，內容為hello world這個格式在批處理文件里用得很多，可以生成.reg .bat .vbs 等臨時文件
type c:/test.txt >prn          屏幕上不顯示文件內容，轉向輸出到打印機
echo hello world>con           在屏幕上顯示hello world，實際上所有輸出都是默認 >con 的
copy c:/test.txt f: >nul       拷貝文件，并且不顯示"文件復制成功"的提示信息，但如果f盤不存在，還是會顯示出錯信息
copy c:/test.txt f: >nul 2>nul 不顯示"文件復制成功"的提示信息，并且f盤不存在的話，也不顯示錯誤提示信息
echo ^^W ^> ^W>c:/test.txt     生成的文件內容為 ^W > W^ 和 > 是控制命令，要把它們輸出到文件，必須在前面加個 ^符號
================================================

重定向2 <

將輸入信息來源重定向為指定的設備或文件。系統默認從顯示器讀取輸入信息。
重定向使用舉例：
=========================================
@echo off
echo abcdefg——這是文件a.txt中的信息>a.txt
echo 請任意輸入字符，以回車結束：
set /p ifo=
cls
echo 【 從屏幕獲得的輸入信息 】
echo %ifo%
set /p ifo=<a.txt
echo 【 從文件a.txt獲得的輸入信息 】
echo %ifo%
pause
=========================================

管道符號 |

前一個命令的執行結果輸出到后一個命令
dir *.* /s/a | find /c ".exe"管道命令表示先執行 dir 命令，對其輸出的結果執行后面的 find 命令該命令行結果：
輸出當前文件夾及所有子文件夾里的.exe文件的個數

轉義符 ^

將特殊符號轉化為一般符號，即剝離特殊符號的特殊地位。特殊符號指：| & > <
比如，如果我們想輸出符號“>”，直接用命令 echo > 是不行的，必須修改為 echo ^> 。其余幾個特殊符號類似需要有同樣的處理。
轉義字符使用舉例：
=========================================
@echo off
echo aaaa>a.txt
echo 第一句echo執行完畢
echo aaaa^>a.txt
echo 第二句echo執行完畢
pause
=========================================
比較上面的兩句echo，第一句echo將信息aaaa輸出到了文件a.txt，而第二句echo則在直接屏幕上顯示除aaaa>a.txt

邏輯命令符包括：&、&&、||

-&順序執行多條命令，而不管命令是否執行成功
    c: & cd/ & dir /w相當于把下面3行命令寫到1行去了c:cd/dir /w
-&&順序執行多條命令，當碰到執行出錯的命令后將不執行后面的命令
    f: && cd/ && dir >c:/test.txt注意如果f盤不存在，那么后面2條命令將不會執行
    find "ok" c:/test.txt && echo 成功如果找到了"ok"字樣，就顯示"成功"，找不到就不顯示
-||順序執行多條命令，當碰到執行正確的命令后將不執行后面的命令
    find "ok" c:/test.txt || echo 不成功如果找不到"ok"字樣，就顯示"不成功"，找到了就不顯示

• 批處理命令簡介

echo

echo 和 @
回顯命令
@                     #關閉單行回顯
echo off              #從下一行開始關閉回顯
@echo off             #從本行開始關閉回顯。一般批處理第一行都是這個
echo on               #從下一行開始打開回顯
echo                  #顯示當前是 echo off 狀態還是 echo on 狀態
echo.                 #輸出一個”回車換行”，空白行

errorlevel

echo %errorlevel%
每個命令運行結束，可以用這個命令行格式查看返回碼
默認值為0，一般命令執行出錯會設 errorlevel 為1
帶選擇的命令后可接受命令代碼，參看choice例子

rem

rem 和 ::
注釋命令
注釋行不執行操作

pause

暫停命令。運行 Pause 命令時，將顯示下面的消息：Press any key to continue. . .(或：請按任意鍵繼續. . .)
===========================================
@echo off
:begin
copy G:*.* d：/back
echo 請插入另一張光盤...
pause
goto begin
============================================
在這個例子中，驅動器 G 中磁盤上的所有文件均復制到d:/back中。顯示的注釋提示您將另一張光盤盤放入驅動器 G 時，pause 命令會使程序掛起，以便您更換光盤，然后按任意鍵繼續處理。

call

從一個批處理程序調用另一個批處理程序，并且不終止父批處理程序。call 命令接受用作調用目標的標簽。如果在腳本或批處理文件外使用 Call，它將不會在命令行起作用。
call [[Drive:][Path] FileName ] [:label [arguments]]
call test.bat //調用另一個bat文件
===========================================
@ echo off  
call :label  
echo 1  
echo 2  
:label  
echo 3  
echo 4  
===========================================
首先，我們看到，用call的時候，label前面的:不能丟掉，否則錯誤（當然，對于goto而言，你也可以加上:）。
另外，結果也不同，用call的時候結果為：341234
可以看到，goto很單純，直接Go to 到了某地方，而call則有點調用的意味，所以， goto 和call的還是有區別的。

start

調用外部程序，所有的DOS命令和命令行程序都可以由start命令來調用。 如：start calc.exe 即可打開Windows的計算器。

goto

goto 和 :
跳轉命令。程序指針跳轉到指定的標簽，從標簽后的第一條命令開始繼續執行批處理程序。
:label         #行首為:表示該行是標簽行，標簽行不執行操作
goto label     #跳轉到指定的標簽那一行

set

顯示、設置或刪除變量。
顯示變量：set 或 set s 前者顯示批處理當前已定義的所有變量及其值，后者顯示所有以s開頭的變量及值。
設置變量：set aa=abcd 此句命令便可向變量aa賦值abcd。
如果變量aa已被定義，則aa的值被修改為abcd；若aa尚未定義，則此句命令即可定義新的變量aa，同時為變量aa賦予初始值abcd。
刪除變量：set aa= 此句命令即可刪除變量aa。若變量aa已被定義，則刪除變量aa；若aa尚未定義，則此句命令為實質意義。
需要說明的是，批處理中的變量是不區分類型的，不需要像C語言中的變量那樣還要區分int、float、char等。比如執行set aa=345后，變量aa的值既可以被視為數字345，也可以被視為字符串345。
set命令具有擴展功能，如用作交互輸入、字符串處理、數值計算等，屬于高級命令范疇。

%0 %1 %2 %3 %4 %5 %6 %7 %8 %9 %*命令行傳遞給批處理的參數

%0 批處理文件本身
%1 第一個參數
%9 第九個參數
%* 從第一個參數開始的所有參數
批參數(%n)的替代已被增強。您可以使用以下語法
     %~1          - 刪除引號(")，擴充 %1
     %~f1         - 將 %1 擴充到一個完全合格的路徑名
     %~d1         - 僅將 %1 擴充到一個驅動器號
     %~p1         - 僅將 %1 擴充到一個路徑
     %~n1         - 僅將 %1 擴充到一個文件名
     %~x1         - 僅將 %1 擴充到一個文件擴展名
     %~s1         - 擴充的路徑指含有短名
     %~a1         - 將 %1 擴充到文件屬性
     %~t1         - 將 %1 擴充到文件的日期/時間
     %~z1         - 將 %1 擴充到文件的大小
     %~$PATH : 1 - 查找列在 PATH 環境變量的目錄，并將 %1
                   擴充到找到的第一個完全合格的名稱。如果環境
                   變量名未被定義，或者沒有找到文件，此組合鍵會
                   擴充到空字符串
可以組合修定符來取得多重結果:
    %~dp1        - 只將 %1 擴展到驅動器號和路徑
    %~nx1        - 只將 %1 擴展到文件名和擴展名
    %~dp$PATH:1 - 在列在 PATH 環境變量中的目錄里查找 %1，
                   并擴展到找到的第一個文件的驅動器號和路徑。
    %~ftza1      - 將 %1 擴展到類似 DIR 的輸出行。
可以參照 call/? 或 for/? 看出每個參數的含意
echo load "%%1" "%%2">c:test.txt
生成的文件內容為 load "%1" "%2"
批處理文件里，用這個格式把命令行參數輸出到文件
==============================================
在C盤根目錄新建test.bat，內容如下：
@echo off
echo %0
echo %1
echo %2
echo %*
運行cmd，輸入 c:/test.bat "/a" /b /c /d,可以看出每個參數的含意 修改test.bat內容如下
@echo off
echo %1
echo %~1
echo %0
echo %~f0
echo %~d0
echo %~p0
echo %~n0
echo %~x0
echo %~s0
echo %~a0
echo %~t0
echo %~z0
再運行cmd，輸入 c:/test.bat "/a" /b /c /d可以參照 call/? 或 for/? 看出每個參數的含意，注意這里可以對文件進行日期比較和大小比較:
echo load "%%1" "%%2">c:/test.txt
==============================================

set設置變量

設置變量
引用變量可在變量名前后加 % ，即 %變量名%
set                     #顯示目前所有可用的變量，包括系統變量和自定義的變量
echo %SystemDrive%      #顯示系統盤盤符。系統變量可以直接引用
set p                   #顯示所有以p開頭的變量，要是一個也沒有就設errorlevel=1
set p=aa1bb1aa2bb2      #設置變量p，并賦值為 = 后面的字符串，即aa1bb1aa2bb2
echo %p%                #顯示變量p代表的字符串，即aa1bb1aa2bb2
echo %p:~6%             #顯示變量p中第6個字符以后的所有字符，即aa2bb2
echo %p:~6,3%           #顯示第6個字符以后的3個字符，即aa2
echo %p:~0,3%           #顯示前3個字符，即aa1
echo %p:~-2%            #顯示最后面的2個字符，即b2
echo %p:~0,-2%          #顯示除了最后2個字符以外的其它字符，即aa1bb1aa2b
echo %p:aa=c%           #用c替換變量p中所有的aa，即顯示c1bb1c2bb2
echo %p:aa=%            #將變量p中的所有aa字符串置換為空，即顯示1bb12bb2
echo %p:*bb=c%          #第一個bb及其之前的所有字符被替換為c，即顯示c1aa2bb2
set p=%p:*bb=c%         #設置變量p，賦值為 %p:*bb=c% ，即c1aa2bb2
set /a p=39             #設置p為數值型變量，值為39
set /a p=39/10          #支持運算符，有小數時用去尾法，39/10=3.9，去尾得3，p=3
set /a p=p/10           #用 /a 參數時，在 = 后面的變量可以不加%直接引用
set /a p=”1&0″          #”與”運算，要加引號。其它支持的運算符參見set/?
set p=                  #取消p變量
set /p p=請輸入
屏幕上顯示”請輸入”，并會將輸入的字符串賦值給變量p
注意這條可以用來取代 choice 命令
注意變量在 if 和 for 的復合語句里是一次性全部替換的，如
@echo off
set p=aaa
if %p%==aaa (
     echo %p%
     set p=bbb
     echo %p%
     )
結果將顯示
aaa
aaa
因為在讀取 if 語句時已經將所有 %p% 替換為aaa
這里的"替換"，在 /? 幫助里就是指"擴充"、"環境變量擴充"
可以啟用”延緩環境變量擴充”，用 ! 來引用變量，即 !變量名!
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
set p=aaa
if %p%==aaa (
     echo %p%
     set p=bbb
     echo !p!
     )
ENDLOCAL
結果將顯示
aaa
bbb
還有幾個動態變量，運行 set 看不到
%CD%                   #代表當前目錄的字符串
%DATE%                 #當前日期
%TIME%                 #當前時間
%RANDOM%               #隨機整數，介于0~32767
%ERRORLEVEL%           #當前 ERRORLEVEL 值
%CMDEXTVERSION%        #當前命令處理器擴展名版本號
%CMDCMDLINE%           #調用命令處理器的原始命令行
可以用echo命令查看每個變量值，如 echo %time%
注意 %time% 精確到毫秒，在批處理需要延時處理時可以用到

choice 語句

@echo off
rem 以下在win2000pro運行通過，從win98里拷的chioce.com文件
choice /c:abc
if errorlevel 3 goto ccc
if %errorlevel%==2 goto bbb
if errorlevel==1 goto aaa
rem 必須先判斷數值高的返回碼rem 可以看到 errorlevel 值的判斷有3種寫法，有時某種寫法不好用，可以用另外的寫法
:aaa
echo aaa
goto end
:bbb
echo bbb
goto end
:ccc
echo ccc
goto end
:end

assoc 和 ftype文件關聯

assoc 和 ftype文件關聯assoc 設置'文件擴展名'關聯，關聯到'文件類型'ftype 設置'文件類型'關聯，關聯到'執行程序和參數'當你雙擊一個.txt文件時，windows并不是根據.txt直接判斷用 notepad.exe 打開而是先判斷.txt屬于 txtfile '文件類型'再調用 txtfile 關聯的命令行 txtfile=%SystemRoot%/system32/NOTEPAD.EXE %1可以在"文件夾選項"→"文件類型"里修改這2種關聯
assoc           #顯示所有'文件擴展名'關聯
assoc .txt      #顯示.txt代表的'文件類型'，結果顯示 .txt=txtfile
assoc .doc      #顯示.doc代表的'文件類型'，結果顯示 .doc=Word.Document.8
assoc .exe      #顯示.exe代表的'文件類型'，結果顯示 .exe=exefile
ftype           #顯示所有'文件類型'關聯
ftype exefile   #顯示exefile類型關聯的命令行，結果顯示 exefile="%1" %* assoc .txt=Word.Document.8設置.txt為word類型的文檔，可以看到.txt文件的圖標都變了
assoc .txt=txtfile恢復.txt的正確關聯 ftype exefile="%1" %*恢復 exefile 的正確關聯
如果該關聯已經被破壞，可以運行 command.com ，再輸入這條命令

pushd 和 popd切換當前目錄

@echo off
c: & cd/ & md mp3       #在 C:/ 建立 mp3 文件夾
md d:/mp4               #在 D:/ 建立 mp4 文件夾
cd /d d:/mp4            #更改當前目錄為 d:/mp4
pushd c:/mp3            #保存當前目錄，并切換當前目錄為 c:/mp3
popd                    #恢復當前目錄為剛才保存的 d:/mp4一般用處不大，在當前目錄名不確定時，會有點幫助

subst (外部命令)映射磁盤

subst z: //server/d     #這樣輸入z:就可以訪問//server/d了
subst z: /d             #取消該映射
subst                   #顯示目前所有的映

if

判斷命令
if "%1"=="/a" echo 第一個參數是/a
if /i "%1" equ "/a" echo 第一個參數是/a
/i 表示不區分大小寫，equ 和 == 是一樣的，其它運算符參見 if/?
if exist c:test.bat echo 存在c:test.bat文件
if not exist c:windows (
     echo 不存在c:windows文件夾
     )
if exist c:test.bat (
     echo 存在c:test.bat
     ) else (
     echo 不存在c:test.bat
     )

setlocal 和 endlocal

設置”命令擴展名”和”延緩環境變量擴充”
SETLOCAL ENABLEEXTENSIONS             #啟用"命令擴展名"
SETLOCAL DISABLEEXTENSIONS            #停用"命令擴展名"
SETLOCAL ENABLEDELAYEDEXPANSION       #啟用"延緩環境變量擴充"
SETLOCAL DISABLEDELAYEDEXPANSION      #停用"延緩環境變量擴充"
ENDLOCAL                              #恢復到使用SETLOCAL語句以前的狀態
“命令擴展名”默認為啟用
“延緩環境變量擴充”默認為停用
批處理結束系統會自動恢復默認值
可以修改注冊表以禁用"命令擴展名"，詳見 cmd /? 。所以用到"命令擴展名"的程
序，建議在開頭和結尾加上 SETLOCAL ENABLEEXTENSIONS 和 ENDLOCAL 語句，以確
保程序能在其它系統上正確運行
"延緩環境變量擴充"主要用于 if 和 for 的符合語句，在 set 的說明里有其實用例程

for

循環命令
這個比較復雜，請對照 for/? 來看
for %%i in (c: d: e: f:) do echo %%i
依次調用小括號里的每個字符串，執行 do 后面的命令
注意%%i，在批處理中 for 語句調用參數用2個%
默認的字符串分隔符是"空格鍵"，"Tab鍵"，"回車鍵"
for %%i in (*.txt) do find "abc" %%i
對當前目錄里所有的txt文件執行 find 命令
for /r . %%i in (*.txt) do find "abc" %%i
在當前目錄和子目錄里所有的.txt文件中搜索包含 abc 字符串的行
for /r . %%i in (.) do echo %%~pni
顯示當前目錄名和所有子目錄名，包括路徑，不包括盤符
for /r d:mp3 %%i in (*.mp3) do echo %%i>>d:mp3.txt
把 d:mp3 及其子目錄里的mp3文件的文件名都存到 d:mp3.txt 里去
for /l %%i in (2,1,8) do echo %%i
生成2345678的一串數字，2是數字序列的開頭，8是結尾，1表示每次加1
for /f %%i in ('set') do echo %%i
對 set 命令的輸出結果循環調用，每行一個
for /f "eol=P" %%i in ('set') do echo %%i
取 set 命令的輸出結果，忽略以 P 開頭的那幾行
for /f %%i in (d:mp3.txt) do echo %%i
顯示 d:mp3.txt 里的每個文件名，每行一個，不支持帶空格的名稱
for /f "delims=" %%i in (d:mp3.txt) do echo %%i
顯示 d:mp3.txt 里的每個文件名，每行一個，支持帶空格的名稱
for /f "skip=5 tokens=4" %%a in ('dir') do echo %%a
對 dir 命令的結果，跳過前面5行，余下的每行取第4列
每列之間的分隔符為默認的"空格"
可以注意到 dir 命令輸出的前5行是沒有文件名的
for /f "tokens=1,2,3 delims=- " %%a in ('date /t') do (
     echo %%a
     echo %%b
     echo %%c
     )
對 date /t 的輸出結果，每行取1、2、3列
第一列對應指定的 %%a ，后面的 %%b 和 %%c 是派生出來的，對應其它列
分隔符指定為 - 和"空格"，注意 delims=- 后面有個"空格"
其中 tokens=1,2,3 若用 tokens=1-3 替換，效果是一樣的
for /f "tokens=2* delims=- " %%a in ('date /t') do echo %%b
取第2列給 %%a ，其后的列都給 %%b

xcopy (外部命令)

文件拷貝
xcopy d:mp3 e:mp3 /s/e/i/y
復制 d:mp3 文件夾、所有子文件夾和文件到 e: ，覆蓋已有文件
加 /i 表示如果 e: 沒有 mp3 文件夾就自動新建一個，否則會有詢問

2021年12月16日，看著筆記寫了一個循環遞增字符串，就是賦不上值

set  a=a
:begin
set  a = %random%%a%
echo %a% > a.txt
ping /n 5 127.1 >nul
goto begin
最后發現是因為：在設置自定義變量時 set 變量后要緊跟=中間不能有空格