開始當然得要點匯編知識了

arm寄存器的兩種名字

@ r0-r3 a1-a4
@ r4-r9 v1-v7
@ r10 sl
@ r11 fp
@ r12 ip
@ r13 sp
@ r14 lr
@ r15 pc

基本指令（沒有什么深奧的知識，看注釋秒懂）

mov r0, r1    @ r0 = r1
mov r0, #13   @ 數(shù)字還是存在于32位中,不可能很長,這時可以用偽指令
ldr r0, =1234 @ 1234存入r0
ldr r1, =0x2000000
ldr r0, [r1]  @ r1所指向的地址中的內(nèi)容存入r0
str r0, [r1]  @ r0的值存入r1所指向的地址中去

ldr r2, str
ldr r3, str1

ldr r2, =str    @ 不是r2 = 77777,而是r2 = 存放77777的地址（鏈接時確定的）
add r0, r1, r0  @ r0 = r1 + r0
sub r0, r1, r0  @ r0 = r1 - r0

str:
     .word 77777  @ 4 Byte
str1:
     .word 88888

重點來了，循序漸進介紹一下棧為何會這么做的

@ 0. apcs:fn調(diào)用完pc從lr里取回,注意arm有3級流水線
     mov lr, pc
     ldr pc, show
     mov pc, lr
show:
     .word 0x33f94aa8
@ 但這么做,如果之前還有函數(shù)調(diào)用,也勢必要使用lr寄存器,lr所保存的值就被覆蓋了

@ 1. 把前函數(shù)的lr的值放在內(nèi)存中
     ldr r5, =0x20000000
     str lr, [r5]
     mov lr, pc
     ldr pc, show
     ldr lr, [r5]
     mov pc, lr
show:
     .word 0x33f94aa8
@ 但這么做,如果r5在show函數(shù)中被使用,則出錯
@ apcs中規(guī)定r0-r3一定被破壞,r4-r9(v1-v7)調(diào)用前后需保持一致,然而此時也沒保證r5的值調(diào)用前后一致

@ 2. 于是乎有了堆棧
     sub sp, sp, #4
     str lr, [sp]

     ldr r0, =fmt

     mov lr, pc
     ldr pc, show

     ldr lr, [sp]
     add sp, sp, #4
     mov pc, lr
show:
     .word 0x33f94aa8
fmt:
     .asciz "hello world.\n" @ .ascii "hello world.\n\0"
@ 函數(shù)嵌套就挺麻煩,于是想到把sp也存入棧中

@ 3. ip(r12)存當前sp且也存入棧中
     mov ip, sp
     sub sp, sp, #8
     str lr, [sp]
     str ip, [sp, #4]

     ldr r0, =fmt

     mov lr, pc
     ldr pc, show

     mov sp, #555  @ sp的修改還是影響后續(xù)

     ldr lr, [sp]
     ldr ip, [sp, #4]
     mov sp, ip
     mov pc, lr
show:
     .word 0x33f94aa8
fmt:
     .asciz "hello world.\n" @ .ascii "hello world.\n\0"

@ 4. fp(r11) 當下的frame pointer也需要保存
     mov ip, sp
     sub sp, sp, #12
     str lr, [sp]
     str ip, [sp, #4]
     str fp, [sp, #8]

     sub fp, ip, #4

     ldr r0, =fmt

     mov lr, pc
     ldr pc, show

     mov sp, #555

     ldr lr, [fp, #-8]
     ldr ip, [fp, #-4]
     ldr fp, [fp, #0]
     mov sp, ip
     mov pc, lr
show:
     .word 0x33f94aa8
fmt:
     .asciz "hello world.\n" @ .ascii "hello world.\n\0" 

@ 5. 簡寫
aaa:
     mov ip, sp
     stmfd sp!, {fp, ip, lr, pc} @ stmdb sp!, {fp, ip, lr, pc} 不寫!則sp不變,這個pc是調(diào)試信息
     sub fp, ip, #4

     bl test @ mov lr, pc @ ldr pc, test
     
     sub sp, fp, #12
     ldmfd sp, {fp, sp, pc}

test:
     mov ip, sp
     stmfd sp!, {fp, ip, lr, pc}
     sub fp, ip, #4

     ldr r0, =fmt
     bl show

     sub sp, fp, #12
     ldmfd sp, {fp, sp, pc}
show:
     .word 0x33f94aa8
fmt:
     .asciz "hello world.\n"