使用Groovy開發(fā)之新特性

一個java程序員剛開始使用Groovy的時候，不可避免的滿腦子想的都是java，當(dāng)熟悉Groovy后就會代碼會逐漸符合Groovy語言習(xí)慣，從而變得更加高產(chǎn)。下面介紹一下一些通用的Groovy語法：

1、不需要分號

學(xué)過C/C++/C#/java的同學(xué)都會對分號很熟悉，我們使用的如此頻繁，幾乎放在每一行的末尾。Groovy支持99%的java語法，甚至可以在Groovy代碼中直接粘貼java代碼，然而在Groovy中分號是可選的，你可以省略他們。

2、return關(guān)鍵字可省略

在Groovy中，方法的最后一句表達(dá)式可作為返回值返回，而不需要return關(guān)鍵字。

String toString() { return "a server" }
String toString() { "a server" }

但有時候省略return關(guān)鍵字并不是一個好主意

def props() {
    def m1 = [a: 1, b: 2]
    m2 = m1.findAll { k, v -> v % 2 == 0 } 
    m2.c = 3
    m2
}

在這種情況下，明確的使用return關(guān)鍵字會更具可讀性。

3、def 和 類型

在Groovy中使用def關(guān)鍵字定義的變量類型都是Object，定義方法是，通常可以省略def關(guān)鍵字，盡量別def和類型混用，避免這種寫法def String name = "Guillaume"。

定義方法時，如果參數(shù)沒有類型，我們可以省略def：

void doSomething(param1, param2) { }

定義類的構(gòu)造器時，避免添加def關(guān)鍵字：

class MyClass {
    MyClass() {}
}

4、默認(rèn)是public權(quán)限

默認(rèn)情況下，Groovy的classes和方法是public權(quán)限，所以我們可以省略public關(guān)鍵字，除非我們想使用private：

class Server { 
   String toString() { "a server" }
}

5、省略圓括號()

Groovy允許你在頂級表達(dá)式中省略圓括號，例如println：

println "Hello"
method a, b

某些情況下，Groovy不允許省略圓括號，比如：

def foo(n) { n }
println foo 1 // won't work

6、Classes是一等公民

在Groovy中.class后綴不是必須的，類似于java的instance。例如：

connection.doPost(BASE_URI + "/modify.hqu", params, ResourcesResponse.class)

使用GStrings，并使用class一等公民：

connection.doPost("${BASE_URI}/modify.hqu", params, ResourcesResponse)

7、Getters and Setters

getter和setter方法來自屬性，Groovy中，提供了一個簡短的獲取和設(shè)置屬性的方法，你可以省略getter和setter：

resourceGroup.getResourcePrototype().getName() == SERVER_TYPE_NAME
resourceGroup.resourcePrototype.name == SERVER_TYPE_NAME
resourcePrototype.setName("something")
resourcePrototype.name = "something"

當(dāng)你在Groovy中創(chuàng)建一個beans的時候，通常我們稱為POGOS(Plain Old Groovy Objects)，Groovy會自動幫我們創(chuàng)建getter/setter方法，所以你可以把

class Person {
    private String name
    String getName() { return name }
    void setName(String name) { this.name = name }
}

替換為

class Person {
    String name
}

當(dāng)你對getter/setter方法有特殊要求，你盡可提供自己的方法，Groovy默認(rèn)的getter/setter方法會被替換。

8、使用命名的參數(shù)初始化beans和默認(rèn)的構(gòu)造器

有一個bean

class Server {
    String name
    Cluster cluster
}

初始化一個實例的時候你可能會這樣寫：

def server = new Server()
server.name = "Obelix"
server.cluster = aCluster

其實你可以用帶命名的參數(shù)的默認(rèn)構(gòu)造器，會大大減少代碼量：

def server = new Server(name: "Obelix", cluster: aCluster)

9、在同一個bean中使用with()來重復(fù)某一個操作

當(dāng)更新一個實例的時候，你可以使用with()來省略相同的前綴，java中你必須這樣寫：

server.name = application.name
server.status = status
server.sessionCount = 3
server.start()
server.stop()

Groovy中則可以使用with():

server.with {
    name = application.name
    status = status
    sessionCount = 3
    start()
    stop()
}

10、Equals 和 ==

Java里的==等同于Groovy里的is()方法，Groovy中的==是更智能的equals()，比較兩個類的時候，你應(yīng)該使用a.is(b),而不是==。

Groovy中的==可以自動避免NullPointerException異常：
替換

status != null && status.equals(ControlConstants.STATUS_COMPLETED)

為

status == ControlConstants.STATUS_COMPLETED

11、GStrings字符串分行

Java中，字符串過長需要換行時我們一般會這樣寫：

throw new PluginException("Failed to execute command list-applications:" +
    " The group with name " +
    parameterMap.groupname[0] +
    " is not compatible group of type " +
    SERVER_TYPE_NAME)

Groovy中你可以用 \ 字符：

throw new PluginException("Failed to execute command list-applications: \
The group with name ${parameterMap.groupname[0]} \
is not compatible group of type ${SERVER_TYPE_NAME}")

或者使用多行字符串""":

throw new PluginException("""Failed to execute command list-applications:
    The group with name ${parameterMap.groupname[0]}
    is not compatible group of type ${SERVER_TYPE_NAME)}""")

Groovy中，單引號引起來的字符串是java字符串，不能使用占位符來替換變量，雙引號引起的字符串則是java字符串或者Groovy字符串。

12、一些操作數(shù)據(jù)結(jié)構(gòu)的方法

def list = [1, 4, 6, 9]

// Map的key默認(rèn)是字符串類型，可以省略雙引號
//你可以用()將keys包起來插入一個變量或者類作為key，例如 [(variableStateAcronym): stateName]
def map = [CA: 'California', MI: 'Michigan']

def range = 10..20
def pattern = ~/fo*/

// <<相當(dāng)于 add()
list << 5

// 調(diào)用包含方法
assert 4 in list
assert 5 in list
assert 15 in range

// subscript notation
assert list[1] == 4

// map添加key-value對
map << [WA: 'Washington']
// subscript notation
assert map['CA'] == 'California'
// property notation
assert map.WA == 'Washington'

// 匹配正則表達(dá)式
assert 'foo' =~ pattern

13、switch方法

Groovy的switch方法更具實用性，可以接受更多的類型：

def x = 1.23
def result = ""
switch (x) {
    case "foo": result = "found foo"
    // lets fall through
    case "bar": result += "bar"
    case [4, 5, 6, 'inList']: result = "list"
    break
    case 12..30: result = "range"
    break
    case Integer: result = "integer"
    break
    case Number: result = "number"
    break
    case { it > 3 }: result = "number > 3"
    break
    default: result = "default"
}
assert result == "number"

types也可以調(diào)用isCase()方法判斷一個值是否等于某一個case。

14、Import 別名

在java中使用兩個類名相同但包名不同的兩個類，像java.util.List 和 java.wt.List，你必須使用完整的包名才能區(qū)分。Groovy中則可以使用import別名：

import java.util.List as jurist
import java.awt.List as aList
import java.awt.WindowConstants as WC

也可以靜態(tài)引入方法：

import static pkg.SomeClass.foo
foo()

15、判斷是否為真

所有類型都能轉(zhuǎn)成布爾值，比如null和void相當(dāng)于0或者相當(dāng)于false，其他則相當(dāng)于true，所以替換：

if (name != null && name.length > 0) {}

為

if (name) {}

在Groovy中可以在類中添加asBoolean()方法來自定義是否為真。

16、安全的取值

在java中，你要獲取某個對象的值必須要檢查是否為null，這就造成了大量的if語句，像這樣的：

if (order != null) {
    if (order.getCustomer() != null) {
        if (order.getCustomer().getAddress() != null) {
            System.out.println(order.getCustomer().getAddress());
        }
    }
}

Groovy中可以使用？.安全的取值：

println order?.customer?.address

17、斷言

檢查方法傳入的參數(shù)是否為空，你可以使用assert來檢查：

def check(String name) {
    // name non-null and non-empty according to Groovy Truth
    assert name
    // safe navigation + Groovy Truth to check
    assert name?.size() > 3
}

18、三目運(yùn)算符

三目運(yùn)算符通常用來給定默認(rèn)值，我們經(jīng)常這樣寫：

def result = name != null ? name : "Unknown"

多虧了Groovy的真值，空值檢查可以簡化為'name'，并且可以省略？和:之間的變量：

def result = name ?: "Unknown"

19、捕獲任何異常

如果你實在不想關(guān)心try塊里拋出何種異常，你可以簡單的捕獲所有異常，并且可以省略異常類型：

try {
    // ...
} catch (Exception t) {
    // something bad happens
}

省略異常類型：

try {
    // ...
} catch (any) {
    // something bad happens
}

這里的any并不包括Throwable，如果你真想捕獲everything，你必須明確的標(biāo)明你想捕獲Throwable

最后編輯于 ：
?著作權(quán)歸作者所有,轉(zhuǎn)載或內(nèi)容合作請聯(lián)系作者
平臺聲明：文章內(nèi)容（如有圖片或視頻亦包括在內(nèi)）由作者上傳并發(fā)布，文章內(nèi)容僅代表作者本人觀點(diǎn)，簡書系信息發(fā)布平臺，僅提供信息存儲服務(wù)。

推薦閱讀更多精彩內(nèi)容

  • Spring Cloud為開發(fā)人員提供了快速構(gòu)建分布式系統(tǒng)中一些常見模式的工具（例如配置管理，服務(wù)發(fā)現(xiàn)，斷路器，智...
    卡卡羅2017閱讀 134,868評論 18贊 139
  • groovy是什么 Groovy 是下一代的Java語言，跟java一樣,它也運(yùn)行在 JVM 中。 作為跑在JVM...
    ronaldo18閱讀 702評論 0贊 4
  • 前言 由于項目需要用到 Groovy 語言，這兩天對其進(jìn)行了粗略的學(xué)習(xí)，本文是對學(xué)習(xí)做的一個簡單總結(jié)，主要內(nèi)容參考...
    簡單的土豆閱讀 189,044評論 12贊 201
  • 什么是 Groovy？ 簡言之，Groovy是一種基于JVM（Java虛擬機(jī)）的敏捷動態(tài)開發(fā)語言。它是一種成熟的面...
    北緯26閱讀 4,152評論 0贊 14
  • Groovy是一門基于JVM的動態(tài)語言，很多語法和Java類似。大部分Java代碼也同時是合法的Groovy代碼。...
    樂百川閱讀 3,609評論 0贊 15