iOS-底層原理:alloc & init & new 源碼分析

在分析alloc源碼之前,先來看看一下3個變量 內存地址 和 指針地址 區別:

image

分別輸出3個對象的內容、內存地址、指針地址,下圖是打印結果

image

結論:通過上圖可以看出,3個對象指向的是同一個內存空間,所以其內容內存地址相同的,但是對象的指針地址是不同的

%p -> &p1:是對象的指針地址,
%p -> p1: 是對象指針指向的的內存地址

這就是本文需要探索的內容,alloc做了什么?init做了什么?

準備工作

alloc 源碼探索

alloc + init 整體源碼的探索流程如下

image
  • 【第一步】首先根據main函數中的LGPerson類的alloc方法進入alloc方法的源碼實現(即源碼分析開始),
//alloc源碼分析-第一步
+ (id)alloc {
    return _objc_rootAlloc(self);
}

  • 【第二步】跳轉至_objc_rootAlloc的源碼實現
//alloc源碼分析-第二步
id
_objc_rootAlloc(Class cls)
{
    return callAlloc(cls, false/*checkNil*/, true/*allocWithZone*/);
}

  • 【第三步】跳轉至callAlloc的源碼實現
static ALWAYS_INLINE id
callAlloc(Class cls, bool checkNil, bool allocWithZone=false)// alloc 源碼 第三步
{
#if __OBJC2__ //有可用的編譯器優化
    /*
     參考鏈接:http://www.lxweimin.com/p/536824702ab6
     */

    // checkNil 為false,!cls 也為false ,所以slowpath 為 false,假值判斷不會走到if里面,即不會返回nil
    if (slowpath(checkNil && !cls)) return nil;

    //判斷一個類是否有自定義的 +allocWithZone 實現,沒有則走到if里面的實現
    if (fastpath(!cls->ISA()->hasCustomAWZ())) {
        return _objc_rootAllocWithZone(cls, nil);
    }
#endif

    // No shortcuts available. // 沒有可用的編譯器優化
    if (allocWithZone) {
        return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
    }
    return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}

如上所示,在calloc方法中,當我們無法確定實現走到哪步時,可以通過斷點調試,判斷執行走哪部分邏輯。這里是執行到_objc_rootAllocWithZone

slowpath & fastpath

其中關于slowpathfastpath這里需要簡要說明下,這兩個都是objc源碼中定義的,其定義如下

//x很可能為真, fastpath 可以簡稱為 真值判斷
#define fastpath(x) (__builtin_expect(bool(x), 1)) 
//x很可能為假,slowpath 可以簡稱為 假值判斷
#define slowpath(x) (__builtin_expect(bool(x), 0)) 

其中的__builtin_expect指令是由gcc引入的,
1、目的:編譯器可以對代碼進行優化,以減少指令跳轉帶來的性能下降。即性能優化
2、作用:允許程序員將最有可能執行的分支告訴編譯器。
3、指令的寫法為:__builtin_expect(EXP, N)。表示 EXP==N的概率很大。
4、fastpath定義中__builtin_expect((x),1)表示 x 的值為真的可能性更大;即 執行if 里面語句的機會更大
5、slowpath定義中的__builtin_expect((x),0)表示 x 的值為假的可能性更大。即執行 else 里面語句的機會更大
6、在日常的開發中,也可以通過設置來優化編譯器,達到性能優化的目的,設置的路徑為:Build Setting --> Optimization Level --> Debug --> 將None 改為 fastest 或者 smallest

cls->ISA()->hasCustomAWZ()

其中fastpath中的 cls->ISA()->hasCustomAWZ() 表示判斷一個類是否有自定義的 +allocWithZone 實現,這里通過斷點調試,是沒有自定義的實現,所以會執行到 if 里面的代碼,即走到_objc_rootAllocWithZone

  • 【第四步】跳轉至_objc_rootAllocWithZone的源碼實現
id
_objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused)// alloc 源碼 第四步
{
    // allocWithZone under __OBJC2__ ignores the zone parameter
    //zone 參數不再使用 類創建實例內存空間
    return _class_createInstanceFromZone(cls, 0, nil,
                                         OBJECT_CONSTRUCT_CALL_BADALLOC);
}

  • 【第五步】跳轉至_class_createInstanceFromZone的源碼實現,這部分是alloc源碼的核心操作,由下面的流程圖及源碼可知,該方法的實現主要分為三部分
    • cls->instanceSize:計算需要開辟的內存空間大小
    • calloc申請內存,返回地址指針
    • obj->initInstanceIsa:將 類 與 isa 關聯
static ALWAYS_INLINE id
_class_createInstanceFromZone(Class cls, size_t extraBytes, void *zone,
                              int construct_flags = OBJECT_CONSTRUCT_NONE,
                              bool cxxConstruct = true,
                              size_t *outAllocatedSize = nil)// alloc 源碼 第五步
{
    ASSERT(cls->isRealized()); //檢查是否已經實現

    // Read class's info bits all at once for performance
    //一次性讀取類的位信息以提高性能
    bool hasCxxCtor = cxxConstruct && cls->hasCxxCtor();
    bool hasCxxDtor = cls->hasCxxDtor();
    bool fast = cls->canAllocNonpointer();
    size_t size;

    //計算需要開辟的內存大小,傳入的extraBytes 為 0
    size = cls->instanceSize(extraBytes);
    if (outAllocatedSize) *outAllocatedSize = size;

    id obj;
    if (zone) {
        obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
    } else {
        //申請內存
        obj = (id)calloc(1, size);
    }
    if (slowpath(!obj)) {
        if (construct_flags & OBJECT_CONSTRUCT_CALL_BADALLOC) {
            return _objc_callBadAllocHandler(cls);
        }
        return nil;
    }

    if (!zone && fast) {
        //將 cls類 與 obj指針(即isa) 關聯
        obj->initInstanceIsa(cls, hasCxxDtor);
    } else {
        // Use raw pointer isa on the assumption that they might be
        // doing something weird with the zone or RR.
        obj->initIsa(cls);
    }

    if (fastpath(!hasCxxCtor)) {
        return obj;
    }

    construct_flags |= OBJECT_CONSTRUCT_FREE_ONFAILURE;
    return object_cxxConstructFromClass(obj, cls, construct_flags);
}

根據源碼分析,得出其實現流程圖如下所示:

image

alloc 核心操作

核心操作都位于calloc方法中

cls->instanceSize:計算所需內存大小

計算需要開辟內存的大小的執行流程如下所示

image
  • 1、跳轉至instanceSize的源碼實現
size_t instanceSize(size_t extraBytes) const {
    //編譯器快速計算內存大小
    if (fastpath(cache.hasFastInstanceSize(extraBytes))) {
        return cache.fastInstanceSize(extraBytes);
    }

    // 計算類中所有屬性的大小 + 額外的字節數0
    size_t size = alignedInstanceSize() + extraBytes;
    // CF requires all objects be at least 16 bytes.
    //如果size 小于 16,最小取16
    if (size < 16) size = 16;
    return size;
}

通過斷點調試,會執行到cache.fastInstanceSize方法,快速計算內存大小

  • 2、跳轉至fastInstanceSize的源碼實現,通過斷點調試,會執行到align16
size_t fastInstanceSize(size_t extra) const
{
    ASSERT(hasFastInstanceSize(extra));

    //Gcc的內建函數 __builtin_constant_p 用于判斷一個值是否為編譯時常數,如果參數EXP 的值是常數,函數返回 1,否則返回 0
    if (__builtin_constant_p(extra) && extra == 0) {
        return _flags & FAST_CACHE_ALLOC_MASK16;
    } else {
        size_t size = _flags & FAST_CACHE_ALLOC_MASK;
        // remove the FAST_CACHE_ALLOC_DELTA16 that was added
        // by setFastInstanceSize
        //刪除由setFastInstanceSize添加的FAST_CACHE_ALLOC_DELTA16 8個字節
        return align16(size + extra - FAST_CACHE_ALLOC_DELTA16);
    }
}

  • 3、跳轉至align16的源碼實現,這個方法是16字節對齊算法
//16字節對齊算法
static inline size_t align16(size_t x) {
    return (x + size_t(15)) & ~size_t(15);
}

內存字節對齊原則

在解釋為什么需要16字節對齊之前,首先需要了解內存字節對齊的原則,主要有以下三點

  • 數據成員對齊規則:struct 或者 union 的數據成員,第一個數據成員放在offset為0的地方,以后每個數據成員存儲的起始位置要從該成員大小或者成員的子成員大小(只要該成員有子成員,比如數據、結構體等)的整數倍開始(例如int在32位機中是4字節,則要從4的整數倍地址開始存儲)
  • 數據成員為結構體:如果一個結構里有某些結構體成員,則結構體成員要從其內部最大元素大小的整數倍地址開始存儲(例如:struct a里面存有struct b,b里面有char、int、double等元素,則b應該從8的整數倍開始存儲)
  • 結構體的整體對齊規則:結構體的總大小,即sizeof的結果,必須是其內部做大成員的整數倍,不足的要補齊

為什么需要16字節對齊

需要字節對齊的原因,有以下幾點:

  • 通常內存是由一個個字節組成的,cpu在存取數據時,并不是以字節為單位存儲,而是以為單位存取,塊的大小為內存存取力度。頻繁存取字節未對齊的數據,會極大降低cpu的性能,所以可以通過減少存取次數降低cpu的開銷
  • 16字節對齊,是由于在一個對象中,第一個屬性isa8字節,當然一個對象肯定還有其他屬性,當無屬性時,會預留8字節,即16字節對齊,如果不預留,相當于這個對象的isa和其他對象的isa緊挨著,容易造成訪問混亂
  • 16字節對齊后,可以加快CPU讀取速度,同時使訪問更安全,不會產生訪問混亂的情況

字節對齊-總結

  • 在字節對齊算法中,對齊的主要是對象,而對象的本質則是一個 struct objc_object的結構體,
  • 結構體在內存中是連續存放的,所以可以利用這點對結構體進行強轉。
  • 蘋果早期是8字節對齊,現在16字節對齊

下面以align(8) 為例,圖解16字節對齊算法的計算過程,如下所示

image
  • 首先將原始的內存 8size_t(15)相加,得到 8 + 15 = 23
  • size_t(15) 即 15進行~(取反)操作,~(取反)的規則是:1變為0,0變為1
  • 最后將 23 與 15的取反結果 進行 &(與)操作,&(與)的規則是:都是1為1,反之為0,最后的結果為 16,即內存的大小是以16的倍數增加的
calloc:申請內存,返回地址指針

通過instanceSize計算的內存大小,向內存中申請 大小 為 size的內存,并賦值給obj,因此 obj是指向內存地址的指針

obj = (id)calloc(1, size);

這里我們可以通過斷點來印證上述的說法,在未執行calloc時,po objnil,執行后,再po obj法線,返回了一個16進制的地址

image

在平常的開發中,一般一個對象的打印的格式都是類似于這樣的<LGPerson: 0x01111111f>(是一個指針)。為什么這里不是呢?

  • 主要是因為objc 地址 還沒有與傳入 的 cls進行關聯,
  • 同時印證了 alloc的根本作用就是 開辟內存
obj->initInstanceIsa:類與isa關聯

經過calloc可知,內存已經申請好了,類也已經傳入進來了,接下來就需要將 類與 地址指針 即isa指針進行關聯,其關聯的流程圖如下所示

image

主要過程就是初始化一個isa指針,并將isa指針指向申請的內存地址,在將指針與cls類進行 關聯

同樣也可以通過斷點調試來印證上面的說法,在執行完initInstanceIsa后,在通過po obj可以得出一個對象指針

image

總結

  • 通過對alloc源碼的分析,可以得知alloc的主要目的就是開辟內存,而且開辟的內存需要使用16字節對齊算法,現在開辟的內存的大小基本上都是16的整數倍
  • 開辟內存的核心步驟有3步:計算 -- 申請 -- 關聯

init 源碼探索

alloc源碼探索完了,接下來探索init源碼,通過源碼可知,inti的源碼實現有以下兩種

類方法 init

+ (id)init {
    return (id)self;
}

這里的init是一個構造方法 ,是通過工廠設計(工廠方法模式),主要是用于給用戶提供構造方法入口。這里能使用id強轉的原因,主要還是因為 內存字節對齊后,可以使用類型強轉為你所需的類型

實例方法 init

  • 通過以下代碼進行探索實例方法 init
LGPerson *objc = [[LGPerson alloc] init];

  • 通過main中的init跳轉至init的源碼實現
- (id)init {
    return _objc_rootInit(self);
}

  • 跳轉至_objc_rootInit的源碼實現
id
_objc_rootInit(id obj)
{
    // In practice, it will be hard to rely on this function.
    // Many classes do not properly chain -init calls.
    return obj;
}

有上述代碼可以,返回的是傳入的self本身。

new 源碼探索

一般在開發中,初始化除了init,還可以使用new,兩者本質上并沒有什么區別,以下是objc中new的源碼實現,通過源碼可以得知,new函數中直接調用了callAlloc函數(即alloc中分析的函數),且調用了init函數,所以可以得出new 其實就等價于 [alloc init]的結論

+ (id)new {
    return [callAlloc(self, false/*checkNil*/) init];
}

但是一般開發中并不建議使用new,主要是因為有時會重寫init方法做一些自定義的操作,例如 initWithXXX,會在這個方法中調用[super init],用new初始化可能會無法走到自定義的initWithXXX部分。

例如,在CJLPerson中有兩個初始化方法,一個是重寫的父類的init,一個是自定義的initWithXXX方法,如下圖所示

image
  • 使用 alloc + init 初始化時,打印的情況如下

    image
  • 使用new 初始化時,打印的情況如下

    image

總結

  • 如果子類沒有重寫父類的init,new會調用父類的init方法
  • 如果子類重寫了父類的init,new會調用子類重寫的init方法
  • 如果使用 alloc + 自定義的init,可以幫助我們自定義初始化操作,例如傳入一些子類所需參數等,最終也會走到父類的init,相比new而言,擴展性更好,更靈活。

注:可在github下載已經編譯成功的objc-781源碼

補充

【問題】為什么無法斷點到obj->initInstanceIsa(cls, hasCxxDtor);

主要是因為斷點斷住的不是 自定義類的流程,而是系統級別的

image
最后編輯于
?著作權歸作者所有,轉載或內容合作請聯系作者
平臺聲明:文章內容(如有圖片或視頻亦包括在內)由作者上傳并發布,文章內容僅代表作者本人觀點,簡書系信息發布平臺,僅提供信息存儲服務。