iOS底層原理總結 - 探尋Class的本質

iOS底層原理總結 - 探尋Class的本質

對小碼哥底層班視頻學習的總結與記錄。

  • 我們知道不管是類對象還是元類對象，類型都是Class，class和mete-class的底層都是objc_class結構體的指針，內存中就是結構體；


    struct objc-class圖.png
Class objectClass = [NSObject class];        
Class objectMetaClass = object_getClass([NSObject class]);
  • 點擊Class來到內部，我們可以發現
typedef struct objc_class *Class;
  • Class對象其實是一個指向objc_class結構體的指針。因此我們可以說類對象或元類對象在內存中其實就是objc_class結構體。
  • 我們來到objc_class內部，可以看到這段在底層原理中經常出現的代碼。
struct objc_class {
    Class _Nonnull isa  OBJC_ISA_AVAILABILITY;

#if !__OBJC2__
    Class _Nullable super_class                              OBJC2_UNAVAILABLE;
    const char * _Nonnull name                               OBJC2_UNAVAILABLE;
    long version                                             OBJC2_UNAVAILABLE;
    long info                                                OBJC2_UNAVAILABLE;
    long instance_size                                       OBJC2_UNAVAILABLE;
    struct objc_ivar_list * _Nullable ivars                  OBJC2_UNAVAILABLE;
    struct objc_method_list * _Nullable * _Nullable methodLists                    OBJC2_UNAVAILABLE;
    struct objc_cache * _Nonnull cache                       OBJC2_UNAVAILABLE;
    struct objc_protocol_list * _Nullable protocols          OBJC2_UNAVAILABLE;
#endif

} OBJC2_UNAVAILABLE;
/* Use `Class` instead of `struct objc_class *` */

  • 這部分代碼相信在文章中很常見，但是OBJC2_UNAVAILABLE;說明這些代碼已經不在使用了。那么目前objc_class的結構是什么樣的呢？我們通過objc源碼中去查找objc_class結構體的內容。


    objc_object結構體部分信息.png

  • 我們發現這個結構體繼承 objc_object 并且結構體內有一些函數，因為這是c++結構體，在c上做了擴展，因此結構體中可以包含函數。我們來到objc_object內，截取部分代碼


    objc_object內部分代碼.png
  • 我們發現這個結構體繼承 objc_object 并且結構體內有一些函數，因為這是c++結構體，在c上做了擴展，因此結構體中可以包含函數。我們來到objc_object內，截取部分代碼
  • 我們發現objc_object中有一個isa指針，那么objc_class繼承objc_object，也就同樣擁有一個isa指針

  • 那么我們之前了解到的，類中存儲的類的成員變量信息，實例方法，屬性名等這些信息在哪里呢。我們來到class_rw_t中，截取部分代碼，我們發現class_rw_t中存儲著方法列表，屬性列表，協議列表等內容。


    class_rw_t部分代碼.png

  • 而class_rw_t是通過bits調用data方法得來的，我們來到data方法內部實現。我們可以看到，data函數內部僅僅對bits進行&FAST_DATA_MASK操作


    objc_class代碼內容.png

    data方法內部實現.png

  • 而成員變量信息則是存儲在class_ro_t內部中的，我們來到class_ro_t內查看。


    class_ro_t內部代碼.png

  • 最后總結通過一張圖進行總結


    窺探struct objc_class的結構.png

如何證明上述內容是正確的呢？

  • 用代碼求證系統封閉結構體內部信息時，我們直接獲取可能拿不到，這時候我們一般采用自定義一個具有類似成員變量的結構體，當我們強制轉化系統結構體為自定義結構體的時候，就能一一對應的賦值，此時，我們可以拿到自定義結構體內部的消息。
    下面是仿照系統objc_class結構體，自定義的結構體，當然了這是小碼哥抽離好的，直接用可以，創建一個MJClassInfo.h文件
#import <Foundation/Foundation.h>

#ifndef MJClassInfo_h
#define MJClassInfo_h

# if __arm64__
#   define ISA_MASK        0x0000000ffffffff8ULL
# elif __x86_64__
#   define ISA_MASK        0x00007ffffffffff8ULL
# endif

#if __LP64__
typedef uint32_t mask_t;
#else
typedef uint16_t mask_t;
#endif
typedef uintptr_t cache_key_t;

struct bucket_t {
    cache_key_t _key;
    IMP _imp;
};

struct cache_t {
    bucket_t *_buckets;
    mask_t _mask;
    mask_t _occupied;
};

struct entsize_list_tt {
    uint32_t entsizeAndFlags;
    uint32_t count;
};

struct method_t {
    SEL name;
    const char *types;
    IMP imp;
};

struct method_list_t : entsize_list_tt {
    method_t first;
};

struct ivar_t {
    int32_t *offset;
    const char *name;
    const char *type;
    uint32_t alignment_raw;
    uint32_t size;
};

struct ivar_list_t : entsize_list_tt {
    ivar_t first;
};

struct property_t {
    const char *name;
    const char *attributes;
};

struct property_list_t : entsize_list_tt {
    property_t first;
};

struct chained_property_list {
    chained_property_list *next;
    uint32_t count;
    property_t list[0];
};

typedef uintptr_t protocol_ref_t;
struct protocol_list_t {
    uintptr_t count;
    protocol_ref_t list[0];
};

struct class_ro_t {
    uint32_t flags;
    uint32_t instanceStart;
    uint32_t instanceSize;  // instance對象占用的內存空間
#ifdef __LP64__
    uint32_t reserved;
#endif
    const uint8_t * ivarLayout;
    const char * name;  // 類名
    method_list_t * baseMethodList;
    protocol_list_t * baseProtocols;
    const ivar_list_t * ivars;  // 成員變量列表
    const uint8_t * weakIvarLayout;
    property_list_t *baseProperties;
};

struct class_rw_t {
    uint32_t flags;
    uint32_t version;
    const class_ro_t *ro;
    method_list_t * methods;    // 方法列表
    property_list_t *properties;    // 屬性列表
    const protocol_list_t * protocols;  // 協議列表
    Class firstSubclass;
    Class nextSiblingClass;
    char *demangledName;
};

#define FAST_DATA_MASK          0x00007ffffffffff8UL
struct class_data_bits_t {
    uintptr_t bits;
public:
    class_rw_t* data() {
        return (class_rw_t *)(bits & FAST_DATA_MASK);
    }
};

/* OC對象 */
struct mj_objc_object {
    void *isa;
};

/* 類對象 */
struct mj_objc_class : mj_objc_object {
    Class superclass;
    cache_t cache;
    class_data_bits_t bits;
public:
    class_rw_t* data() {
        return bits.data();
    }
    
    mj_objc_class* metaClass() {
        return (mj_objc_class *)((long long)isa & ISA_MASK);
    }
};

#endif /* MJClassInfo_h */
  • 我們需要將main.m 文件后綴修改為main.mm（告訴編譯器兼容oc代碼跟c++代碼）.
  • 我們在main.mm文件中寫好要強轉的代碼：
// objective-c++
#import <Foundation/Foundation.h>
#import <objc/runtime.h>
#import "MJClassInfo.h"

// MJPerson
@interface MJPerson : NSObject <NSCopying>
{
@public
    int _age;
}
@property (nonatomic, assign) int no;
- (void)personInstanceMethod;
+ (void)personClassMethod;
@end

@implementation MJPerson

- (void)test
{
    
}

- (void)personInstanceMethod
{
    
}
+ (void)personClassMethod
{
    
}
- (id)copyWithZone:(NSZone *)zone
{
    return nil;
}
@end

// MJStudent
@interface MJStudent : MJPerson <NSCoding>
{
@public
    int _weight;
}
@property (nonatomic, assign) int height;
- (void)studentInstanceMethod;
+ (void)studentClassMethod;
@end

@implementation MJStudent
- (void)test
{
    
}
- (void)studentInstanceMethod
{
    
}
+ (void)studentClassMethod
{
    
}
- (id)initWithCoder:(NSCoder *)aDecoder
{
    return nil;
}

- (void)encodeWithCoder:(NSCoder *)aCoder
{
    
}
@end


int main(int argc, const char * argv[]) {
    @autoreleasepool {
        MJStudent *stu = [[MJStudent alloc] init];
        stu->_weight = 10;
        Class objectClass = [NSObject class];
        Class objectMetaClass = object_getClass([NSObject class]);
        
        mj_objc_class *studentClass = (__bridge mj_objc_class *)([MJStudent class]);
        mj_objc_class *personClass = (__bridge mj_objc_class *)([MJPerson class]);
        
        class_rw_t *studentClassData = studentClass->data();
        class_rw_t *personClassData = personClass->data();
        
        class_rw_t *studentMetaClassData = studentClass->metaClass()->data();
        class_rw_t *personMetaClassData = personClass->metaClass()->data();

        NSLog(@"1111");
    }
    return 0;
}
  • 然后我們通過打斷點依次分析如下：

  • 至此，我們再次拿出那張經典的圖，挨個分析圖中isa指針和superclass指針的指向


    isa、superclass指向圖.png
  • 然后我們通過打斷點依次分析如下：
  • 至此，我們再次拿出那張經典的圖，挨個分析圖中isa指針和superclass指針的指向

instance對象

  • 首先我們來看instance對象，我們通過上一篇文章知道，instance對象中存儲著isa指針和其他成員變量，并且instance對象的isa指針是指向其類對象地址的。我們首先分析上述代碼中我們創建的object，person，student三個instance對象與其相對應的類對象objectClass，personClass，studentClass。


    instance對象分析.png

class對象

  • 接著我們來看class對象，同樣通過上一篇文章，我們明確class對象中存儲著isa指針，superclass指針，以及類的屬性信息，類的成員變量信息，類的對象方法，和類的協議信息，而通過上面對object源碼的分析，我們知道這些信息存儲在class對象的class_rw_t中，我們通過強制轉化來窺探其中的內容。如下圖


    personClassData內結構.png
  • 上圖中我們通過模擬對person類對象調用.data函數，即對bits進行&FAST_DATA_MASK(0x00007ffffffffff8UL)運算，并轉化為class_rw_t。即上圖中的personClassData。其中我們發現成員變量信息，對象方法，屬性等信息只顯示first第一個，如果想要拿到更多的需要通過代碼將指針后移獲取。而上圖中的instaceSize = 16也同person對象中isa指針8個字節+_age4個字節+_height4個字節相對應起來。這里不在展開對objectClassData及studentClassData進行分析，基本內容同personClassData相同。

  • 那么類對象中的isa指針和superclass指針的指向是否如那張經典的圖示呢？我們來驗證一下。


    類對象的isa指針和superclass指針指向.png
  • 從上圖中我們可以發現instance對象中確實存儲了isa指針和其成員變量，同時將instance對象的isa指針經過&運算之后計算出的地址確實是其相應類對象的內存地址。由此我們證明isa，superclass指向圖中的1，2，3號線。

class對象

  • 接著我們來看class對象，同樣通過上一篇文章，我們明確class對象中存儲著isa指針，superclass指針，以及類的屬性信息，類的成員變量信息，類的對象方法，和類的協議信息，而通過上面對object源碼的分析，我們知道這些信息存儲在class對象的class_rw_t中，我們通過強制轉化來窺探其中的內容。如下圖
  • 上圖中我們通過模擬對person類對象調用.data函數，即對bits進行&FAST_DATA_MASK(0x00007ffffffffff8UL)運算，并轉化為class_rw_t。即上圖中的personClassData。其中我們發現成員變量信息，對象方法，屬性等信息只顯示first第一個，如果想要拿到更多的需要通過代碼將指針后移獲取。而上圖中的instaceSize = 16也同person對象中isa指針8個字節+_age4個字節+_height4個字節相對應起來。這里不在展開對objectClassData及studentClassData進行分析，基本內容同personClassData相同。
  • 那么類對象中的isa指針和superclass指針的指向是否如那張經典的圖示呢？我們來驗證一下。
  • 通過上圖中的內存地址的分析，由此我們證明isa，superclass指向圖中，isa指針的4，5，6號線，以及superclass指針的10，11，12號線。

meta-class對象

  • 最后我們來看meta-class元類對象，上文提到meta-class中存儲著isa指針，superclass指針，以及類的類方法信息。同時我們知道meta-class元類對象與class類對象，具有相同的結構，只不過存儲的信息不同，并且元類對象的isa指針指向基類的元類對象，基類的元類對象的isa指針指向自己。元類對象的superclass指針指向其父類的元類對象，基類的元類對象的superclass指針指向其類對象。

  • 與class對象相同，我們同樣通過模擬對person元類對象調用.data函數，即對bits進行&FAST_DATA_MASK(0x00007ffffffffff8UL)運算，并轉化為class_rw_t


    personMetaClassData內結構.png
  • 首先我們可以看到結構同personClassData相同，并且成員變量及屬性列表等信息為空，而methods中存儲著類方法personClassMethod。

  • 接著來驗證isa及superclass指針的指向是否同上圖序號標注一樣。


    meta-class的isa指針指向.png

  • 上圖中通過地址證明meta-class的isa指向基類的meta-class，基類的isa指針也指向自己。


    meta-class的superclass指針指向.png
  • 上圖中通過地址證明meta-class的superclass指向父類的meta-class，基類的meta-class的superclass指向基類的class類。
?著作權歸作者所有,轉載或內容合作請聯系作者
平臺聲明：文章內容（如有圖片或視頻亦包括在內）由作者上傳并發布，文章內容僅代表作者本人觀點，簡書系信息發布平臺，僅提供信息存儲服務。

推薦閱讀更多精彩內容