由于官網的例子很全面，因此這里直接套用Kotlin官網的例子：

open class D {
}

class D1 : D() {
}

open class C {
    open fun D.foo() {
        println("D.foo in C")
    }

    open fun D1.foo() {
        println("D1.foo in C")
    }

    fun caller(d: D) {
        d.foo()   // call the extension function
    }
}

class C1 : C() {
    override fun D.foo() {
        println("D.foo in C1")
    }

    override fun D1.foo() {
        println("D1.foo in C1")
    }
}

C().caller(D())   // prints "D.foo in C"
C1().caller(D())  // prints "D.foo in C1" - dispatch receiver is resolved virtually
C().caller(D1())  // prints "D.foo in C" - extension receiver is resolved statically

例子很簡單，無非就是Extension的聲明和如何調用Extension方法（注意：這里調用Members' Extension 通過了實例方法的轉接，可以跟Kotlin Extension - Method中提到的無法在.kt文件中從實例或者外界直接拿到Extension方法引用聯系起來）
這里Kotlin定義了兩個重要的概念：

dispatch receiver: 指的便是例子中執行caller() 方法的C或者C1實例對象

extension receiver: 指的便是例子中caller() 方法定義中執行Extension方法foo() 的對象

接下來看看三個例子給我們揭示的一些重要現象

1. C().caller(D1())

很明顯，我們這里往caller()方法里面傳的是extension receiver類型是D1，但是為何最后調用的是父類D的Extension方法呢?
通過反編譯生成的.class文件我們找到的原因所在

//C.class
...
public final void caller(com.maxtropy.viewtest.D);
    Code:
       0: aload_1
       1: ldc           #39                 // String d
       3: invokestatic  #15                 // Method kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull:(Ljava/lang/Object;Ljava/lang/String;)V
       6: aload_0
       7: aload_1
       8: invokevirtual #41                 // Method foo:(Lcom/maxtropy/viewtest/D;)V
      11: return
...

//.class where C().caller(D1()) was executed
...
      32: invokespecial #20                 // Method com/maxtropy/viewtest/C."<init>":()V
      35: new           #29                 // class com/maxtropy/viewtest/D1
      38: dup
      39: invokespecial #30                 // Method com/maxtropy/viewtest/D1."<init>":()V
      42: checkcast     #22                 // class com/maxtropy/viewtest/D
      45: invokevirtual #27                 // Method com/maxtropy/viewtest/C.caller:(Lcom/maxtropy/viewtest/D;)V
...

在caller()的入參中，d的參數類型是D，因此在調用caller()時，入參實例的類型就已經被上轉型成D了。

2. C1().caller(D())

程序執行的結果很明顯的告訴我們這是動態選擇的結果，執行的是C1中的Extension方法，而不是父類C中的Extension方法。
哇！在 top-level Extension反編譯的例子中很明顯的看到Extension方法被編譯成了靜態方法，這里怎么又跟動態選擇有關了呢？？？
同樣施以反編譯的魔法：

//C.class
Compiled from "C.kt"
public class com.maxtropy.viewtest.C {
  public void foo(com.maxtropy.viewtest.D);
    Code:
       0: aload_1
       1: ldc           #9                  // String $receiver
       3: invokestatic  #15                 // Method kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull:(Ljava/lang/Object;Ljava/lang/String;)V
       6: ldc           #17                 // String D.foo in C
       8: astore_2
       9: getstatic     #23                 // Field java/lang/System.out:Ljava/io/PrintStream;
      12: aload_2
      13: invokevirtual #29                 // Method java/io/PrintStream.println:(Ljava/lang/Object;)V
      16: return

  public void foo(com.maxtropy.viewtest.D1);
    Code:
       0: aload_1
       1: ldc           #9                  // String $receiver
       3: invokestatic  #15                 // Method kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull:(Ljava/lang/Object;Ljava/lang/String;)V
       6: ldc           #35                 // String D1.foo in C
       8: astore_2
       9: getstatic     #23                 // Field java/lang/System.out:Ljava/io/PrintStream;
      12: aload_2
      13: invokevirtual #29                 // Method java/io/PrintStream.println:(Ljava/lang/Object;)V
      16: return

  public final void caller(com.maxtropy.viewtest.D);
    Code:
       0: aload_1
       1: ldc           #39                 // String d
       3: invokestatic  #15                 // Method kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull:(Ljava/lang/Object;Ljava/lang/String;)V
       6: aload_0
       7: aload_1
       8: invokevirtual #41                 // Method foo:(Lcom/maxtropy/viewtest/D;)V
      11: return

  public com.maxtropy.viewtest.C();
    Code:
       0: aload_0
       1: invokespecial #45                 // Method java/lang/Object."<init>":()V
       4: return
}

//C1.class
Compiled from "C.kt"
public final class com.maxtropy.viewtest.C1 extends com.maxtropy.viewtest.C {
  public void foo(com.maxtropy.viewtest.D);
    Code:
       0: aload_1
       1: ldc           #9                  // String $receiver
       3: invokestatic  #15                 // Method kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull:(Ljava/lang/Object;Ljava/lang/String;)V
       6: ldc           #17                 // String D.foo in C1
       8: astore_2
       9: getstatic     #23                 // Field java/lang/System.out:Ljava/io/PrintStream;
      12: aload_2
      13: invokevirtual #29                 // Method java/io/PrintStream.println:(Ljava/lang/Object;)V
      16: return

  public void foo(com.maxtropy.viewtest.D1);
    Code:
       0: aload_1
       1: ldc           #9                  // String $receiver
       3: invokestatic  #15                 // Method kotlin/jvm/internal/Intrinsics.checkParameterIsNotNull:(Ljava/lang/Object;Ljava/lang/String;)V
       6: ldc           #35                 // String D1.foo in C1
       8: astore_2
       9: getstatic     #23                 // Field java/lang/System.out:Ljava/io/PrintStream;
      12: aload_2
      13: invokevirtual #29                 // Method java/io/PrintStream.println:(Ljava/lang/Object;)V
      16: return

  public com.maxtropy.viewtest.C1();
    Code:
       0: aload_0
       1: invokespecial #40                 // Method com/maxtropy/viewtest/C."<init>":()V
       4: return
}

原來聲明在Member中的Extension方法全部被編譯成了Member所在類型的實例方法！
這實例方法有什么用呢？（再次重復這些實例方法在寫.kt時無法通過實例直接拿到引用，也就c.foo()是不能通過編譯的）
玄妙便在call()方法的第6、行, 第6行的aload_0指的便是this, 也即是caller()被執行時真正的實例對象dispatch receiver。正是this，讓Extension方法具備了動態選擇的能力。