最近用Common Lisp開發(fā)一個個人項目，需要記錄發(fā)出的HTTP請求的參數(shù)，包括了目標地址、HTTP body，以及HTTP頭部等多種信息。為了可以結構化地存儲這些數(shù)據(jù)（比如HTTP頭部是由多個鍵值對組成的），我選擇將它們保存到MongoDB中。Google一番后，我找到了cl-mongo這個庫，可以在Common Lisp中讀寫MongoDB，嘗試了一下也確實可以滿足自己的需求。為了方便自己查閱，也為了方便有相同需求的人了解如何使用cl-mongo，于是寫了這篇文章。

首先使用CL-MONGO:MONGO函數(shù)連接MongoDB的服務器程序（mongod）。因為在我的系統(tǒng)上mongod進程監(jiān)聽的是27017這個端口，并且我希望使用的數(shù)據(jù)庫名為test，因此鍵入如下代碼來連接數(shù)據(jù)庫

(cl-mongo:mongo :db "test"
                :host "127.0.0.1"
                :port 27017)

連接上了數(shù)據(jù)庫后，首先嘗試往其中寫入一個文檔。假設現(xiàn)在要記錄的是發(fā)出的HTTP請求的信息，那么一個可以寫入的基本信息就是請求的目標地址。假設在命令行的mongo shell中輸入的內容如下

db.http_request.insert({uri: 'http://example.com'});

那么使用cl-mongo提供的DB.INSERT函數(shù)達到上述效果的代碼如下

(cl-mongo:db.insert "http_request"
                    (cl-mongo:kv "uri" "http://example.com"))

求值上述代碼后返回值為NIL。為了將上述寫入的文檔重新查詢出來，需要使用cl-mongo提供的DB.FIND函數(shù)。因為只有一個文檔，所以直接查詢就可以查看到結果了。在mongo shell中我們可以使用如下代碼查詢

db.http_request.find();

使用DB.FIND函數(shù)的話編寫的代碼可能會長得像下面這樣

(cl-mongo:db.find "http_request" :all)

在我的系統(tǒng)上求值了上述代碼后在REPL中輸出的內容如下

((86 449 0 1 8 0 0 1 "http_request")
 (<CL-MONGO:DOCUMENT> : { 
   _id : CL-MONGO::BSON-OID [#(89 52 26 160 109 156 254 71 184 115 102 30)]
   elements : 1}

))

值得注意的是，DB.FIND的返回值不完全是文檔組成的數(shù)組，而是在這個結果集的數(shù)組之外又多了一層列表，并且列表的第一個元素還是一個一看之下不知其所以然的子列表。由于cl-mongo的GitHub上沒有提及這個玩意兒的來歷，我也沒有深入去了解DB.FIND函數(shù)的實現(xiàn)代碼，因此這個元素就先忽略它吧。如果需要使用DB.FIND查詢到的結果，那么開發(fā)者需要對DB.FIND的返回值應用一下函數(shù)SECOND才行，如下

(second (cl-mongo:db.find "http_request" :all))

返回值的列表中的每一個元素都是CL-MONGO:DOCUMENT這個類的實例對象，如果要直接使用還是稍微有點不方便的，因此我寫了一個函數(shù)用來將DB.FIND函數(shù)查詢到的CL-MONGO:DOCUMENT的實例對象都轉換為較為熟悉，容易操作的數(shù)據(jù)類型——association list，函數(shù)的定義如下

(defun document-to-alist (doc)
  "Convert a DOC of type CL-MONGO:DOCUMENT to a equivalent, serializable alist."
  (check-type doc cl-mongo:document)
  (labels ((aux (doc)
             (cond ((typep doc 'cl-mongo:document)
                    (let ((keys (cl-mongo:get-keys doc)))
                      (mapcar #'(lambda (key)
                                  (cons key
                                        (aux (cl-mongo:get-element key doc))))
                              keys)))
                   (t doc))))
    (let ((id (cl-mongo:doc-id doc)))
      (append (aux doc) (list (cons "_id" id))))))

使用如下代碼即可查看方才所寫入的文檔究竟長什么樣子了

(document-to-alist (first (second (cl-mongo:db.find "http_request" :all))))

如果想要修改數(shù)據(jù)庫中的文檔，例如增加一個字段，那么可以使用cl-mongo提供的DB.UPDATE函數(shù)，用法如下

(cl-mongo:db.update "http_request"
                    (cl-mongo:kv "uri" "http://example.com")
                    (cl-mongo:kv "$set"
                                 (cl-mongo:kv "method" "GET")))

最后如果要刪除剛才所寫入的這個文檔，可以使用cl-mongo的DB.DELETE函數(shù)（我很好奇這個函數(shù)居然不是叫做DB.REMOVE），用法如下

(cl-mongo:db.delete "http_request"
                    (cl-mongo:kv "uri" "http://example.com"))