.MODEL  TINY
.STACK      100
.DATA    

BUFFER DB 10 DUP(?);BUFFER存放8個不確定數
augend DB 2 DUP(?) ;被加數
addend DB 2 DUP(?) ;加數
msg1 DB 0DH,0AH,'請輸入被加數: $'
msg2 DB 0DH,0AH,'請輸入加數: $'
msg3 DB 0DH,0AH,'結果： $';msg3存放結果
;0DH和0AH分別是回車和換行的ASCII碼,
;'$'是DOS功能調用INT 21H中9號功能要求的要顯示字符串的結束標志
.CODE
START: MOV AX,@DATA
MOV DS,AX
MOV ES,AX
CLD ;方向標志位清零 ;CLD與STD是用來操作方向標志位DF（Direction Flag）。
;CLD使DF復位，即DF=0，STD使DF置位，即DF=1.用于串操作指令中
NOP ;空操作 ;NOP指令只使程序計數器PC加1，所以占用一個機器周期
;其目的為保證寫、讀之間有個穩定時間
MOV AH,00H
MOV AL,03H
INT 10H ;清屏
START1: MOV AH,09H ;9號調用DX指向被加數的首地址，輸出提示信息
LEA DX,msg1 ;將源操作數給出的有效地址傳送到指定的的寄存器中
INT 21H
LEA DI,augend ;DI->augend的首地址
MOV CX,4 ;按鍵次數
CALL GetBCDKey ;得到雙字節十進制數(被加數)
JNB START2 ;沒有輸入任何數字,結束 CF=0
MOV AH,09H ;9號調用DX指向加數的首地址
LEA DX,msg2 ;將源操作數給出的有效地址傳送到指定的的寄存器中
INT 21H
LEA DI,addend ;di指向加數
MOV CX,4 ;按鍵次數
CALL GetBCDKey ;得到雙字節十進制數(加數)
JNB START2 ;沒有輸入任何數字,結束
MOV AL,augend ;被加數的低8位送al
ADD AL,addend ;al與加數的低位相加的結果送al
DAA ;BCD算術運算調整，轉換為壓縮型BCD
XCHG AL,AH ;高位與低位互換
MOV AL,augend + 1
ADC AL,addend + 1 ;高位
DAA
XCHG AL,AH
MOV BL,0
ADC BL,0 ;進位 bl存放的是進位 bl和ax相加是最后的結果
STD ;方向標志置1
LEA DI,BUFFER+4 ;存放顯示結果
CALL B1toB2 ;低位
MOV AL,AH
CALL B1toB2 ;高位
MOV AL,BL
OR AL,30H ;轉換成數字
STOSB ;存數
LEA SI,BUFFER
MOV CX,5
CALL BlackDisplay ;將高位0消隱
MOV AH,09H
LEA DX,msg3 ;9號調用DX指向結果的首地址
INT 21H
MOV AH,09H
LEA DX,BUFFER ;9號調用DX指向BUFFER的首地址
INT 21H
JMP START1 ;跳轉到START1
START2: MOV AH,4CH ;結束程序
INT 21H
; JMP $

;將一個字節壓縮BCD碼轉換成二個字節數字
B1toB2 PROC NEAR ;段內
PUSH AX ;ax存放的是相加后的結果
AND AL,0FH ;高四位置0
OR AL,30H ;加30H
STOSB ;存數 個位 百位
POP AX
AND AL,0F0H ;低四位置0
ROR AL,4 ;循環右移4位
OR AL,30H ;加30H
STOSB ;存數 十位 千位
RET
B1toB2 ENDP

BlackDisplay PROC NEAR
CLD ;方向標志清零
MOV DI,SI ;si送給di si指向buff的第一個緩沖區 增量變化
BlackDisplay1: LODSB ;將高位0消隱，取串
CMP AL,'0'
JNZ Exit ;若al不等于0跳轉EXIT
LOOP BlackDisplay1 ;否則cx不為0一直循環 cx次
INC CX ;cx加1
Exit: DEC SI ;si前移
REP MOVSB ;重復傳送字節
MOV AL,'$' ;把$符送al
STOSB ;存數
RET
BlackDisplay ENDP

GetBCDKey PROC NEAR
LEA SI,BUFFER
MOV AL,4 ;把4寫入到buff
MOV [SI],AL ;【】是內存單元
MOV DX,SI
MOV AH,0AH ;dx指向緩沖區
MOV AL,02H ;0:任意字符 1:16進制數 2:10進制數，10進制數輸入
INT 21H

    MOV AL,[BUFFER+1]   ;把內存數據段buff地址+1的值給al
    XOR AH,AH           ;AH清零 異或指令
    MOV CX,AX           ;ax的內容送CX cx的值是數據的個數
    JCXZ    GetBCDKey3      ;cx為0，轉向GetBCDKey3 判斷cx直接回車cx=0
    LEA SI,BUFFER+1     ;不為0
    ADD SI,AX           ;ax=4 si=5
    STD                     ;std 使si或di遞增

GetBCDKey1: LODSB ;ds:si->al
AND AL,0FH ;高4位清零
CMP CX,1 ;
JE GetBCDKey2
DEC CX ;進數位-1
MOV AH,AL
LODSB
AND AL,0FH
SHL AL,4 ;邏輯左移4位
OR AL,AH ;
GetBCDKey2: CLD
STOSB ;存串指令
STD
LOOP GetBCDKey1 ;cx=2 原先為4 上面減了一次一 loop再減一所以等于2
MOV CL,[BUFFER]
SUB CL,[BUFFER+1]
SHR CL,1 ;邏輯右移1位
MOV AL,0
CLD
REP STOSB ;重復存數
STC ;進位標志位置1
RET
GetBCDKey3: CLC ;進位標志位清零cf=0
RET ;返回
GetBCDKey ENDP

    END START